GNU bug report logs - #61483
[PATCH 0/5] Some basic Home Shepherd Services

Previous Next

Full log

View this message in rfc822 format

From: "Jan (janneke) Nieuwenhuizen" <janneke <at> gnu.org>
To: 61483 <at> debbugs.gnu.org
Subject: [bug#61483] [PATCH v2 2/5] DRAFT gnu: home: services: Add home-ssh-agent-service-type.
Date: Thu, 16 Feb 2023 16:53:52 +0100

* gnu/home/services/shepherd-xyz.scm
(<home-ssh-agent-configuration>): New type.
(home-ssh-agent-services): New procedure.
(home-ssh-agent-service-type): New variable.
---
 gnu/home/services/shepherd-xyz.scm | 60 +++++++++++++++++++++++++++++-
 1 file changed, 59 insertions(+), 1 deletion(-)

diff --git a/gnu/home/services/shepherd-xyz.scm b/gnu/home/services/shepherd-xyz.scm
index 4d84008dae..75f3770ffc 100644
--- a/gnu/home/services/shepherd-xyz.scm
+++ b/gnu/home/services/shepherd-xyz.scm
@@ -25,6 +25,7 @@ (define-module (gnu home services shepherd-xyz)
 
   #:use-module (gnu home services)
   #:use-module (gnu home services shepherd)
+  #:use-module (gnu packages ssh)
   #:use-module (gnu packages version-control)
   #:use-module (gnu services configuration)
   #:use-module (gnu services shepherd)
@@ -32,7 +33,9 @@ (define-module (gnu home services shepherd-xyz)
   #:use-module (guix gexp)
 
   #:export (home-git-daemon-configuration
-            home-git-daemon-service-type))
+            home-git-daemon-service-type
+            home-ssh-agent-configuration
+            home-ssh-agent-service-type))
 
 ;;; Commentary:
 ;;
@@ -46,6 +49,15 @@ (define-module (gnu home services shepherd-xyz)
 ;;          (home-git-configuration
 ;;           (root (string-append (getenv "HOME") "/src"))))
 ;;
+;; Ssh-agent
+;;
+;; Add to your ~/.bash_profile:
+;;
+;; SSH_AUTH_SOCK=${XDG_RUNTIME_DIR-$HOME/.cache}/ssh-agent/socket
+;; export SSH_AUTH_SOCK
+;;
+;; (service home-ssh-agent-service-type)
+;;
 ;;; Code:
 
 ;;;
@@ -120,3 +132,49 @@ (define home-git-daemon-service-type
                              home-git-daemon-services)))
    (description
     "Install and configure the git-daemon as a shepherd service.")))
+
+
+;;;
+;;; Ssh-agent.
+;;;
+(define-record-type* <home-ssh-agent-configuration>
+  home-ssh-agent-configuration make-home-ssh-agent-configuration
+  home-ssh-agent-configuration?
+  (openssh       home-ssh-agent-openssh       ;file-like
+                 (default openssh))
+  (socket-dir    home-ssh-agent-socket-dir    ;string
+                 (default (string-append %user-runtime-dir "/ssh-agent")))
+  (extra-options home-ssh-agent-extra-options ;list of string
+                 (default '())))
+
+(define (home-ssh-agent-services config)
+  "Return a <shepherd-service> for an ssh-agent with CONFIG."
+  (match config
+    (($ <home-ssh-agent-configuration>
+        openssh socket-dir extra-options)
+     (let* ((ssh-agent (file-append openssh "/bin/ssh-agent"))
+            (socket-file (string-append socket-dir "/socket"))
+            (command `(,ssh-agent
+                       "-D"
+                       "-a" ,socket-file
+                       ,@extra-options))
+            (log-file (string-append %user-log-dir "/ssh-agent.log")))
+       (list (shepherd-service
+              (documentation "Run the ssh-agent.")
+              (provision '(ssh-agent))
+              (start #~(lambda _
+                         (unless (file-exists? #$socket-dir)
+                           (mkdir-p #$socket-dir)
+                           (chmod #$socket-dir #o700))
+                         (fork+exec-command '#$command #:log-file #$log-file)))
+              (stop #~(make-kill-destructor))))))))
+
+(define home-ssh-agent-service-type
+  (service-type
+   (name 'home-ssh-agent)
+   (default-value (home-ssh-agent-configuration))
+   (extensions
+    (list (service-extension home-shepherd-service-type
+                             home-ssh-agent-services)))
+   (description
+    "Install and configure the ssh-agent as a shepherd service.")))
-- 
2.38.1

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.