Subject: Re: bug#64619: [PATCH] Add toggle-window-dedicated command

From: [email-masked]
Date: Sat, 19 Aug 2023 20:02:35 +0000 (UTC)

Philip Kaludercic <[email-masked]> writes:

> [email-masked] writes:
>
>> Philip Kaludercic <[email-masked]> writes:
>>
>>> [email-masked] writes:
>>>
>>>> Spencer Baugh <[email-masked]> writes:
>>>>> OK, this patch adds support for making the buffer strongly dedicated
>>>>> with a prefix argument, and also adds an indicator to the mode line of
>>>>> whether the current window is dedicated (which seems useful even if we
>>>>> don't apply the toggle part of this patch).
>>>>
>>>> Any thoughts on this patch?
>>>
>>> I just tried it out and it works as advertised.  The only question is if
>>> a NEWS entry should be added, or if it is worth mentioning it in the
>>> manual?
>>
>> Yes, I think definitely a NEWS entry is warranted, if only because it
>> adds an indicator the mode line.  But I wanted to settle the format
>> before writing it.
>
> I think it is fine the way it is right now.

OK, added a NEWS entry and information in the manual.

>From dc02ad0891c3a832617d6b234bd30a0bc8f8ef69 Mon Sep 17 00:00:00 2001
From: Spencer Baugh <[email-masked]>
Date: Sat, 19 Aug 2023 16:01:54 -0400
Subject: [PATCH] Add toggle-window-dedicated command and
 mode-line-window-dedicated

It's sometimes useful to interactively make certain windows dedicated.
This allows a level of interactive control over which window
display-buffer uses.

Additionally, when a window is dedicated (even without this new
command) it can affect display-buffer behavior in ways which may be
unexpected for users.  Let's display the window dedicated status in
the mode-line to help indicate what's going on.

* doc/emacs/windows.texi (Displaying Buffers): Add information about
dedicated windows and toggle-window-dedicated.
* etc/NEWS: Announce the mode-line-window-dedicated and
toggle-window-dedicated.
* lisp/window.el (toggle-window-dedicated): Add.
(window-prefix-map): Add C-x w d binding.
* lisp/bindings.el (mode-line-window-control): Add.
(mode-line-window-dedicated): Add.
(standard-mode-line-format): Insert mode-line-window-dedicated.
---
 doc/emacs/windows.texi | 16 ++++++++++++++++
 etc/NEWS               | 14 ++++++++++++++
 lisp/bindings.el       | 22 ++++++++++++++++++++++
 lisp/window.el         | 28 ++++++++++++++++++++++++++++
 4 files changed, 80 insertions(+)

diff --git a/doc/emacs/windows.texi b/doc/emacs/windows.texi
index e4abdef76be..f24ffc20464 100644
--- a/doc/emacs/windows.texi
+++ b/doc/emacs/windows.texi
@@ -411,6 +411,22 @@ Displaying Buffers
 window on some other frame to display the desired buffer.  Several of
 these commands are bound in the @kbd{C-x 5} prefix key.
 
+  Sometimes, a window is ``dedicated'' to its current buffer.
+@code{display-buffer} will avoid reusing dedicated windows most of the
+time.  This is indicated by a ``d'' in the mode line.  A window can
+also be strongly dedicated, which prevents any changes to what buffer
+that window displays; this is indicated by a ``D'' in the mode line.
+
+Usually, dedicated windows are used to display specialized buffers,
+but dedication can sometimes be useful to interactively control
+@code{display-buffer}'s window choices.
+
+@kindex C-x w d
+@findex toggle-window-dedicated
+  Toggle whether the current window is dedicated to the current
+buffer.  With a prefix argument, make the window strongly dedicated
+instead.
+
 @menu
 * Window Choice::   How @code{display-buffer} works.
 * Temporary Displays::   Displaying non-editable buffers.
diff --git a/etc/NEWS b/etc/NEWS
index 3cfc36e10da..6368d640fb7 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -92,6 +92,20 @@ plus, minus, check-mark, start, etc.
 The 'tool-bar-position' frame parameter can be set to 'bottom' on all
 window systems other than Nextstep.
 
++++
+** 'd' in the mode line now indicates that the window is dedicated.
+Windows have always been able to be dedicated to a specific buffer;
+see 'window-dedicated-p'.  Now the mode line indicates the dedicated
+status of a window, with 'd' appearing in the mode line if a window is
+dedicated and 'D' if the window is strongly dedicated.
+
++++
+** New command 'toggle-window-dedicated'.
+This makes it easy to interactively mark a specific window as
+dedicated, so it won't be reused by 'display-buffer'.  This can be
+useful for complicated window setups.  It is bound to 'C-x w d'
+globally.
+
 ** cl-print
 *** You can expand the "..." truncation everywhere.
 The code that allowed "..." to be expanded in the *Backtrace* should
diff --git a/lisp/bindings.el b/lisp/bindings.el
index f1a75b080be..b751fed22ce 100644
--- a/lisp/bindings.el
+++ b/lisp/bindings.el
@@ -298,6 +298,27 @@ mode-line-frame-identification
 ;;;###autoload
 (put 'mode-line-frame-identification 'risky-local-variable t)
 
+(defun mode-line-window-control ()
+  "Compute mode line construct for window dedicated state.
+Value is used for `mode-line-window-dedicated', which see."
+  (cond
+   ((eq (window-dedicated-p) t)
+   '(:propertize
+     " D"
+     help-echo "Window is strongly dedicated to current buffer"
+     mouse-face 'mode-line-highlight))
+   ((window-dedicated-p)
+   '(:propertize
+     " d"
+     help-echo "Window is dedicated to current buffer"
+     mouse-face 'mode-line-highlight))
+   (t "")))
+
+(defvar mode-line-window-dedicated '(:eval (mode-line-window-control))
+  "Mode line construct to describe the current window.")
+;;;###autoload
+(put 'mode-line-window-dedicated 'risky-local-variable t)
+
 (defvar-local mode-line-process nil
   "Mode line construct for displaying info on process status.
 Normally nil in most modes, since there is no process to display.")
@@ -675,6 +696,7 @@ mode-line-end-spaces
 	            'mode-line-modified
 	            'mode-line-remote)
               'display '(min-width (5.0)))
+             'mode-line-window-dedicated
 	     'mode-line-frame-identification
 	     'mode-line-buffer-identification
 	     "   "
diff --git a/lisp/window.el b/lisp/window.el
index d91bbabc010..259c1e679ac 100644
--- a/lisp/window.el
+++ b/lisp/window.el
@@ -7463,6 +7463,33 @@ display-buffer-mark-dedicated
 The actual non-nil value of this variable will be copied to the
 `window-dedicated-p' flag.")
 
+(defun toggle-window-dedicated (&optional window flag interactive)
+  "Toggle whether WINDOW is dedicated.
+
+See `set-window-dedicated-p' for more details.  WINDOW defaults
+to the currently selected window.  FLAG defaults to
+`dedicated' (weak dedication) or `t' (strong dedication) with a
+prefix argument.  If INTERACTIVE is non-nil, will print a message
+about the dedication status of the window afterwards."
+  (interactive "i\nP\np")
+  (setq window (window-normalize-window window))
+  (setq flag (cond
+              ((consp flag) t)
+              ((null flag) 'dedicated)
+              (t flag)))
+  (if (window-dedicated-p window)
+      (set-window-dedicated-p window nil)
+    (set-window-dedicated-p window flag))
+  (when interactive
+    (message "Window is %s dedicated to buffer %s"
+             (let ((status (window-dedicated-p window)))
+               (cond
+                ((null status) "no longer")
+                ((eq status t) "now strongly")
+                (t "now")))
+             (current-buffer))
+    (force-mode-line-update)))
+
 (defconst display-buffer--action-function-custom-type
   '(choice :tag "Function"
 	   (const :tag "--" ignore) ; default for insertion
@@ -10746,6 +10773,7 @@ window-prefix-map
   "2" #'split-root-window-below
   "3" #'split-root-window-right
   "s" #'window-toggle-side-windows
+  "d" #'toggle-window-dedicated
   "^ f" #'tear-off-window
   "^ t" #'tab-window-detach
   "-" #'fit-window-to-buffer
-- 
2.41.0