Subject: [bug#68354] [PATCH v2 2/2] etc: snippets: Add skeletons for scheme-mode.

From: Tomas Volf <[email-masked]>
Date: Tue, 16 Jan 2024 18:10:13 +0100

Some people use just plain old skeleton system, which comes with Emacs.  This
commit adds skeletons for generating package definition and some other common
parts.

* etc/snippets/skeleton/scheme.el: New file.
* doc/contributing.texi (The Perfect Setup): Document it.

Change-Id: Ided31c06266b0d3c70ae1e050ae8694fd5e47751
---
v2:
* Fix whitespace in the guix-insert-origin.

 doc/contributing.texi           |  22 ++++++
 etc/snippets/skeleton/scheme.el | 117 ++++++++++++++++++++++++++++++++
 2 files changed, 139 insertions(+)
 create mode 100644 etc/snippets/skeleton/scheme.el

diff --git a/doc/contributing.texi b/doc/contributing.texi
index 1311098dfc..b5ee046c0a 100644
--- a/doc/contributing.texi
+++ b/doc/contributing.texi
@@ -380,6 +380,28 @@ The Perfect Setup
 
 The commit message skeletons depend on @url{https://magit.vc/, Magit}.
 
+Additional skeletons for editing the package definitions are provided in
+@file{etc/snippets/skeleton/scheme.el}.
+
+@cindex @code{M-x guix-insert-package}
+@cindex @code{M-x guix-insert-origin}
+@cindex @code{M-x guix-insert-git-reference}
+@cindex @code{M-x guix-insert-hg-reference}
+@cindex @code{M-x guix-insert-svn-reference}
+@cindex @code{M-x guix-insert-bzr-reference}
+@cindex @code{M-x guix-insert-cvs-reference}
+@cindex @code{M-x guix-insert-:phases}
+Once you load the file, the following functions are provided:
+@code{guix-insert-package}, @code{guix-insert-origin},
+@code{guix-insert-git-reference}, @code{guix-insert-hg-reference},
+@code{guix-insert-svn-reference}, @code{guix-insert-bzr-reference},
+@code{guix-insert-cvs-reference} and @code{guix-insert-:phases}.  They
+do what you would expect based on the name, inserting the implied
+snippet while asking for data to fill in. @code{guix-insert-:phases}
+inserts commonly used snippet to edit phases for the package.
+
+The scheme skeletons might depend on paredit for correct indentation.
+
 @cindex insert or update copyright
 @cindex @code{M-x guix-copyright}
 @cindex @code{M-x copyright-update}
diff --git a/etc/snippets/skeleton/scheme.el b/etc/snippets/skeleton/scheme.el
new file mode 100644
index 0000000000..4e6ddad0dc
--- /dev/null
+++ b/etc/snippets/skeleton/scheme.el
@@ -0,0 +1,117 @@
+;;; scheme.el --- skeletons for scheme-mode          -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2024  Tomas Volf
+
+;; Author: Tomas Volf <[email-masked]>
+;; Keywords: convenience
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(define-skeleton guix-insert-package
+  "Insert a Guix package definition."
+  "Name: "
+  "(define-public " str
+  \n"(package"
+  \n  "(name \"" str "\")"
+  \n  "(version \"" (skeleton-read "Version: ") "\")"
+  \n  "(source " _ ")"
+  \n  "(build-system " (skeleton-read "Build system: " "gnu") "-build-system)"
+  \n  "(home-page \"" (skeleton-read "Homepage: ") "\")"
+  \n  "(synopsis " (format "%S" (skeleton-read "Synopsis: ")) ")"
+  \n  "(description " (format "%S" (skeleton-read "Description: ")) ")"
+  \n  "(license license:" (skeleton-read "License: " "unknown") ")))"
+  \n)
+
+(define-skeleton guix-insert-origin
+  "Insert a Guix origin definition."
+  nil
+  '(setq v1 (skeleton-read "Method: " "url"))
+  '(setq v1 (if (string-search "-fetch" v1)
+                v1
+              (concat v1 "-fetch")))
+  "(origin"
+  \n"(method " v1 ")"
+  \n"(uri " (let ((skeleton-end-newline nil))
+              (pcase v1
+                ((or "git-fetch" "git-fetch/lfs")
+                 (guix-insert-git-reference))
+                ("hg-fetch"
+                 (guix-insert-hg-reference))
+                ("svn-fetch"
+                 (guix-insert-svn-reference))
+                ("bzr-fetch"
+                 (guix-insert-bzr-reference))
+                ("cvs-fetch"
+                 (guix-insert-cvs-reference))
+                ("url-fetch"
+                 (insert (format "%S" (skeleton-read "URI: ")))))
+              nil)
+  ")"
+  \n (pcase v1
+       ((or "git-fetch" "git-fetch/lfs")
+        "(file-name (git-file-name name version))")
+       ("hg-fetch"
+        "(file-name (hg-file-name name version))")
+       ((or "svn-fetch" "bzr-fetch" "cvs-fetch")
+        "(file-name (string-append name \"-\" version \"-checkout\"))"))
+  & \n"(sha256"
+  \n  "(base32"
+  ;; Hash of an empty directory
+  \n  (format "%S" "0sjjj9z1dhilhpc8pq4154czrb79z9cm044jvn75kxcjv6v5l2m5") ")))")
+
+(define-skeleton guix-insert-git-reference
+  "Insert a Guix git-reference definition."
+  nil
+  "(git-reference"
+  \n"(url \"" (skeleton-read "URL: ") "\")"
+  \n"(commit \"" (skeleton-read "Commit / Tag: ") "\"))")
+
+(define-skeleton guix-insert-hg-reference
+  "Insert a Guix hg-reference definition."
+  nil
+  "(hg-reference"
+  \n"(url \"" (skeleton-read "URL: ") "\")"
+  \n"(changeset \"" (skeleton-read "Changeset: ") "\"))")
+
+(define-skeleton guix-insert-svn-reference
+  "Insert a Guix svn-reference definition."
+  nil
+  "(svn-reference"
+  \n"(url \"" (skeleton-read "URL: ") "\")"
+  \n"(revision \"" (skeleton-read "Revision: ") "\"))")
+
+(define-skeleton guix-insert-bzr-reference
+  "Insert a Guix bzr-reference definition."
+  nil
+  "(bzr-reference"
+  \n"(url \"" (skeleton-read "URL: ") "\")"
+  \n"(revision \"" (skeleton-read "Revision: ") "\"))")
+
+(define-skeleton guix-insert-cvs-reference
+  "Insert a Guix cvs-reference definition."
+  nil
+  "(cvs-reference"
+  \n"(root-directory \"" (skeleton-read "Root directory: ") "\")"
+  \n"(module \"" (skeleton-read "Module: ") "\")"
+  \n"(revision \"" (skeleton-read "Revision: ") "\"))")
+
+(define-skeleton guix-insert-:phases
+  "Insert a Guix #:phases snippet."
+  nil
+  "#:phases " \n
+  "(modify-phases %standard-phases" \n
+  _ ")")
+;;; scheme.el ends here
-- 
2.41.0