Subject: [bug#68354] [PATCH v2 1/2] etc: snippets: Add skeletons for commit messages.

From: Tomas Volf <[email-masked]>
Date: Tue, 16 Jan 2024 18:10:12 +0100

Some people use just plain old skeleton system, which comes with Emacs.  This
commit adds skeletons for generating commit messages for the common
operations (updating packages, ...).

* etc/snippets/skeleton/commit-message.el: New file.
* doc/contributing.texi (The Perfect Setup): Document it.

Change-Id: Ic37b6455a337fc431ad2b049d5b7261da97e5a06
---
 doc/contributing.texi                   |  20 ++++
 etc/snippets/skeleton/commit-message.el | 143 ++++++++++++++++++++++++
 2 files changed, 163 insertions(+)
 create mode 100644 etc/snippets/skeleton/commit-message.el

diff --git a/doc/contributing.texi b/doc/contributing.texi
index 5707ff5cde..1311098dfc 100644
--- a/doc/contributing.texi
+++ b/doc/contributing.texi
@@ -360,6 +360,26 @@ The Perfect Setup
 @code{origin} snippet in turn may insert other trigger strings ending on
 @code{...}, which also can be expanded further.
 
+@cindex skeleton
+If you use built-in skeleton system (@xref{Top,,,autotype}), you can
+load the snippets from the @file{etc/snippets/skeleton} directory.
+
+Skeletons for editing commit messages are provided in
+@file{etc/snippets/skeleton/commit-message.el}.
+
+@cindex @code{M-x guix-package-add}
+@cindex @code{M-x guix-package-remove}
+@cindex @code{M-x guix-package-update}
+@cindex @code{M-x guix-package-rename}
+@cindex @code{M-x guix-package-move}
+Once you load the file, the following functions are provided:
+@code{guix-package-add}, @code{guix-package-remove},
+@code{guix-package-update}, @code{guix-package-rename} and
+@code{guix-package-move}.  When editing a commit message, invoke the
+appropriate one using @code{M-x} to insert a message for the change.
+
+The commit message skeletons depend on @url{https://magit.vc/, Magit}.
+
 @cindex insert or update copyright
 @cindex @code{M-x guix-copyright}
 @cindex @code{M-x copyright-update}
diff --git a/etc/snippets/skeleton/commit-message.el b/etc/snippets/skeleton/commit-message.el
new file mode 100644
index 0000000000..698079a004
--- /dev/null
+++ b/etc/snippets/skeleton/commit-message.el
@@ -0,0 +1,143 @@
+;;; commit-message.el --- skeletons for Guix's commit messages  -*- lexical-binding: t; -*-
+;;; Copyright © 2024 Tomas Volf <[email-masked]>
+
+;; Author: Tomas Volf <[email-masked]>
+;; Keywords: vc, convenience
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(defun guix--package-name-from-magit-diff (regex)
+  (with-temp-buffer
+    (magit-git-wash #'magit-diff-wash-diffs "diff" "--cached")
+    (goto-char (point-min))
+    (when (re-search-forward regex
+                             nil 'noerror)
+      (match-string-no-properties 1))))
+
+(defun guix--first-file-from-magit-diff ()
+    (car (magit-staged-files)))
+
+(define-skeleton guix-package-add
+  "Insert a commit message for adding a package."
+  nil
+  '(setq v1 (or (guix--package-name-from-magit-diff
+                 (rx "+(define-public " (group (+ (not (syntax whitespace))))))
+                (skeleton-read "Package: ")))
+  '(setq v2 (or (guix--first-file-from-magit-diff)
+                (skeleton-read "File: ")))
+  ;; v1 - package, v2 - file
+  "gnu: Add " v1 "." \n
+  _ \n
+  "* " v2 " (" v1  "): New variable." \n)
+
+(define-skeleton guix-package-remove
+  "Insert a commit message for removing a package."
+  nil
+  '(setq v1 (or (guix--package-name-from-magit-diff
+                 (rx "-(define-public " (group (+ (not (syntax whitespace))))))
+                (skeleton-read "Package: ")))
+  '(setq v2 (or (guix--first-file-from-magit-diff)
+                (skeleton-read "File: ")))
+  ;; v1 - package, v2 - file
+  "gnu: Remove " v1 "." \n
+  _ \n
+  "* " v2 " (" v1  "): Delete variable." \n)
+
+(define-skeleton guix-package-update
+  "Insert a commit message for updating a package."
+  (or (guix--package-name-from-magit-diff
+       (rx line-start (* (syntax whitespace))
+           "(define-public " (group (+ (not (syntax whitespace))))))
+      (skeleton-read "Package: "))
+  '(setq v1 (or (with-temp-buffer
+                  (magit-git-wash #'magit-diff-wash-diffs
+                    "diff" "--cached")
+                  (goto-char (point-min))
+                  (search-forward "name" nil 'noerror)
+                  (search-forward "+" nil 'noerror) ; first change
+                  (when (and (search-forward "version " nil 'noerror)
+                             (looking-at-p "\""))
+                    (let ((end (save-excursion (search-forward "\")"
+                                                               nil 'noerror))))
+                      (when end
+                        (forward-char)
+                        (buffer-substring-no-properties (point) (- end 2))))))
+                (skeleton-read "New version: ")))
+  '(setq v2 (or (guix--first-file-from-magit-diff)
+                (skeleton-read "File: ")))
+  ;; str - package, v1 - new version, v2 - file
+  "gnu: " str ": Update to " v1 "." \n
+  _ \n
+  "* " v2 " (" str  "): Update to " v1 "." \n)
+
+(define-skeleton guix-package-rename
+  "Insert a commit message for renaming a package."
+  (or (guix--first-file-from-magit-diff)
+      (skeleton-read "File: "))
+  '(setq v1 (or (guix--package-name-from-magit-diff
+                 (rx "-(define-public " (group (+ (not (syntax whitespace))))))
+                (skeleton-read "Old package: ")))
+  '(setq v2 (or (guix--package-name-from-magit-diff
+                 (rx "+(define-public " (group (+ (not (syntax whitespace))))))
+                (skeleton-read "New package: ")))
+  ;; str - file, v1 - old package, v2 - new package
+  "gnu: " v1 ": Rename package to " v2 "." \n
+  _ \n
+  @
+  "* " str " (" v1 "): Define in terms of `deprecated-package'." \n
+  "(" v2 "): New variable, formerly known as `crawl'." \n
+  @
+  '(fill-region (cadr skeleton-positions) (car skeleton-positions)))
+
+(define-skeleton guix-package-move
+  "Insert a commit message for moving a package."
+  (or (guix--package-name-from-magit-diff
+       (rx "-(define-public " (group (+ (not (syntax whitespace))))))
+      (skeleton-read "Package: "))
+  '(setq v1 (or (with-temp-buffer
+                  (magit-git-wash #'magit-diff-wash-diffs
+                    "diff" "--cached" "--no-prefix")
+                  (goto-char (point-min))
+                  (when (and
+                         (re-search-forward "\\-(define-public \\(\\S-+\\)"
+                                            nil 'noerror)
+                         (re-search-backward "modified[ ]*\\(\\S-+\\)"
+                                             nil 'noerror))
+                    (match-string-no-properties 1)))
+                (skeleton-read "Old file: ")))
+  '(setq v2 (or (with-temp-buffer
+                  (magit-git-wash #'magit-diff-wash-diffs
+                    "diff" "--cached" "--no-prefix")
+                  (goto-char (point-min))
+                  (when (and
+                         (re-search-forward "\\+(define-public \\(\\S-+\\)"
+                                            nil 'noerror)
+                         (re-search-backward "modified[ ]*\\(\\S-+\\)"
+                                             nil 'noerror))
+                    (match-string-no-properties 1)))
+                (skeleton-read "New file: ")))
+  ;; str - package, v1 - old file, v2 - new file
+  "gnu: " str ": Move to ("
+  (string-replace ".scm" "" (string-replace "/" " " v2))
+  ")." \n
+  _ \n
+  @
+  "* " v1 " (" str "): Move from here..." \n
+  "* " v2 " (" str "): ...to here." \n
+  @
+  '(fill-region (cadr skeleton-positions) (car skeleton-positions)))
+
+;;; commit-message.el ends here

base-commit: b212e6934643e085f168a5364cb593f61aa616ba
-- 
2.41.0