Subject: bug#64126: [PATCH] New command 'eww-copy-alternate-url'

From: Eshel Yaron <[email-masked]>
Date: Sat, 17 Jun 2023 14:07:40 +0300

Tags: patch

This patch extends EWW with a command that grabs the URL of an alternate
link of the current page, such as an RSS or Atom feed.

In GNU Emacs 30.0.50 (build 5, x86_64-apple-darwin22.5.0, NS
 appkit-2299.60 Version 13.4 (Build 22F66)) of 2023-06-16 built on
 Dazzs-MBP
Repository revision: 8657afac774f36777d0fdd368e0bec64beca22ae
Repository branch: master
Windowing system distributor 'Apple', version 10.3.2299
System Description:  macOS 13.4

Configured using:
 'configure 'CFLAGS=-g0 -O3' --with-native-compilation --with-json
 --with-imagemagick --with-tree-sitter --enable-link-time-optimization'

>From 998f3048bd0a804b861140991e3c62cf3c42e9ed Mon Sep 17 00:00:00 2001
From: Eshel Yaron <[email-masked]>
Date: Sat, 17 Jun 2023 13:48:51 +0300
Subject: [PATCH] New command 'eww-copy-alternate-url'

This adds a new command to EWW that copies an alternate link to the
currently visited page into the kill ring.  This is useful for
subscribing to website feeds, etc..

* lisp/net/eww.el (eww--alternate-urls)
(eww-read-alternate-url): New functions.
(eww-copy-alternate-url): New command.
(eww-mode-map): Bind it to 'A'.

* doc/misc/eww.texi (Basics): Document it.

* etc/NEWS: Announce it.
---
 doc/misc/eww.texi |  7 +++++
 etc/NEWS          |  5 ++++
 lisp/net/eww.el   | 75 +++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 87 insertions(+)

diff --git a/doc/misc/eww.texi b/doc/misc/eww.texi
index c02e9db11c9..2f2a1d7d405 100644
--- a/doc/misc/eww.texi
+++ b/doc/misc/eww.texi
@@ -115,6 +115,13 @@ Basics
 @kbd{w} calls @code{eww-copy-page-url}, which will copy the current
 page's URL to the kill ring instead.
 
+@findex eww-copy-alternate-url
+@kindex A
+  The @kbd{A} command (@code{eww-copy-alternate-url}) copies the URL
+of an alternate link of the current page (such as an associated RSS
+feed) into the kill ring.  If the page specifies multiple alternate
+links, this command prompt for one of them in the minibuffer.
+
 @findex eww-open-in-new-buffer
 @kindex M-RET
   The @kbd{M-@key{RET}} command (@code{eww-open-in-new-buffer}) opens the
diff --git a/etc/NEWS b/etc/NEWS
index 61e6e161665..7c94c3efa89 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -253,6 +253,11 @@ The interactive minibuffer prompt when invoking 'eww' now provides
 completions from 'eww-suggest-uris'.  'eww-suggest-uris' now includes
 bookmark URIs.
 
++++
+*** New command 'eww-copy-alternate-url'.
+It copies an alternate link to the page currently visited in EWW into
+the kill ring.
+
 ** go-ts-mode
 
 +++
diff --git a/lisp/net/eww.el b/lisp/net/eww.el
index 61f0f47373d..3ce9061ea7d 100644
--- a/lisp/net/eww.el
+++ b/lisp/net/eww.el
@@ -1086,6 +1086,7 @@ eww-mode-map
   "&" #'eww-browse-with-external-browser
   "d" #'eww-download
   "w" #'eww-copy-page-url
+  "A" #'eww-copy-alternate-url
   "C" #'url-cookie-list
   "v" #'eww-view-source
   "R" #'eww-readable
@@ -2576,4 +2577,78 @@ eww-bookmark-jump
 
 (provide 'eww)
 
+;;; Alternate links (RSS and Atom feeds, etc.)
+
+(defun eww--alternate-urls (dom &optional base)
+  "Return an alist of alternate links in DOM.
+
+Each element is a list of the form (URL TYPE TITLE) where URL is
+the href attribute of the link expanded relative to BASE, TYPE is
+its type attribute, and TITLE is its title attribute.  If any of
+these attributes is absent, the corresponding element is nil."
+  (let ((alternates
+         (seq-filter
+          (lambda (attrs) (string= (alist-get 'rel attrs)
+                                   "alternate"))
+          (mapcar #'dom-attributes (dom-by-tag dom 'link)))))
+    (mapcar (lambda (alternate)
+              (list (url-expand-file-name (alist-get 'href alternate)
+                                          base)
+                    (alist-get 'type  alternate)
+                    (alist-get 'title alternate)))
+            alternates)))
+
+(defun eww-read-alternate-url ()
+  "Get the URL of an alternate link of this page.
+
+If there is just one alternate link, return it's URL.  If there
+are multiple alternate links, prompt for one in the minibuffer.
+If there are none, return nil."
+  (when-let ((alternates (eww--alternate-urls
+                          (plist-get eww-data :dom)
+                          (plist-get eww-data :url))))
+    (let ((max-length
+           (apply #'max
+                  (mapcar #'length
+                          (mapcar #'car alternates))))
+          (max-title
+           (apply #'max
+                  (mapcar #'length
+                          (mapcar #'caddr alternates)))))
+      (if (cdr alternates)
+          (let ((completion-extra-properties
+                 (list :annotation-function
+                       (lambda (feed)
+                         (let* ((attrs (alist-get feed
+                                                  alternates
+                                                  nil
+                                                  nil
+                                                  #'string=))
+                                (type (car attrs))
+                                (title (cadr attrs)))
+                           (concat (when title
+                                     (concat (make-string
+                                              (1+ (- max-length
+                                                     (length feed)))
+                                              ?\s)
+                                             title))
+                                   (when type
+                                     (concat
+                                      (make-string
+                                       (1+ (- max-title
+                                              (length title)))
+                                       ?\s)
+                                      "[" type "]"))))))))
+            (completing-read "Alternate URL: " alternates nil t))
+        (caar alternates)))))
+
+(defun eww-copy-alternate-url ()
+  "Copy an alternate URL of the current page into the kill ring."
+  (interactive nil eww-mode)
+  (if-let ((url (eww-read-alternate-url)))
+      (progn
+        (kill-new url)
+        (message "Copied %s to kill ring" url))
+    (user-error "No feeds found!")))
+
 ;;; eww.el ends here
-- 
2.41.0