Subject: Re: bug#66113: Apply the entire diff buffer

From: Juri Linkov <[email-masked]>
Date: Sun, 24 Sep 2023 10:34:32 +0300

>> +(defun diff-apply-buffer ()
>> +  "Apply the diff in the entire diff buffer.
>> +When applying all hunks was successful, then save the changed buffers."
>> +  (interactive)
>> +  (let ((buffer-edits nil)
>> +        (failures 0)
>> +        (diff-refine nil))
>> +    (save-excursion
>> +      (goto-char (point-min))
>> +      (diff-beginning-of-hunk t)
>> +      (while (pcase-let ((`(,buf ,line-offset ,pos ,_src ,dst ,switched)
>> +                          (diff-find-source-location nil nil)))
>> +               (cond ((and line-offset (not switched))
>> +                      (push (cons pos dst)
>> +                            (alist-get buf buffer-edits)))
>> +                     (t (setq failures (1+ failures))))
>> +               (not (or (eq (prog1 (point) (diff-hunk-next)) (point))
>> +                        (eobp))))))
>> +    (cond ((zerop failures)
>> +           (dolist (buf-edits (reverse buffer-edits))
>> +             (with-current-buffer (car buf-edits)
>> +               (dolist (edit (cdr buf-edits))
>> +                 (let ((pos (car edit))
>> +                       (dst (cdr edit))
>> +                       (inhibit-read-only t))
>> +                   (goto-char (car pos))
>> +                   (delete-region (car pos) (cdr pos))
>> +                   (insert (car dst))))
>> +               (save-buffer)))
>> +           (message "Saved %d buffers" (length buffer-edits)))
>> +          (t
>> +           (message "%d hunks failed; no buffers changed" failures)))))
>
> Sorry, was there supposed to be a call to diff-test-hunk here? Or I'm just
> not following the implementation.

diff-test-hunk was just an example of implementation.  But the same way as
diff-apply-hunk is not used here, also only the logic of diff-test-hunk is used.

> I tried testing it out too. There is a patch where the third hunk doesn't
> apply (errors with "can't find the text to patch" in regular usage). This
> command ends with cryptic "No next hunk".

This is what I expected that diff-hunk-next might signal an error
that we should catch, but still couldn't find a patch that fails
with such error.  So I will try to construct such a patch manually.