Subject: bug#59786: closed (Re: bug#59786: Allowing arbitrary expressions in cl-labels)

From: [email-masked] (GNU bug Tracking System)
Date: Wed, 13 Nov 2024 04:06:02 +0000

Your bug report

#59786: Allowing arbitrary expressions in cl-labels

which was filed against the emacs package, has been closed.

The explanation is attached below, along with your original report.
If you require more details, please reply to [email-masked].

-- 
59786: https://debbugs.gnu.org/cgi/bugreport.cgi?bug=59786
GNU Bug Tracking System
Contact [email-masked] with problems

Subject: Re: bug#59786: Allowing arbitrary expressions in cl-labels
From: Stefan Monnier <[email-masked]>
To: Michael Heerdegen <[email-masked]>
Cc: [email-masked]
Date: Tue, 12 Nov 2024 23:04:56 -0500
List-Id: <debbugs-submit.debbugs.gnu.org>

Pushed to `master`, closing,

        Stefan

Subject: Allowing arbitrary expressions in cl-labels
From: Stefan Monnier <[email-masked]>
To: [email-masked]
Date: Fri, 02 Dec 2022 14:44:13 -0500
List-Id: <debbugs-submit.debbugs.gnu.org>

Tags: patch

I have found some circumstances where I'd like to write things like:

    (cl-labels ((f1 (if blabla
                        (lambda (x) (do one thing))
                      (lambda (x) (do another thing))))
                (f2 (if bleble
                        (lambda (y) (do some thing))
                      (lambda (y) (do some other thing)))))
      ...)

I.e. define two, mutually-recursive functions, but where I want to
perform some computation before "building/returning" each function.

I could rewrite the above to

    (cl-labels ((f1 (x) (if blabla
                            (do one thing)
                          (do another thing)))
                (f2 (y) (if bleble
                            (do some thing)
                          (do some other thing))))
      ...)

but then the `if` tests are repeated at each call.
I could also rewrite it to

    (letrec ((f1 (if blabla
                     (lambda (x) (do one thing))
                   (lambda (x) (do another thing))))
             (f2 (if bleble
                     (lambda (y) (do some thing))
                   (lambda (y) (do some other thing)))))
      ...)

but then I have to use (funcall f1 ..) and (funcall f2 ...) instead of
just (f1 ...) and (f2 ...).  I could add a (cl-flet ((f1 f1) (f2 f2)) ...)
but that's inconvenient, especially because I'd have to add it in
various places.

So I'd like to propose to extend `cl-labels` in the same way that
`cl-flet` was extended to allow each function to be defined by an
expression that returns a function rather than by "args + body".

One option is to use the same approach as I used in `cl-flet`,
i.e. allow each binding to be either

    (FUNC ARGS BODY...)    the normal existing syntax
or
    (FUNC EXP)             the new syntax

After I introduced this in `cl-flet` it was pointed out that it was an
incompatible change since BODY... can be the empty list.  Another option
is to use a syntax like:

    (FUNC = EXP)           the new new syntax

which should not suffer from such incompatibility since ARGS should
never be of the form `=`.

The patch below uses this "new new" syntax (and adjusts `cl-flet` to
also support this new new syntax).  It still lacks a NEWS entry (as
well as updating the CL manual), but before I do that, I'd like to hear
what other people think,

        Stefan

 In GNU Emacs 30.0.50 (build 1, x86_64-pc-linux-gnu, X toolkit, cairo
 version 1.16.0, Xaw3d scroll bars) of 2022-11-29 built on pastel
Repository revision: 4254a4a71d5d04cfcefaedfefe5d22af55650a6a
Repository branch: work
Windowing system distributor 'The X.Org Foundation', version 11.0.12011000
System Description: Debian GNU/Linux 11 (bullseye)

Configured using:
 'configure -C --enable-checking --enable-check-lisp-object-type --with-modules --with-cairo --with-tiff=ifavailable
 'CFLAGS=-Wall -g3 -Og -Wno-pointer-sign'
 PKG_CONFIG_PATH=/home/monnier/lib/pkgconfig'

