Subject: bug#72511: 30.0.50; prefix-completions is always nil in help--symbol-completion-table

From: Eli Zaretskii <[email-masked]>
Date: Wed, 07 Aug 2024 17:20:49 +0300

> Date: Wed, 7 Aug 2024 13:53:05 +0200
> From:  Chris Roberts via "Bug reports for GNU Emacs,
>  the Swiss army knife of text editors" <[email-masked]>
> 
> On lines 209-214 inside the function `help--symbol-complete-table' in
> help-fns.el there is a following block of code:
> 
> (when help-enable-completion-autoload
>   (let ((prefixes (radix-tree-prefixes (help-definition-prefixes) string)))
>     (help--load-prefixes prefixes)))
> (let ((prefix-completions
>        (and help-enable-completion-autoload
>             (mapcar #'intern (all-completions string definition-prefixes)))))
> 
> By default, `help-enable-completion-autoload' is t, so this code should
> normally run. The perceived problem here is that the definition of
> `help-definition-prefixes' function is as follows:
> 
> (defun help-definition-prefixes ()
>   "Return the up-to-date radix-tree form of `definition-prefixes'."
>   (when (> (hash-table-count definition-prefixes) 0)
>     (maphash (lambda (prefix files)
>                (let ((old (radix-tree-lookup help-definition-prefixes prefix)))
>                  (setq help-definition-prefixes
>                        (radix-tree-insert help-definition-prefixes
>                                           prefix (append old files)))))
>              definition-prefixes)
>     (clrhash definition-prefixes))
>   help-definition-prefixes)
> 
> Because of the `clrhash', `definition-prefixes' will always be empty
> after the function call to `help-definition-prefixes'. So in practice,
> `definition-prefixes' will always have zero elements when we're trying
> to calculate `prefix-completions', which makes the calls to
> `all-completions' and `mapcar' basically no-ops. The end result is that
> `prefix-completions' will always be NIL.
> 
> This can be verified by evaluating the following code in emacs -Q:
> 
> (require 'radix-tree)
> (require 'help-fns)
> 
> (let ((string "string-remove-prefix"))
>   (format "Definition prefixes count before: %d\n%sDefinition prefixes count after: %d\nPrefix completions: %s\n"
>           (hash-table-count definition-prefixes)
>           (or
>            (when help-enable-completion-autoload
>              (let ((prefixes (radix-tree-prefixes (help-definition-prefixes) string)))
>                (help--load-prefixes prefixes)))
>            "")
>           (hash-table-count definition-prefixes)
>           (let ((prefix-completions
>                  (and help-enable-completion-autoload
>                       (mapcar #'intern (all-completions string definition-prefixes)))))
>             prefix-completions)))
> 
> This has been first introduced in commit fd8084a (Automatically find
> vars and functions via definition-prefixes)
> 
> I'm not sure if this was the intended behavior or not, but it seemed
> suspicious to me, so I decided it's better to report it.
> 
> It might also be useful to note that `prefix-completion' is used in the
> following way:
> 
> (complete-with-action action obarray string
>                       (if pred (lambda (sym)
>                                  (or (funcall pred sym)
>                                      (memq sym prefix-completions)))))
> 
> I'm not sure what `pred' will be in this context, or what impact
> `prefix-completions' being always NIL will have, if any. But I believe
> that at the very least the code pertaining to `prefix-completions' could
> concievably be removed.
> 
> Also, was clearing out the entirety of `definition-prefixes' on completion
> really the intended behavior? As it stands, just C-h f s <TAB> is enough
> to completely truncate it.

Thanks, I'm adding Stefan, who wrote this code, to the discussion.