Subject: Re: bug#9820: 24.0.90; Behaviour of add-file-local-variable

From: Juri Linkov <[email-masked]>
Date: Sun, 16 Jun 2013 01:58:07 +0300

This is an old request that I'd like to close now, one way or another.

> BTW, I think the message is not yet as good as it should be.  E.g. we
> could either tell the exact command that needs to be used (e.g. M-x
> revert-buffer), or go the other way and only point out the current
> situation without indicating how to "fix" it, something like "the change
> hasn't yet taken effect".

In a similar situation, Dired displays this message:

  (message "%s" (substitute-command-keys
                 "Directory has changed on disk; type \\[revert-buffer] to update Dired"))

So for `add-file-local-variable' it could be:

  (message "%s" (substitute-command-keys
                 "For this change to take effect revisit file using \\[revert-buffer]"))

The following patch displays this message.

=== modified file 'lisp/files-x.el'
--- lisp/files-x.el	2013-06-15 22:44:38 +0000
+++ lisp/files-x.el	2013-06-15 22:57:03 +0000
@@ -115,7 +115,7 @@ (defun read-file-local-variable-mode ()
      ((and (stringp mode) (fboundp (intern mode))) (intern mode))
      (t mode))))
 
-(defun modify-file-local-variable (variable value op)
+(defun modify-file-local-variable (variable value op &optional interactive)
   "Modify file-local VARIABLE in Local Variables depending on operation OP.
 
 If OP is `add-or-replace' then delete all existing settings of
@@ -198,10 +198,17 @@ (defun modify-file-local-variable (varia
 	   ((eq variable 'mode) (goto-char beg))
 	   ((null replaced-pos) (goto-char end))
 	   (replaced-pos (goto-char replaced-pos)))
-	  (insert (format "%s%S: %S%s\n" prefix variable value suffix)))))))
+	  (insert (format "%s%S: %S%s\n" prefix variable value suffix)))
+
+	(when (and interactive
+		   (not (and (symbolp variable)
+			     (boundp variable)
+			     (equal (symbol-value variable) value))))
+	  (message "%s" (substitute-command-keys
+			 "For this change to take effect revisit file using \\[revert-buffer]"))))))))
 
 ;;;###autoload
-(defun add-file-local-variable (variable value)
+(defun add-file-local-variable (variable value &optional interactive)
   "Add file-local VARIABLE with its VALUE to the Local Variables list.
 
 This command deletes all existing settings of VARIABLE (except `mode'
@@ -213,17 +220,17 @@ (defun add-file-local-variable (variable
 `Local Variables:' and the last line containing the string `End:'."
   (interactive
    (let ((variable (read-file-local-variable "Add file-local variable")))
-     (list variable (read-file-local-variable-value variable))))
-  (modify-file-local-variable variable value 'add-or-replace))
+     (list variable (read-file-local-variable-value variable) t)))
+  (modify-file-local-variable variable value 'add-or-replace interactive))
 
 ;;;###autoload
-(defun delete-file-local-variable (variable)
+(defun delete-file-local-variable (variable &optional interactive)
   "Delete all settings of file-local VARIABLE from the Local Variables list."
   (interactive
-   (list (read-file-local-variable "Delete file-local variable")))
-  (modify-file-local-variable variable nil 'delete))
+   (list (read-file-local-variable "Delete file-local variable") t))
+  (modify-file-local-variable variable nil 'delete interactive))
 
-(defun modify-file-local-variable-prop-line (variable value op)
+(defun modify-file-local-variable-prop-line (variable value op &optional interactive)
   "Modify file-local VARIABLE in the -*- line depending on operation OP.
 
 If OP is `add-or-replace' then delete all existing settings of
@@ -341,10 +348,17 @@ (defun modify-file-local-variable-prop-l
 	      (insert ";"))
 	  (unless (eq (char-before) ?\s) (insert " "))
 	  (insert (format "%S: %S;" variable value))
-	  (unless (eq (char-after) ?\s) (insert " "))))))))
+	  (unless (eq (char-after) ?\s) (insert " "))))))
+
+    (when (and interactive
+	       (not (and (symbolp variable)
+			 (boundp variable)
+			 (equal (symbol-value variable) value))))
+      (message "%s" (substitute-command-keys
+		     "For this change to take effect revisit file using \\[revert-buffer]")))))
 
 ;;;###autoload
-(defun add-file-local-variable-prop-line (variable value)
+(defun add-file-local-variable-prop-line (variable value &optional interactive)
   "Add file-local VARIABLE with its VALUE to the -*- line.
 
 This command deletes all existing settings of VARIABLE (except `mode'
@@ -355,15 +369,15 @@ (defun add-file-local-variable-prop-line
 then this function adds it."
   (interactive
    (let ((variable (read-file-local-variable "Add -*- file-local variable")))
-     (list variable (read-file-local-variable-value variable))))
-  (modify-file-local-variable-prop-line variable value 'add-or-replace))
+     (list variable (read-file-local-variable-value variable) t)))
+  (modify-file-local-variable-prop-line variable value 'add-or-replace interactive))
 
 ;;;###autoload
-(defun delete-file-local-variable-prop-line (variable)
+(defun delete-file-local-variable-prop-line (variable &optional interactive)
   "Delete all settings of file-local VARIABLE from the -*- line."
   (interactive
-   (list (read-file-local-variable "Delete -*- file-local variable")))
-  (modify-file-local-variable-prop-line variable nil 'delete))
+   (list (read-file-local-variable "Delete -*- file-local variable") t))
+  (modify-file-local-variable-prop-line variable nil 'delete interactive))
 
 (defvar auto-insert) ; from autoinsert.el