GNU bug report logs - #70409
30.0.50; `latexenc-find-file-coding-system` uses `TeX-master` before we know it's safe

Previous Next

Full log

Message #5 received at submit <at> debbugs.gnu.org (full text, mbox):

From: Stefan Monnier <monnier <at> iro.umontreal.ca>
To: bug-gnu-emacs <at> gnu.org
Subject: 30.0.50; `latexenc-find-file-coding-system` uses `TeX-master`
 before we know it's safe
Date: Mon, 15 Apr 2024 18:42:36 -0400

[Message part 1 (text/plain, inline)]

Package: Emacs
Version: 30.0.50


If I open a file `foo.tex` with a local variable setting of
`TeX-master: "paper.tex"` and that `paper.tex` file has a local
variable setting of `TeX-master: t`, I get the funny behavior that
Emacs first asks me whether to obey the `TeX-master: t` setting of
`paper.tex` before asking me whether to obey the `TeX-master:
"paper.tex"` setting of `foo.tex`, even though it obviously had to use
the `TeX-master: "paper.tex"` setting in order to decide to open the
`paper.tex` file (and ask me about its `TeX-master: t`).

The corresponding backtrace looks as below:

    Debugger entered--Lisp error: (minibuffer-quit)
      #<subr F616e6f6e796d6f75732d6c616d626461_anonymous_lambda_57>()
      read-char-from-minibuffer("Please type y, n, ! or i, or C-v/M-v to scroll: " (33 105 121 110 32))
      read-char-choice("Please type y, n, ! or i, or C-v/M-v to scroll: " (33 105 121 110 32))
      hack-local-variables-confirm(((TeX-master . t)) ((TeX-master . t)) nil nil)
      hack-local-variables-filter(((TeX-master . t)) nil)
      hack-local-variables(no-mode)
      run-mode-hooks(latex-mode-hook)
      latex-mode()
      set-auto-mode-0(latex-mode nil)
      set-auto-mode()
      normal-mode(t)
      after-find-file(nil nil)
      find-file-noselect-1(#<buffer paper.tex> ".../paper.tex" t nil ".../paper.tex" (3064599 65026))
      find-file-noselect("paper.tex" t)
      latexenc-find-file-coding-system((insert-file-contents ".../foo.tex" t nil nil nil))
      insert-file-contents(".../foo.tex" t)
      find-file-noselect-1(#<buffer foo.tex> ".../foo.tex" nil nil ".../foo.tex" (3064581 65026))
      find-file-noselect(".../foo.tex")
      command-line-1((".../foo.tex"))
      command-line()
      normal-top-level()

showing that the problem is that `latexenc-find-file-coding-system`
is the function that opens `paper.tex` before the users had a chance to
confirm that they think this is safe.

I suggest the patch below which makes `latexenc-find-file-coding-system`
use `safe-local-variable-p` before using a file-local setting, and also
adds corresponding `safe-local-variable` settings for `TeX-master` and
`tex-main-file`.


        Stefan

[tex-master.diff (text/x-diff, inline)]

diff --git a/lisp/international/latexenc.el b/lisp/international/latexenc.el
index 6e2306449bc..66e3faa37b9 100644
--- a/lisp/international/latexenc.el
+++ b/lisp/international/latexenc.el
@@ -155,14 +155,16 @@ latexenc-find-file-coding-system
               (when (re-search-forward
                      "^%+ *\\(TeX-master\\|tex-main-file\\): *\"\\(.+\\)\""
                      nil t)
-                (let ((file (match-string 2)))
-                  (dolist (ext `("" ,(if (boundp 'TeX-default-extension)
-                                         (concat "." TeX-default-extension)
-                                       "")
-                                 ".tex" ".ltx" ".dtx" ".drv"))
-                    (if (and (null latexenc-main-file) ;Stop at first.
-                             (file-exists-p (concat file ext)))
-                        (setq latexenc-main-file (concat file ext)))))))
+                (let ((var (match-string 1))
+                      (file (match-string 2)))
+                  (when (safe-local-variable-p (intern var) file)
+                    (dolist (ext `("" ,(if (boundp 'TeX-default-extension)
+                                           (concat "." TeX-default-extension)
+                                         "")
+                                   ".tex" ".ltx" ".dtx" ".drv"))
+                      (if (and (null latexenc-main-file) ;Stop at first.
+                               (file-exists-p (concat file ext)))
+                          (setq latexenc-main-file (concat file ext))))))))
             ;; try tex-modes tex-guess-main-file
             (when (and (not latexenc-dont-use-tex-guess-main-file-flag)
                        (not latexenc-main-file))
diff --git a/lisp/textmodes/tex-mode.el b/lisp/textmodes/tex-mode.el
index 02ee1242c72..e7b1522751f 100644
--- a/lisp/textmodes/tex-mode.el
+++ b/lisp/textmodes/tex-mode.el
@@ -89,6 +89,7 @@ tex-main-file
 if the variable is non-nil."
   :type '(choice (const :tag "None" nil)
                  file)
+  :safe #'stringp
   :group 'tex-file)
 
 ;;;###autoload
@@ -2213,6 +2214,10 @@ tex-guess-main-file
 			  header-re (+ (point) 10000) t))))
 	    (throw 'found (expand-file-name buffer-file-name))))))))
 
+(unless (get 'TeX-master 'safe-local-variable) ;Don't override AUCTeX's setting.
+  (put 'TeX-master 'safe-local-variable
+       (lambda (x) (or (booleanp x) (stringp x)))))
+
 (defun tex-main-file ()
   "Return the relative name of the main file."
   (let* ((file (or tex-main-file

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.