diff --git a/lisp/emacs-lisp/cl-macs.el b/lisp/emacs-lisp/cl-macs.el
index 43a2ed92059..cc8c98f2264 100644
--- a/lisp/emacs-lisp/cl-macs.el
+++ b/lisp/emacs-lisp/cl-macs.el
@@ -2028,11 +2028,11 @@ cl--labels-convert
 ;;;###autoload
 (defmacro cl-flet (bindings &rest body)
   "Make local function definitions.
-Each definition can take the form (FUNC EXP) where
+Each definition can take the form (FUNC = EXP) where
 FUNC is the function name, and EXP is an expression that returns the
 function value to which it should be bound, or it can take the more common
 form (FUNC ARGLIST BODY...) which is a shorthand
-for (FUNC (lambda ARGLIST BODY)).
+for (FUNC = (lambda ARGLIST BODY)).
 
 FUNC is defined only within FORM, not BODY, so you can't write
 recursive function definitions.  Use `cl-labels' for that.  See
@@ -2055,8 +2055,12 @@ cl-flet
         (if (and (= (length args-and-body) 1) (symbolp (car args-and-body)))
             ;; Optimize (cl-flet ((fun var)) body).
             (setq var (car args-and-body))
-          (push (list var (if (= (length args-and-body) 1)
-                              (car args-and-body)
+          (push (list var (cond
+                           ((= (length args-and-body) 1) ;Obsolete syntax.
+                            (car args-and-body))
+                           ((eq '= (car args-and-body))
+                            (macroexp-progn (cdr args-and-body)))
+                           (t
                             `(cl-function (lambda . ,args-and-body))))
                 binds))
 	(push (cons (car binding)
@@ -2203,12 +2207,13 @@ cl--self-tco
 ;;;###autoload
 (defmacro cl-labels (bindings &rest body)
   "Make local (recursive) function definitions.
-+BINDINGS is a list of definitions of the form (FUNC ARGLIST BODY...) where
-FUNC is the function name, ARGLIST its arguments, and BODY the
-forms of the function body.  FUNC is defined in any BODY, as well
-as FORM, so you can write recursive and mutually recursive
-function definitions.  See info node `(cl) Function Bindings' for
-details.
+BINDINGS is a list of definitions of the form either:
+- (FUNC ARGLIST BODY...) where FUNC is the function name,
+  ARGLIST its arguments, and BODY the forms of the function body.
+- (FUNC = BODY) where BODY is an expression that evaluates to a function.
+FUNC is defined in any BODY, as well as FORM, so you can write recursive
+and mutually recursive function definitions.
+See info node `(cl) Function Bindings' for details.
 
 \(fn ((FUNC ARGLIST BODY...) ...) FORM...)"
   (declare (indent 1) (debug cl-flet))
@@ -2226,17 +2231,31 @@ cl-labels
     (unless (assq 'function newenv)
       (push (cons 'function #'cl--labels-convert) newenv))
     ;; Perform self-tail call elimination.
-    (setq binds (mapcar
-                 (lambda (bind)
-                   (pcase-let*
-                       ((`(,var ,sargs . ,sbody) bind)
-                        (`(function (lambda ,fargs . ,ebody))
-                         (macroexpand-all `(cl-function (lambda ,sargs . ,sbody))
-                                          newenv))
-                        (`(,ofargs . ,obody)
-                         (cl--self-tco var fargs ebody)))
-                     `(,var (function (lambda ,ofargs . ,obody)))))
-                 (nreverse binds)))
+    (setq binds
+          (mapcar
+           (lambda (bind)
+             (pcase-let*
+                 ((`(,var ,sargs . ,sbody) bind))
+               (list var
+                     (named-let loop
+                         ((mfunexp (macroexpand-all
+                                    (if (eq '= sargs)
+                                        (macroexp-progn sbody)
+                                      `(cl-function (lambda ,sargs . ,sbody)))
+                                    newenv)))
+                       (pcase mfunexp
+                         (`#'(lambda ,fargs . ,ebody)
+                          `#'(lambda . ,(cl--self-tco var fargs ebody)))
+                         (`(progn . ,exps)
+                          `(progn ,@(butlast exps) ,(loop (car (last exps)))))
+                         (`(let ,bindings ,exps)
+                          `(let ,bindings
+                             ,@(butlast exps) ,(loop (car (last exps)))))
+                         (`(if ,exp1 ,exp2 ,exps)
+                          `(if ,exp1 ,(loop exp2)
+                             ,@(butlast exps) ,(loop (car (last exps)))))
+                         (_ mfunexp))))))
+           (nreverse binds)))
     `(letrec ,binds
        . ,(macroexp-unprogn
            (macroexpand-all