Subject: bug#64531: [PATCH] Add new command vc-dir-copy-filename-as-kill

From: Ivan Sokolov <[email-masked]>
Date: Sat, 08 Jul 2023 10:51:53 +0300

Hi!

This new command is inspired by `dired-copy-filename-as-kill', but has a
few differences, that can be easily reversed if there is such need.

Changes:
1. even single filename is quoted;
2. filenames are relative by default, prefix makes them absolute;
3. value of prefix argument does not matter, in dired it has to be 0.

I bound it to the `w' key because `w' is currently unbound in
vc-dir-mode-map and it is what is used in dired.

>From d2edc8052d3f8a34b4f28f6721cb2b2ceca1d4a5 Mon Sep 17 00:00:00 2001
From: Ivan Sokolov <[email-masked]>
Date: Sat, 8 Jul 2023 10:34:18 +0300
Subject: [PATCH] Add new command vc-dir-copy-filename-as-kill

---
 lisp/vc/vc-dir.el | 19 +++++++++++++++++++
 1 file changed, 19 insertions(+)

diff --git a/lisp/vc/vc-dir.el b/lisp/vc/vc-dir.el
index 53d58870b32..e348f1027ab 100644
--- a/lisp/vc/vc-dir.el
+++ b/lisp/vc/vc-dir.el
@@ -353,6 +353,7 @@ See `run-hooks'."
     (define-key map (kbd "M-s a C-s")   #'vc-dir-isearch)
     (define-key map (kbd "M-s a M-C-s") #'vc-dir-isearch-regexp)
     (define-key map "G" #'vc-dir-ignore)
+    (define-key map "w" #'vc-dir-copy-filename-as-kill)
 
     (let ((branch-map (make-sparse-keymap)))
       (define-key map "b" branch-map)
@@ -930,6 +931,24 @@ system."
   (interactive)
   (view-file (vc-dir-current-file)))
 
+(defun vc-dir-copy-filename-as-kill (&optional absolutep)
+  "Copy names of marked files (or file under cursor) into the kill ring.
+If there are severals names, they will be separated by a space.
+Names are always quoted using `shell-quote-argument'.
+
+If ABSOLUTEP use the absolute names, otherwise names are relative
+to the `default-directory'."
+  (interactive "P")
+  (let ((files (or (vc-dir-marked-files)
+                   (list (vc-dir-current-file)))))
+    (unless absolutep
+      (setq files (mapcar #'file-relative-name files)))
+    (let ((string (mapconcat #'shell-quote-argument files " ")))
+      (if (eq last-command 'kill-region)
+          (kill-append string nil)
+        (kill-new string))
+      (message "%s" string))))
+
 (defun vc-dir-isearch ()
   "Search for a string through all marked buffers using Isearch."
   (interactive)
-- 
2.40.1