GNU bug report logs - #1415
23.0.60; display-buffer doesn't honor NOT-THIS-WINDOW argument

Previous Next

To add a comment to this bug, you must first unarchive it, by sending
a message to control AT debbugs.gnu.org, with unarchive 1415 in the body.
You can then email your comments to 1415 AT debbugs.gnu.org in the normal way.

Toggle the display of automated, internal messages from the tracker.

Message #5 received at submit <at> emacsbugs.donarmstrong.com (full text, mbox):

From: Helmut Eller <eller.helmut <at> gmail.com>
To: emacs-pretest-bug <at> gnu.org
Subject: 23.0.60; display-buffer doesn't honor NOT-THIS-WINDOW argument
Date: Sat, 22 Nov 2008 18:01:37 +0100

I think that display-buffer returns sometimes the selected window even
if the NOT-THIS-WINDOW argument is true.  Here is a test case:

(progn
  (defun display-buffer-checked (buffer)
    (let ((selected (selected-window))
          (window (display-buffer buffer t)))
      (when (eq selected window)
        (error "display-buffer returned selected window"))
      window))
  
  (let ((foo (get-buffer-create "foo"))
        (bar (get-buffer-create "bar")))
    (select-window (get-buffer-window "*scratch*"))
    (save-selected-window 
      (select-window (display-buffer-checked foo)))
    (save-selected-window 
      (select-window (display-buffer-checked bar)))))


display-buffer-checked just calls display-buffer and checks that the
returned window isn't the selected window.  From looking at the code of
display-buffer, I would say that display-buffer returns the lru window
even if that's the selected window.

Helmut.


In GNU Emacs 23.0.60.10 (i686-pc-linux-gnu, GTK+ Version 2.8.20)
 of 2008-11-22 on xaital
Windowing system distributor `The X.Org Foundation', version 11.0.70101000
configured using `configure  '--without-sound' '--without-pop' '--without-gif' '--without-tiff''

Message #10 received at 1415 <at> emacsbugs.donarmstrong.com (full text, mbox):

From: martin rudalics <rudalics <at> gmx.at>
To: Helmut Eller <eller.helmut <at> gmail.com>
Cc: 1415 <at> debbugs.gnu.org
Subject: Re: bug#1415: 23.0.60;	display-buffer doesn't honor NOT-THIS-WINDOW
 argument
Date: Mon, 24 Nov 2008 10:59:48 +0100

[Message part 1 (text/plain, inline)]

> I think that display-buffer returns sometimes the selected window even
> if the NOT-THIS-WINDOW argument is true.  Here is a test case:
>
> (progn
>   (defun display-buffer-checked (buffer)
>     (let ((selected (selected-window))
>           (window (display-buffer buffer t)))
>       (when (eq selected window)
>         (error "display-buffer returned selected window"))
>       window))
>
>   (let ((foo (get-buffer-create "foo"))
>         (bar (get-buffer-create "bar")))
>     (select-window (get-buffer-window "*scratch*"))
>     (save-selected-window
>       (select-window (display-buffer-checked foo)))
>     (save-selected-window
>       (select-window (display-buffer-checked bar)))))
>
>
> display-buffer-checked just calls display-buffer and checks that the
> returned window isn't the selected window.  From looking at the code of
> display-buffer, I would say that display-buffer returns the lru window
> even if that's the selected window.

Nice bug.  Thanks for the precise report and test case!

Emacs 22 handled this, but I'm too lazy to figure out how.

Please try the attached patch.

martin

[window.diff (text/plain, inline)]

*** window.el.~1.168.~	2008-11-18 22:26:34.390625000 +0100
--- window.el	2008-11-24 10:31:29.953125000 +0100
***************
*** 1038,1051 ****
  		     (window--try-to-split-window
  		      (get-lru-window frame-to-use t))))
  	   (window--display-buffer-2 buffer window-to-use)))
!      ((setq window-to-use
! 	    ;; Reuse an existing window.
! 	    (or (get-lru-window frame-to-use)
! 		(get-buffer-window buffer 'visible)
! 		(get-largest-window 'visible nil)
! 		(get-buffer-window buffer 0)
! 		(get-largest-window 0 nil)
! 		(frame-selected-window (funcall pop-up-frame-function))))
        (window--even-window-heights window-to-use)
        (window--display-buffer-2 buffer window-to-use)))))
  
--- 1038,1063 ----
  		     (window--try-to-split-window
  		      (get-lru-window frame-to-use t))))
  	   (window--display-buffer-2 buffer window-to-use)))
!      ((let ((window-to-undedicate
! 	     ;; When NOT-THIS-WINDOW is non-nil, temporarily dedicate
! 	     ;; the selected window to its buffer, to avoid that some of
! 	     ;; the routines below choose it.  (Bug#1415)
! 	     (and not-this-window
! 		  (not (window-dedicated-p (selected-window)))
! 		  (set-window-dedicated-p (selected-window) t)
! 		  (selected-window))))
! 	(unwind-protect
! 	    (setq window-to-use
! 		  ;; Reuse an existing window.
! 		  (or (get-lru-window frame-to-use)
! 		      (get-buffer-window buffer 'visible)
! 		      (get-largest-window 'visible)
! 		      (get-buffer-window buffer 0)
! 		      (get-largest-window 0)
! 		      (frame-selected-window (funcall pop-up-frame-function))))
! 	  (when (window-live-p window-to-undedicate)
! 	    ;; Restore dedicated status of selected window.
! 	    (set-window-dedicated-p window-to-undedicate nil))))
        (window--even-window-heights window-to-use)
        (window--display-buffer-2 buffer window-to-use)))))
  

Message #15 received at 1415 <at> emacsbugs.donarmstrong.com (full text, mbox):

From: Helmut Eller <eller.helmut <at> gmail.com>
To: martin rudalics <rudalics <at> gmx.at>
Cc: 1415 <at> debbugs.gnu.org
Subject: Re: bug#1415: 23.0.60;	display-buffer doesn't honor NOT-THIS-WINDOW argument
Date: Wed, 26 Nov 2008 22:13:58 +0100

* martin rudalics [2008-11-24 10:59+0100] writes:

>
> Nice bug.  Thanks for the precise report and test case!
>
> Emacs 22 handled this, but I'm too lazy to figure out how.
>
> Please try the attached patch.

I've used the patch now for two days and it seems to work well.

Thank you for the quick fix.

Helmut.

Message #20 received at 1415-done <at> emacsbugs.donarmstrong.com (full text, mbox):

From: martin rudalics <rudalics <at> gmx.at>
To: 1415-done <at> debbugs.gnu.org
Cc: Helmut Eller <eller.helmut <at> gmail.com>
Subject: Re: bug#1415: 23.0.60;	display-buffer doesn't honor NOT-THIS-WINDOW
 argument
Date: Thu, 27 Nov 2008 14:41:11 +0100

> I've used the patch now for two days and it seems to work well.

I've checked in a slightly more restrictive version.
Please try again and keep an eye on this.

Thanks again for reporting, martin.

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.