GNU bug report logs - #73723
31.0.50; Add copy/kill/mark commands to isearch

Previous Next

Full log

View this message in rfc822 format

From: Phil Sainty <psainty <at> orcon.net.nz>
To: 73723 <at> debbugs.gnu.org
Subject: bug#73723: 31.0.50; Add copy/kill/mark commands to isearch
Date: Thu, 10 Oct 2024 09:33:41 +1300

I find the following useful, and sometimes see others asking for
the same thing.  Shall we add these to Emacs?

 (defun isearch-copy-match ()
   "Copy the currently-matched text to the kill ring."
   (interactive)
   (kill-new (buffer-substring (min (point) isearch-other-end)
                               (max (point) isearch-other-end))))

 (defun isearch-kill-match ()
   "Kill the currently-matched text."
   (interactive)
   (kill-region (min (point) isearch-other-end)
                (max (point) isearch-other-end)))

 (defun isearch-mark-match ()
   "Exit isearch, marking the last match."
   (interactive)
   (set-mark isearch-other-end)
   (isearch-exit)
   (activate-mark))

 (define-key isearch-mode-map (kbd "M-s M-w") #'isearch-copy-match)
 (define-key isearch-mode-map (kbd "M-s C-w") #'isearch-kill-match)
 (define-key isearch-mode-map (kbd "M-s C-SPC") #'isearch-mark-match)
 (define-key isearch-mode-map (kbd "M-s C-@") #'isearch-mark-match)

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.