Subject: Re: bug#69079: [PATCH] Add 'customize-toggle-option' command

From: Philip Kaludercic <[email-masked]>
Date: Tue, 13 Feb 2024 00:14:38 +0000

Eli Zaretskii <[email-masked]> writes:

>> From: Philip Kaludercic <[email-masked]>
>> Cc: [email-masked]
>> Date: Mon, 12 Feb 2024 18:56:39 +0000
>> 
>> Eli Zaretskii <[email-masked]> writes:
>> 
>> >> From: Philip Kaludercic <[email-masked]>
>> >> Date: Mon, 12 Feb 2024 17:32:37 +0000
>> >> 
>> >> +;;;###autoload
>> >> +(defun customize-toggle-option (opt)
>> >> +  "Toggle the value of boolean option OPT for this session."
>> >> +  (interactive (let (opts)
>> >> +		 (mapatoms
>> >> +		  (lambda (sym)
>> >> +		    (when (eq (get sym 'custom-type) 'boolean)
>> >> +		      (push sym opts))))
>> >> +		 (list (intern (completing-read "Option: " opts)))))
>> >> +  (message "%s user options '%s'."
>> >> +	   (if (funcall (or (get opt 'custom-set) #'set-default)
>> >> +			opt (not (funcall (or (get opt 'custom-get)
>> >> +					      #'symbol-value)
>> >> +					  opt)))
>> >> +	       "Enabled" "Disabled")
>> >> +	   opt))
>> >
>> > Shouldn't this have some validation? what if the argument OPT is
>> > not a
>> > boolean?
>> 
>> My assumption was that the command would only be invoked interactivly,
>> so I can either make that explicit with an `interactive-only' or repeat
>> the check.  What do you think would be better?
>
> I think an explicit test is better, since then we get to display a
> user-friendly error message, instead of relying on Lisp errors to
> explain themselves.
>
> Btw, are you sure that the users can never succeed in inputting a
> non-boolean option with the way you prompt them?

No, that was not ensured, and I think it is better not to.  I have
adjusted the patch to check and prompt the user if the user option is
non-boolean, in case they know what they are doing.  WDYT?

>From abb72681c82e30a52bcfa90174e0677757174971 Mon Sep 17 00:00:00 2001
From: Philip Kaludercic <[email-masked]>
Date: Mon, 12 Feb 2024 18:29:50 +0100
Subject: [PATCH] Add 'custom-variable' command.

* lisp/cus-edit.el (customize-toggle-option): Add command.
(toggle-option): Add shorter alias for 'customize-toggle-option'.
* etc/NEWS: Document it.
---
 etc/NEWS         |  4 ++++
 lisp/cus-edit.el | 34 ++++++++++++++++++++++++++++++++++
 2 files changed, 38 insertions(+)

diff --git a/etc/NEWS b/etc/NEWS
index afc2c22e68b..6fae64728f2 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -1329,6 +1329,10 @@ in Buffer menu mode.
 *** New command 'customize-dirlocals'.
 This command pops up a buffer to edit the settings in ".dir-locals.el".
 
+---
+** New command 'customize-toggle-option'.
+This command can toggle boolean options for the duration of a session.
+
 ** Calc
 
 +++
diff --git a/lisp/cus-edit.el b/lisp/cus-edit.el
index 38b6ec984ab..270d9b44908 100644
--- a/lisp/cus-edit.el
+++ b/lisp/cus-edit.el
@@ -1227,6 +1227,40 @@ customize-option
     (unless (eq symbol basevar)
       (message "`%s' is an alias for `%s'" symbol basevar))))
 
+;;;###autoload
+(defun customize-toggle-option (symbol)
+  "Toggle the value of boolean option SYMBOL for this session."
+  (interactive (let ((prompt "Toggle boolean option: ") opts)
+                 (mapatoms
+                  (lambda (sym)
+                    (when (eq (get sym 'custom-type) 'boolean)
+                      (push sym opts))))
+                 (list (intern (completing-read prompt opts)))))
+  (let* ((setter (or (get symbol 'custom-set) #'set-default))
+         (getter (or (get symbol 'custom-get) #'symbol-value))
+         (value (condition-case nil
+                    (funcall getter symbol)
+                  (void-variable (error "`%s' is not bound" symbol))))
+         (type (get symbol 'custom-type)))
+    (cond
+     ((eq type 'boolean))
+     ((and (null type)
+           (yes-or-no-p
+            (format "`%s' doesn't have a type, and has the value %S.  \
+Proceed to toggle?" symbol value))))
+     ((yes-or-no-p
+       (format "`%s' is of type %s, and has the value %S.  \
+Proceed to toggle?"
+               symbol type value)))
+     ((error "Abort toggling of option `%s'" symbol)))
+    (message "%s user options `%s'."
+             (if (funcall setter symbol (not value))
+                 "Enabled" "Disabled")
+             symbol)))
+
+;;;###autoload
+(defalias 'toggle-option #'customize-toggle-option)
+
 ;;;###autoload
 (defalias 'customize-variable-other-window 'customize-option-other-window)
 
-- 
2.43.0