Subject: bug#7158: 24.0.50; Incorrect handling of variable 'display-time-mail-function'

From: Detlev Zundel <[email-masked]>
Date: Tue, 05 Oct 2010 10:18:30 +0200

Detlev Zundel <[email-masked]> writes:

> As I understand the documentation, the variable
> 'display-time-mail-function' should allow to provide a function which
> decides whether to display the mail icon in the status area.
>
> Unfortunately the code does not allow this semantic, as the code uses an
> or expression over several possibilities (lisp/time.el:407):
>
>         (mail (or (and display-time-mail-function
>                        (funcall display-time-mail-function))
>                   (and display-time-mail-directory
>                        (display-time-mail-check-directory))
>                   (and (stringp mail-spool-file)
>                        (or (null display-time-server-down-time)
>                            ;; If have been down for 20 min, try again.
>                            (> (- (nth 1 now) display-time-server-down-time)
>                               1200)
>                            (and (< (nth 1 now) display-time-server-down-time)
>                                 (> (- (nth 1 now)
>                                       display-time-server-down-time)
>                                    -64336)))
>                        (let ((start-time (current-time)))
>                          (prog1
>                              (display-time-file-nonempty-p mail-spool-file)
>                            (if (> (- (nth 1 (current-time))
>                                      (nth 1 start-time))
>                                   20)
>                                ;; Record that mail file is not accessible.
>                                (setq display-time-server-down-time
>                                      (nth 1 (current-time)))
>                              ;; Record that mail file is accessible.
>                              (setq display-time-server-down-time nil)))))))
>
>
> So when display-time-mail-function is set but returns nil, then the
> following tests will still be evaluated instead of using this negative
> result.
>
> As a fix I propose the attached patch.

This patch is actually erroneous - it has a missing closing parenthesis
and an unrelated typeo.  The attached patch is tested.  Sorry for the
inconvenience.

Cheers
  Detlev

-- 
Ftpd never switches uid and euid, it uses setfsuid(2) instead. The
main reason is that uid switching has been exploited in several
breakins, but the sheer ugliness of uid switching counts too.
                                     -- pure-ftpd(8)
diff --git a/lisp/time.el b/lisp/time.el
index d512fae..2f8eda7 100644
--- a/lisp/time.el
+++ b/lisp/time.el
@@ -404,30 +404,31 @@ update which can wait for the next redisplay."
                               (getenv "MAIL")
                               (concat rmail-spool-directory
                                       (user-login-name))))
-	 (mail (or (and display-time-mail-function
-			(funcall display-time-mail-function))
-		   (and display-time-mail-directory
-			(display-time-mail-check-directory))
-		   (and (stringp mail-spool-file)
-			(or (null display-time-server-down-time)
-			    ;; If have been down for 20 min, try again.
-			    (> (- (nth 1 now) display-time-server-down-time)
-			       1200)
-			    (and (< (nth 1 now) display-time-server-down-time)
-				 (> (- (nth 1 now)
-				       display-time-server-down-time)
-				    -64336)))
-			(let ((start-time (current-time)))
-			  (prog1
-			      (display-time-file-nonempty-p mail-spool-file)
-			    (if (> (- (nth 1 (current-time))
-				      (nth 1 start-time))
-				   20)
-				;; Record that mail file is not accessible.
-				(setq display-time-server-down-time
-				      (nth 1 (current-time)))
-			      ;; Record that mail file is accessible.
-			      (setq display-time-server-down-time nil)))))))
+	 (mail (cond (display-time-mail-function
+		      (funcall display-time-mail-function))
+		     (display-time-mail-directory
+		      (display-time-mail-check-directory))
+		     ((stringp mail-spool-file)
+		      (and
+		       (or (null display-time-server-down-time)
+			   ;; If have been down for 20 min, try again.
+			   (> (- (nth 1 now) display-time-server-down-time)
+			      1200)
+			   (and (< (nth 1 now) display-time-server-down-time)
+				(> (- (nth 1 now)
+				      display-time-server-down-time)
+				   -64336)))
+		       (let ((start-time (current-time)))
+			 (prog1
+			     (display-time-file-nonempty-p mail-spool-file)
+			   (if (> (- (nth 1 (current-time))
+				     (nth 1 start-time))
+				  20)
+			       ;; Record that mail file is not accessible.
+			       (setq display-time-server-down-time
+				     (nth 1 (current-time)))
+			     ;; Record that mail file is accessible.
+			     (setq display-time-server-down-time nil))))))))
          (24-hours (substring time 11 13))
          (hour (string-to-number 24-hours))
          (12-hours (int-to-string (1+ (% (+ hour 11) 12))))