GNU bug report logs - #58208
[PATCH 0/7] Add Sonic Visualiser and VAMP plugins.

Previous Next

To reply to this bug, email your comments to 58208 AT debbugs.gnu.org.

Toggle the display of automated, internal messages from the tracker.

Message #5 received at submit <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: guix-patches <at> gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 0/7] Add Sonic Visualiser and VAMP plugins.
Date: Fri, 30 Sep 2022 19:19:07 -0500

Adds Sonic Visualiser as well as a set of VAMP plugins in order to provide
annotation and analysis functionality, as Sonic Visualiser is a VAMP host. One
of Sonic Visualiser's dependencies, oggz, was marked as a TODO to add on another
package, so add it there as well. Finally, make sure all VAMP plugins (known to
me) are added to the VAMP_PATH search path for use in a host.

Lilah Tascheter (7):
  gnu: Add oggz.
  gnu: libkate: Add optional input oggz.
  gnu: Add libfishsound.
  gnu: Add sonic-visualiser.
  gnu: Add VAMP plugins to VAMP_PATH.
  gnu: Add vamp-aubio-plugins.
  gnu: Add nnls-chroma.

 gnu/packages/audio.scm | 134 +++++++++++++++++++++++++++++++++++++++++
 gnu/packages/xiph.scm  |  45 +++++++++++++-
 2 files changed, 177 insertions(+), 2 deletions(-)


base-commit: 0dec41f329c37a4293a2a8326f1fe7d9318ec455
-- 
2.37.2

Message #8 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 2/7] gnu: libkate: Add optional input oggz.
Date: Fri, 30 Sep 2022 19:22:35 -0500

* gnu/packages/xiph.scm (libkate)[inputs]: Add optional input oggz.
---
 gnu/packages/xiph.scm | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/gnu/packages/xiph.scm b/gnu/packages/xiph.scm
index b97d2a0553..112b8ddf87 100644
--- a/gnu/packages/xiph.scm
+++ b/gnu/packages/xiph.scm
@@ -293,8 +293,7 @@ (define-public libkate
               "0s3vr2nxfxlf1k75iqpp4l78yf4gil3f0v778kvlngbchvaq23n4"))))
    (build-system gnu-build-system)
    (native-inputs (list doxygen bison pkg-config))
-   ;; FIXME: Add optional input liboggz
-   (inputs (list libogg libpng python-wrapper zlib))
+   (inputs (list libogg oggz libpng python-wrapper zlib))
    (synopsis "Karaoke and text codec for embedding in ogg")
    (description
     "Kate is an overlay codec, originally designed for karaoke and text,
-- 
2.37.2

Message #11 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 1/7] gnu: Add oggz.
Date: Fri, 30 Sep 2022 19:22:34 -0500

* gnu/packages/xiph.scm (oggz): New variable.
---
 gnu/packages/xiph.scm | 21 +++++++++++++++++++++
 1 file changed, 21 insertions(+)

diff --git a/gnu/packages/xiph.scm b/gnu/packages/xiph.scm
index dffad299e9..b97d2a0553 100644
--- a/gnu/packages/xiph.scm
+++ b/gnu/packages/xiph.scm
@@ -259,6 +259,27 @@ (define-public flac
                                "See COPYING in the distribution.")) ; and LGPL and GPL
    (home-page "https://xiph.org/flac/")))
 
+(define-public oggz
+  (package
+    (name "oggz")
+    (version "1.1.1")
+    (source (origin
+             (method url-fetch)
+             (uri (string-append "https://downloads.xiph.org/releases/liboggz/"
+                                 "liboggz-" version ".tar.gz"))
+             (sha256
+               (base32
+                 "0nj17lhnsw4qbbk8jy4j6a78w6v2llhqdwq46g44mbm9w2qsvbvb"))))
+    (build-system gnu-build-system)
+    (inputs (list libogg))
+    (propagated-inputs (list util-linux)) ;; for getopt in oggz-diff
+    (synopsis "Library and cli tool for working with Ogg files")
+    (description "A C library for reading and writing Ogg files and streams in
+multiple formats, bundled with cli tools to inspect, validate, crop, and edit
+Ogg files.")
+    (license license:bsd-3)
+    (home-page "https://xiph.org/oggz/")))
+
 (define-public libkate
   (package
    (name "libkate")
-- 
2.37.2

Message #14 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 3/7] gnu: Add libfishsound.
Date: Fri, 30 Sep 2022 19:22:36 -0500

* gnu/packages/xiph.scm (libfishsound): New variable.
---
 gnu/packages/xiph.scm | 21 +++++++++++++++++++++
 1 file changed, 21 insertions(+)

diff --git a/gnu/packages/xiph.scm b/gnu/packages/xiph.scm
index 112b8ddf87..3f2fb6a6f7 100644
--- a/gnu/packages/xiph.scm
+++ b/gnu/packages/xiph.scm
@@ -280,6 +280,27 @@ (define-public oggz
     (license license:bsd-3)
     (home-page "https://xiph.org/oggz/")))
 
+(define-public libfishsound
+  (package
+    (name "libfishsound")
+    (version "1.0.0")
+    (source (origin
+             (method url-fetch)
+             (uri (string-append
+                    "https://downloads.xiph.org/releases/libfishsound/"
+                    "libfishsound-" version ".tar.gz"))
+             (sha256
+               (base32
+                 "1iz7mn6hw2wg8ljaw74f4g2zdj68ib88x4vjxxg3gjgc5z75f2rf"))))
+    (build-system gnu-build-system)
+    (inputs (list libvorbis speex))
+    (synopsis "Library for encoding and decoing Xiph.org codecs")
+    (description "A C library wrapping individual Xiph.org codecs, including
+FLAC, Speex, and Vorbis, providing a unified higher-level interface for handling
+raw codec streams.")
+    (license license:bsd-3)
+    (home-page "https://xiph.org/fishsound/")))
+
 (define-public libkate
   (package
    (name "libkate")
-- 
2.37.2

Message #17 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 4/7] gnu: Add sonic-visualiser.
Date: Fri, 30 Sep 2022 19:22:37 -0500

* gnu/packages/audio.scm (sonic-visualiser): New variable.
---
 gnu/packages/audio.scm | 45 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index fd27c1cc71..0dd0b8ff55 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -5895,3 +5895,48 @@ (define-public streamripper
 separation data, and uses that as a marker for where the track should
 be separated.")
     (license license:gpl2+)))
+
+(define-public sonic-visualiser
+  (package
+    (name "sonic-visualiser")
+    (version "4.5")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                     "https://github.com/sonic-visualiser/sonic-visualiser"
+                     "/releases/download/sv_v" version "/sonic-visualiser-"
+                     version ".tar.gz"))
+              (sha256
+                (base32
+                  "18w2mf4c6sis0lg6dq75v4zb8q9rbmbmlfvcvk60lyqynmvq4yy5"))))
+    (build-system meson-build-system)
+    (arguments (list #:tests? #f)) ;; tests fail due to build sandbox
+    (inputs (list alsa-lib
+                  bzip2
+                  capnproto
+                  fftw
+                  jack-1
+                  libfishsound
+                  libid3tag
+                  liblo
+                  libmad
+                  libsamplerate
+                  libsndfile
+                  lrdf
+                  oggz
+                  opusfile
+                  portaudio
+                  pulseaudio
+                  qtbase-5
+                  qtsvg-5
+                  rubberband
+                  serd
+                  sord
+                  zlib))
+    (native-inputs (list pkg-config))
+    (synopsis "Program for visualising and inspecting audio files")
+    (description "Sonic Visualiser is a program for annotating, visualising, and
+inspecting audio files, providing waveform analysis and a VAMP host for external
+audio analysis and annotation plugins.")
+    (home-page "https://sonicvisualiser.org")
+    (license license:gpl2+)))
-- 
2.37.2

Message #20 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 5/7] gnu: Add VAMP plugins to VAMP_PATH.
Date: Fri, 30 Sep 2022 19:22:38 -0500

* gnu/packages/audio.scm (rubberband, vamp)[native-search-paths]: Add
  VAMP plugins to the VAMP_PATH search path.
---
 gnu/packages/audio.scm | 8 ++++++++
 1 file changed, 8 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index 0dd0b8ff55..0d9261c35a 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -3330,6 +3330,10 @@ (define-public rubberband
      (list ladspa libsamplerate vamp))
     (native-inputs
      (list pkg-config))
+    (native-search-paths
+     (list (search-path-specification
+            (variable "VAMP_PATH")
+            (files '("lib/vamp")))))
     (home-page "https://breakfastquay.com/rubberband/")
     (synopsis "Audio time-stretching and pitch-shifting library")
     (description
@@ -3547,6 +3551,10 @@ (define-public vamp
      (list libsndfile))
     (native-inputs
      (list pkg-config))
+    (native-search-paths
+     (list (search-path-specification
+            (variable "VAMP_PATH")
+            (files '("lib/vamp")))))
     (home-page "https://vamp-plugins.org")
     (synopsis "Modular and extensible audio processing system")
     (description
-- 
2.37.2

Message #23 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 6/7] gnu: Add vamp-aubio-plugins.
Date: Fri, 30 Sep 2022 19:22:39 -0500

* gnu/packages/audio.scm (vamp-aubio-plugins): New variable.
---
 gnu/packages/audio.scm | 38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index 0d9261c35a..198e3cb7e8 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -5904,6 +5904,44 @@ (define-public streamripper
 be separated.")
     (license license:gpl2+)))
 
+(define-public vamp-aubio-plugins
+  (package
+    (name "vamp-aubio-plugins")
+    (version "0.5.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "https://aubio.org/pub/vamp-aubio-plugins/"
+                                  "vamp-aubio-plugins-" version ".tar.bz2"))
+              (sha256
+                (base32
+                  "1gpcg7hih42qmys8a9zylgas3xfrzqijasgaphm43bmiw7vrvxis"))
+              (modules '((guix build utils)))
+              (snippet '(begin ;; remove outdated & bundled waf
+                          (delete-file "waf")
+                          (delete-file-recursively "waflib")))))
+    (build-system waf-build-system)
+    (arguments
+      `(#:tests? #f ;; no tests available
+        #:phases
+        (modify-phases %standard-phases
+          (add-before 'configure 'setup-waf
+            (lambda* (#:key inputs #:allow-other-keys)
+              (let ((waf (assoc-ref inputs "python-waf")))
+                (copy-file (string-append waf "/bin/waf") "waf")))))))
+    (inputs (list aubio vamp))
+    (native-inputs (list pkg-config python-waf))
+    (native-search-paths
+      (list (search-path-specification
+              (variable "VAMP_PATH")
+              (files '("lib/vamp")))))
+    (synopsis "VAMP plugin for audio labelling")
+    (description "A set of VAMP plugins wrapping the audio annotation features
+of Aubio for use in a VAMP host. Includes plugins for note tracking, energy
+extracting, pitch detection, silence detection, spectral description, and beat
+tracking.")
+    (home-page "https://aubio.org/vamp-aubio-plugins/")
+    (license license:gpl3+)))
+
 (define-public sonic-visualiser
   (package
     (name "sonic-visualiser")
-- 
2.37.2

Message #26 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH 7/7] gnu: Add nnls-chroma.
Date: Fri, 30 Sep 2022 19:22:40 -0500

* gnu/packages/audio.scm (nnls-chroma): New variable.
---
 gnu/packages/audio.scm | 43 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index 198e3cb7e8..c9a7829236 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -5942,6 +5942,49 @@ (define-public vamp-aubio-plugins
     (home-page "https://aubio.org/vamp-aubio-plugins/")
     (license license:gpl3+)))
 
+(define-public nnls-chroma
+  (package
+    (name "nnls-chroma")
+    (version "1.1")
+    (source (origin
+              (method url-fetch)
+              ;; These urls have an "attachment number" :/ which makes this url
+              ;; not generalizable across versions.
+              (uri (string-append
+                     "https://code.soundsoftware.ac.uk/attachments/download/"
+                     "1691/nnls-chroma-1.1.tar.gz"))
+              (sha256
+                (base32
+                  "06n66ff4w4a07rfz1kn0hq2g953dsx8a4cx1bhpvswqds1kb70md"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:tests? #f ;; no tests available
+       #:make-flags
+       (list "-f" "Makefile.linux"
+             (string-append "CC=" ,(cc-for-target))
+             (string-append "VAMP_SDK_DIR=" (assoc-ref %build-inputs "vamp")
+                            "/include/vamp-sdk"))
+       #:phases
+       ,#~(modify-phases %standard-phases
+            (delete 'configure) ;; no configure phase
+            (replace 'install ;; no install phase
+              (lambda _
+                (let ((outdir (string-append #$output "/lib/vamp"))
+                      (outfile "nnls-chroma.so"))
+                  (mkdir-p outdir)
+                  (copy-file outfile (string-append outdir "/" outfile))))))))
+    (inputs (list boost vamp))
+    (native-search-paths
+      (list (search-path-specification
+              (variable "VAMP_PATH")
+              (files '("lib/vamp")))))
+    (synopsis "VAMP plugins for audio transcription")
+    (description "A set of three VAMP plugins used for audio transcription: NNLS
+Chroma, providing chromatic transcription, Chordino, providing chord
+transcription, and Tuning, which estimates local and global tuning.")
+    (home-page "http://www.isophonics.net/nnls-chroma/")
+    (license license:gpl2+)))
+
 (define-public sonic-visualiser
   (package
     (name "sonic-visualiser")
-- 
2.37.2

Message #29 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 1/7] gnu: Add oggz.
Date: Thu, 27 Oct 2022 19:48:00 +0100

Hey Lilah :),

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> +             (uri (string-append "https://downloads.xiph.org/releases/liboggz/"
> +                                 "liboggz-" version ".tar.gz"))

Add a file-name field below uri like this:

  (file-name (string-append name "-" version ".tar.gz"))

> +             (sha256
> +               (base32
                 ^
> +                 "0nj17lhnsw4qbbk8jy4j6a78w6v2llhqdwq46g44mbm9w2qsvbvb"))))
                   ^
Remove these spaces.

> +    (propagated-inputs (list util-linux)) ;; for getopt in oggz-diff

Try to avoid propagated-inputs if possible; instead, patch the
src/tools/ogg-diff.in file to refer to commands directly, e.g.

  (substitute* "src/tools/ogg-diff.in"
    (("`getopt")
     (string-append "`"
                    (search-input-file inputs "bin/getopt"))))

Do the same for any other commands referenced in the script (even
basic things like ls) so that the script works inside a

  guix shell oggz --pure

> +    (synopsis "Library and cli tool for working with Ogg files")

s/cli/command line/

> +    (description "A C library for reading and writing Ogg files and streams in
> +multiple formats, bundled with cli tools to inspect, validate, crop, and edit
> +Ogg files.")

Use full sentences for descriptions.

> +    (home-page "https://xiph.org/oggz/")))

home-page usually goes between the various input fields and synopsis.

    -- (

Message #32 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 2/7] gnu: libkate: Add optional input oggz.
Date: Thu, 27 Oct 2022 19:52:29 +0100

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> * gnu/packages/xiph.scm (libkate)[inputs]: Add optional input oggz.
> ---
>  gnu/packages/xiph.scm | 3 +--
>  1 file changed, 1 insertion(+), 2 deletions(-)
>
> diff --git a/gnu/packages/xiph.scm b/gnu/packages/xiph.scm
> index b97d2a0553..112b8ddf87 100644
> --- a/gnu/packages/xiph.scm
> +++ b/gnu/packages/xiph.scm
> @@ -293,8 +293,7 @@ (define-public libkate
>                "0s3vr2nxfxlf1k75iqpp4l78yf4gil3f0v778kvlngbchvaq23n4"))))
>     (build-system gnu-build-system)
>     (native-inputs (list doxygen bison pkg-config))
> -   ;; FIXME: Add optional input liboggz
> -   (inputs (list libogg libpng python-wrapper zlib))
> +   (inputs (list libogg oggz libpng python-wrapper zlib))
>     (synopsis "Karaoke and text codec for embedding in ogg")
>     (description
>      "Kate is an overlay codec, originally designed for karaoke and text,
> -- 
> 2.37.2

LGTM.

    -- (

Message #35 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 3/7] gnu: Add libfishsound.
Date: Thu, 27 Oct 2022 19:53:29 +0100

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> +             (uri (string-append
> +                    "https://downloads.xiph.org/releases/libfishsound/"
> +                    "libfishsound-" version ".tar.gz"))

file-name here, please.

> +             (sha256
> +               (base32
> +                 "1iz7mn6hw2wg8ljaw74f4g2zdj68ib88x4vjxxg3gjgc5z75f2rf"))))

One space indentation for sha256 and base32.

> +    (build-system gnu-build-system)
> +    (inputs (list libvorbis speex))
> +    (synopsis "Library for encoding and decoing Xiph.org codecs")
> +    (description "A C library wrapping individual Xiph.org codecs, including
> +FLAC, Speex, and Vorbis, providing a unified higher-level interface for handling
> +raw codec streams.")

Full sentences, please :)

> +    (home-page "https://xiph.org/fishsound/")))

Move the home-page before synopsis.

    -- (

Message #38 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 4/7] gnu: Add sonic-visualiser.
Date: Thu, 27 Oct 2022 19:57:02 +0100

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> +              (uri (string-append
> +                     "https://github.com/sonic-visualiser/sonic-visualiser"
> +                     "/releases/download/sv_v" version "/sonic-visualiser-"
> +                     version ".tar.gz"))

file-name, please.

> +              (sha256
> +                (base32
> +                  "18w2mf4c6sis0lg6dq75v4zb8q9rbmbmlfvcvk60lyqynmvq4yy5"))))

Too many spaces again :)

> +    (arguments (list #:tests? #f)) ;; tests fail due to build sandbox

Could you please be more specific here? How does it fail? Also, the usual
practice in Scheme is to use a single semicolon for comments at the *end*
of a line (as opposed to two for a full line, three for a whole section of
a file, and four for the whole file).

> +    (inputs (list alsa-lib

Put the (list ...) on a new line.

> +    (home-page "https://sonicvisualiser.org")

home-page goes before synopsis.

    -- (

Message #41 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 5/7] gnu: Add VAMP plugins to VAMP_PATH.
Date: Thu, 27 Oct 2022 19:59:49 +0100

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> @@ -3330,6 +3330,10 @@ (define-public rubberband
> +    (native-search-paths
> +     (list (search-path-specification
> +            (variable "VAMP_PATH")
> +            (files '("lib/vamp")))))
> @@ -3547,6 +3551,10 @@ (define-public vamp
> +    (native-search-paths
> +     (list (search-path-specification
> +            (variable "VAMP_PATH")
> +            (files '("lib/vamp")))))

Maybe factor this search-path-specification into a private variable
called ``$VAMP_PATH'', then write,

  (native-search-paths (list $VAMP_PATH))

    -- (

Message #44 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 6/7] gnu: Add vamp-aubio-plugins.
Date: Thu, 27 Oct 2022 20:05:18 +0100

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> +              (uri (string-append "https://aubio.org/pub/vamp-aubio-plugins/"
> +                                  "vamp-aubio-plugins-" version ".tar.bz2"))

Add a file-name field.

> +              (sha256
> +                (base32
> +                  "1gpcg7hih42qmys8a9zylgas3xfrzqijasgaphm43bmiw7vrvxis"))

One space indents here.

> +              (snippet '(begin ;; remove outdated & bundled waf
> +                          (delete-file "waf")
> +                          (delete-file-recursively "waflib")))))

Use gexp instead of quote here,

  (snippet
   #~(begin
       (delete-file "waf")
       (delete-file-recursively "waflib")))

> +    (arguments
> +      `(#:tests? #f ;; no tests available
> +        #:phases
> +        (modify-phases %standard-phases
> +          (add-before 'configure 'setup-waf
> +            (lambda* (#:key inputs #:allow-other-keys)
> +              (let ((waf (assoc-ref inputs "python-waf")))
> +                (copy-file (string-append waf "/bin/waf") "waf")))))))

Use the modern argument style (and correct comment style),

  (arguments
   (list #:tests? #f ;no tests
         #:phases
         #~(modify-phases %standard-phases
             (add-before 'configure 'setup-waf
               (lambda* (#:key inputs #:allow-other-keys)
                 (copy-file (search-input-file inputs "bin/waf")
                            "waf"))))))

> +    (native-search-paths
> +      (list (search-path-specification
> +              (variable "VAMP_PATH")
> +              (files '("lib/vamp")))))

Use the ``$VAMP_PATH'' variable here.

> +    (description "A set of VAMP plugins wrapping the audio annotation features
> +of Aubio for use in a VAMP host. Includes plugins for note tracking, energy

guix lint says "sentences in description should be followed by two
spaces"; remember to run it for every package you write :) Also, full
sentences.

> +    (home-page "https://aubio.org/vamp-aubio-plugins/")

Move home-page, etc etc :)

    -- (

Message #47 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 7/7] gnu: Add nnls-chroma.
Date: Thu, 27 Oct 2022 20:11:27 +0100

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> +              (uri (string-append
> +                     "https://code.soundsoftware.ac.uk/attachments/download/"
> +                     "1691/nnls-chroma-1.1.tar.gz"))

Add file-name.

> +              (sha256
> +                (base32
> +                  "06n66ff4w4a07rfz1kn0hq2g953dsx8a4cx1bhpvswqds1kb70md"))))

One space indents...

> +    (arguments
> +     `(#:tests? #f ;; no tests available
> +       #:make-flags
> +       (list "-f" "Makefile.linux"
> +             (string-append "CC=" ,(cc-for-target))
> +             (string-append "VAMP_SDK_DIR=" (assoc-ref %build-inputs "vamp")
> +                            "/include/vamp-sdk"))
> +       #:phases
> +       ,#~(modify-phases %standard-phases
> +            (delete 'configure) ;; no configure phase
> +            (replace 'install ;; no install phase
> +              (lambda _
> +                (let ((outdir (string-append #$output "/lib/vamp"))
> +                      (outfile "nnls-chroma.so"))
> +                  (mkdir-p outdir)
> +                  (copy-file outfile (string-append outdir "/" outfile))))))))

Modernised,

  (arguments
   (list #:tests? #f ;no tests
         #:make-flags
         #~(list "-f" "Makefile.linux"
                 (string-append "CC=" #$(cc-for-target))
                 (string-append "VAMP_SDK_DIR="
                                #$(this-package-input vamp)
                                "/include/vamp-sdk"))
         #:phases
         #~(modify-phases %standard-phases
             (delete 'configure) ;no configure script
             (replace 'install
               (lambda _
                 (install-file "nnls-chroma.so"
                               (string-append #$output
                                              "/lib/vamp")))))))

> +    (native-search-paths
> +      (list (search-path-specification
> +              (variable "VAMP_PATH")
> +              (files '("lib/vamp")))))

Actually, on second thought, I don't think this is necessary for
VAMP *plugins*, only VAMP itself? (Not certain though.)

> +    (home-page "http://www.isophonics.net/nnls-chroma/")

home-page goes before synopsis :)

    -- (

Message #50 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: "(" <paren <at> disroot.org>
To: "Lilah Tascheter" <lilah <at> lunabee.space>, <58208 <at> debbugs.gnu.org>
Cc: ludo <at> gnu.org
Subject: Re: [bug#58208] [PATCH 6/7] gnu: Add vamp-aubio-plugins.
Date: Thu, 27 Oct 2022 20:12:59 +0100

On Sat Oct 1, 2022 at 1:22 AM BST, Lilah Tascheter via Guix-patches via wrote:
> +    (native-search-paths
> +      (list (search-path-specification
> +              (variable "VAMP_PATH")
> +              (files '("lib/vamp")))))

Actually, on second thought, is this necessary for VAMP *plugins*,
not just VAMP itsalf?

    -- (

Message #55 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 0/9] Add Sonic Visualiser and VAMP plugins.
Date: Fri,  2 Jun 2023 00:56:37 -0500

Revision fixing problems pointed out by ( (apart from some of the file-name
fields, in cases which the default behavior is the same as if it was specified
manually), and bringing Sonic Visualiser up to its latest version, which
supports out-of-tree VAMP.

Thanks for the review!!

Lilah Tascheter (9):
  gnu: Add oggz.
  gnu: libkate: Add optional input oggz.
  gnu: Add libfishsound.
  gnu: Add rubberband-next.
  gnu: Update vamp.
  gnu: Add sonic-visualiser.
  gnu: Register VAMP_PATH with host.
  gnu: Add vamp-aubio-plugins.
  gnu: Add nnls-chroma.

 gnu/packages/audio.scm | 157 ++++++++++++++++++++++++++++++++++++++++-
 gnu/packages/xiph.scm  |  60 +++++++++++++++-
 2 files changed, 212 insertions(+), 5 deletions(-)


base-commit: b4382b294e6cd475e9476610d98fdd0bdaec4c84
-- 
2.40.1

Message #58 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 2/9] gnu: libkate: Add optional input oggz.
Date: Fri,  2 Jun 2023 00:56:39 -0500

* gnu/packages/xiph.scm (libkate)[inputs]: Add optional input oggz.
---
 gnu/packages/xiph.scm | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/gnu/packages/xiph.scm b/gnu/packages/xiph.scm
index 2f69d3aa6b..5339b5965d 100644
--- a/gnu/packages/xiph.scm
+++ b/gnu/packages/xiph.scm
@@ -308,8 +308,7 @@ (define-public libkate
               "0s3vr2nxfxlf1k75iqpp4l78yf4gil3f0v778kvlngbchvaq23n4"))))
    (build-system gnu-build-system)
    (native-inputs (list doxygen bison pkg-config))
-   ;; FIXME: Add optional input liboggz
-   (inputs (list libogg libpng python-wrapper zlib))
+   (inputs (list libogg oggz libpng python-wrapper zlib))
    (synopsis "Karaoke and text codec for embedding in ogg")
    (description
     "Kate is an overlay codec, originally designed for karaoke and text,
-- 
2.40.1

Message #61 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 1/9] gnu: Add oggz.
Date: Fri,  2 Jun 2023 00:56:38 -0500

* gnu/packages/xiph.scm (oggz): New variable.
---
 gnu/packages/xiph.scm | 36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

diff --git a/gnu/packages/xiph.scm b/gnu/packages/xiph.scm
index b47c718fb6..2f69d3aa6b 100644
--- a/gnu/packages/xiph.scm
+++ b/gnu/packages/xiph.scm
@@ -32,6 +32,7 @@
 (define-module (gnu packages xiph)
   #:use-module (gnu packages)
   #:use-module (gnu packages autotools)
+  #:use-module (gnu packages base)
   #:use-module (gnu packages bison)
   #:use-module (gnu packages compression)
   #:use-module (gnu packages curl)
@@ -46,6 +47,7 @@ (define-module (gnu packages xiph)
   #:use-module ((guix licenses) #:prefix license:)
   #:use-module (guix packages)
   #:use-module (guix download)
+  #:use-module (guix gexp)
   #:use-module (guix git-download)
   #:use-module (guix build-system gnu))
 
@@ -259,6 +261,40 @@ (define-public flac
                                "See COPYING in the distribution.")) ; and LGPL and GPL
    (home-page "https://xiph.org/flac/")))
 
+(define-public oggz
+  (package
+    (name "oggz")
+    (version "1.1.1")
+    (source (origin
+             (method url-fetch)
+             (uri (string-append "https://downloads.xiph.org/releases/liboggz/"
+                                 "liboggz-" version ".tar.gz"))
+             (file-name (string-append name "-" version ".tar.gz"))
+             (sha256
+              (base32
+               "0nj17lhnsw4qbbk8jy4j6a78w6v2llhqdwq46g44mbm9w2qsvbvb"))))
+    (build-system gnu-build-system)
+    (arguments
+      (list #:phases
+            #~(modify-phases %standard-phases
+                (add-before 'build 'patch-oggz-diff-script
+                  (lambda* (#:key inputs #:allow-other-keys)
+                    (let* ((input (lambda (i) (search-input-file inputs i)))
+                           (getopt (input "/bin/getopt"))
+                           (basename (input "/bin/basename"))
+                           (diff (input "/bin/diff")))
+                      (substitute* "src/tools/oggz-diff.in"
+                        (("`getopt") (string-append "`" getopt))
+                        (("`basename") (string-append "`" basename))
+                        (("^diff") diff))))))))
+    (inputs (list coreutils-minimal diffutils libogg util-linux))
+    (home-page "https://xiph.org/oggz/")
+    (synopsis "Library and command-line tool for working with Ogg files")
+    (description "Oggz is a C library for reading and writing Ogg files and
+streams in multiple formats.  It comes bundled with cli tools to inspect,
+validate, crop, and edit Ogg files.")
+    (license license:bsd-3)))
+
 (define-public libkate
   (package
    (name "libkate")
-- 
2.40.1

Message #64 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 3/9] gnu: Add libfishsound.
Date: Fri,  2 Jun 2023 00:56:40 -0500

* gnu/packages/xiph.scm (libfishsound): New variable.
---
 gnu/packages/xiph.scm | 21 +++++++++++++++++++++
 1 file changed, 21 insertions(+)

diff --git a/gnu/packages/xiph.scm b/gnu/packages/xiph.scm
index 5339b5965d..63e83fec24 100644
--- a/gnu/packages/xiph.scm
+++ b/gnu/packages/xiph.scm
@@ -295,6 +295,27 @@ (define-public oggz
 validate, crop, and edit Ogg files.")
     (license license:bsd-3)))
 
+(define-public libfishsound
+  (package
+    (name "libfishsound")
+    (version "1.0.0")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                     "https://downloads.xiph.org/releases/libfishsound/"
+                     "libfishsound-" version ".tar.gz"))
+              (sha256
+               (base32
+                "1iz7mn6hw2wg8ljaw74f4g2zdj68ib88x4vjxxg3gjgc5z75f2rf"))))
+    (build-system gnu-build-system)
+    (inputs (list libvorbis speex))
+    (home-page "https://xiph.org/fishsound/")
+    (synopsis "Library for encoding and decoing Xiph.org codecs")
+    (description "Libfishsound is a C library wrapping individual Xiph.org
+codecs, including FLAC, Speex, and Vorbis.  It provides a unified higher-level
+interface for handling raw codec streams.")
+    (license license:bsd-3)))
+
 (define-public libkate
   (package
    (name "libkate")
-- 
2.40.1

Message #67 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 5/9] gnu: Update vamp.
Date: Fri,  2 Jun 2023 00:56:42 -0500

* gnu/packages/audio.scm (vamp): Update to 2.10.
---
 gnu/packages/audio.scm | 6 +++---
 1 file changed, 3 insertions(+), 3 deletions(-)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index a4a0120f89..58e48973a1 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -3843,16 +3843,16 @@ (define-public timidity++
 (define-public vamp
   (package
     (name "vamp")
-    (version "2.6")
+    (version "2.10.0")
     (source (origin
               (method url-fetch)
               (uri (string-append
                     "https://code.soundsoftware.ac.uk"
-                    "/attachments/download/1520/vamp-plugin-sdk-"
+                    "/attachments/download/2691/vamp-plugin-sdk-"
                     version ".tar.gz"))
               (sha256
                (base32
-                "0pzq0yy2kdl3jgfc2aqmh5m55nk1ild0hq8mydiiw35c6y0mglyh"))))
+                "0pzpkxrz71fzqd2m83kjyafzqzrifzsq5phcn7mqq52blii3gbxf"))))
     (build-system gnu-build-system)
     (arguments
      `(#:tests? #f                      ; no check target
-- 
2.40.1

Message #70 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 4/9] gnu: Add rubberband-next.
Date: Fri,  2 Jun 2023 00:56:41 -0500

Sonic Visualiser requires rubberband two major versions newer than
currently packaged.

* gnu/packages/audio.scm (rubberband-next): New variable.
---
 gnu/packages/audio.scm | 20 ++++++++++++++++++++
 1 file changed, 20 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index 58a981b2fe..a4a0120f89 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -3640,6 +3640,26 @@ (define-public rubberband
 tempo and pitch of an audio recording independently of one another.")
     (license license:gpl2+)))
 
+(define-public rubberband-next
+  (package
+    (name "rubberband")
+    (version "3.2.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "https://breakfastquay.com/files/releases/"
+                                  "rubberband-" version ".tar.bz2"))
+              (sha256
+               (base32
+                "0wnijydgk4lb1z2kz102zq7r8iikrbagrcaxm2k5dzhbqp8arvc2"))))
+    (build-system meson-build-system)
+    (inputs (list boost ladspa libsamplerate vamp))
+    (home-page "https://breakfastquay.com/rubberband/")
+    (synopsis "Audio time-stretching and pitch-shifting library")
+    (description
+     "Rubber Band is a library and utility program that permits changing the
+tempo and pitch of an audio recording independently of one another.")
+    (license license:gpl2+)))
+
 (define-public rtmidi
   (package
     (name "rtmidi")
-- 
2.40.1

Message #73 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 6/9] gnu: Add sonic-visualiser.
Date: Fri,  2 Jun 2023 00:56:43 -0500

* gnu/packages/audio.scm (sonic-visualiser): New variable.
---
 gnu/packages/audio.scm | 56 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index 58e48973a1..1ff8c77eb9 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -1092,6 +1092,62 @@ (define %configure (assoc-ref %standard-phases 'configure))
 tools.")
     (license license:gpl2+)))
 
+(define-public sonic-visualiser
+  (package
+    (name "sonic-visualiser")
+    (version "4.5.2")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append
+                     "https://github.com/sonic-visualiser/sonic-visualiser"
+                     "/releases/download/sv_v" version "/sonic-visualiser-"
+                     version ".tar.gz"))
+              (modules '((guix build utils)))
+              (snippet #~(begin
+                           (delete-file-recursively "vamp-plugin-sdk")
+                           (mkdir "vamp-plugin-sdk")))
+              (sha256
+               (base32
+                "11xl5lhj50yhy49qmzwhf3s1rbfcdcc589ffbr4sz5rzksxf25h8"))))
+    (build-system meson-build-system)
+    (arguments
+      (list #:phases
+            #~(modify-phases %standard-phases
+                (add-before 'check 'set-home
+                  (lambda _ ; tests write to $HOME
+                    (setenv "HOME" "/tmp"))))))
+    (inputs
+      (list alsa-lib
+            bzip2
+            capnproto
+            fftw
+            jack-1
+            libfishsound
+            libid3tag
+            liblo
+            libmad
+            libsamplerate
+            libsndfile
+            lrdf
+            oggz
+            opusfile
+            portaudio
+            pulseaudio
+            qtbase-5
+            qtsvg-5
+            rubberband-next
+            serd
+            sord
+            vamp   ; due to how search paths are implemented, plugin use
+            zlib)) ; requires vamp to be added to a profile.
+    (native-inputs (list pkg-config))
+    (home-page "https://sonicvisualiser.org")
+    (synopsis "Program for visualising and inspecting audio files")
+    (description "Sonic Visualiser is a program for annotating, visualising, and
+inspecting audio files, providing waveform analysis and a VAMP host for external
+audio analysis and annotation plugins.")
+    (license license:gpl2+)))
+
 (define-public audiofile
   (package
     (name "audiofile")
-- 
2.40.1

Message #76 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 7/9] gnu: Register VAMP_PATH with host.
Date: Fri,  2 Jun 2023 00:56:44 -0500

* gnu/packages/audio.scm (vamp)[native-search-paths]: Add VAMP plugins
  to the VAMP_PATH search path.
---
 gnu/packages/audio.scm | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index 1ff8c77eb9..2931cba488 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -3926,6 +3926,10 @@ (define-public vamp
      (list libsndfile))
     (native-inputs
      (list pkg-config))
+    (native-search-paths
+     (list (search-path-specification
+            (variable "VAMP_PATH")
+            (files '("lib/vamp")))))
     (home-page "https://vamp-plugins.org")
     (synopsis "Modular and extensible audio processing system")
     (description
-- 
2.40.1

Message #79 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 8/9] gnu: Add vamp-aubio-plugins.
Date: Fri,  2 Jun 2023 00:56:45 -0500

* gnu/packages/audio.scm (vamp-aubio-plugins): New variable.
---
 gnu/packages/audio.scm | 33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index 2931cba488..c34ccb30a5 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -626,6 +626,39 @@ (define-public aubio
 streams from live audio.")
     (license license:gpl3+)))
 
+(define-public vamp-aubio-plugins
+  (package
+    (name "vamp-aubio-plugins")
+    (version "0.5.1")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "https://aubio.org/pub/vamp-aubio-plugins/"
+                                  "vamp-aubio-plugins-" version ".tar.bz2"))
+              (modules '((guix build utils)))
+              (snippet #~(begin ; remove outdated & bundled waf
+                           (delete-file "waf")
+                           (delete-file-recursively "waflib")))
+              (sha256
+               (base32
+                "1gpcg7hih42qmys8a9zylgas3xfrzqijasgaphm43bmiw7vrvxis"))))
+    (build-system waf-build-system)
+    (arguments
+      (list #:tests? #f ; no tests available
+            #:phases
+            #~(modify-phases %standard-phases
+                (add-before 'configure 'setup-waf
+                  (lambda* (#:key inputs #:allow-other-keys)
+                    (copy-file (search-input-file inputs "/bin/waf") "waf"))))))
+    (inputs (list aubio vamp))
+    (native-inputs (list pkg-config python-waf))
+    (home-page "https://aubio.org/vamp-aubio-plugins/")
+    (synopsis "VAMP plugin for audio labelling")
+    (description "vamp-aubio-plugins is a set of VAMP plugins wrapping the audio
+annotation features of Aubio for use in a VAMP host.  Includes plugins for note
+tracking, energy extracting, pitch detection, silence detection, spectral
+description, and beat tracking.")
+    (license license:gpl3+)))
+
 (define-public dsp
   (package
     (name "dsp")
-- 
2.40.1

Message #82 received at 58208 <at> debbugs.gnu.org (full text, mbox):

From: Lilah Tascheter <lilah <at> lunabee.space>
To: 58208 <at> debbugs.gnu.org
Cc: paren <at> disroot.org, Lilah Tascheter <lilah <at> lunabee.space>
Subject: [PATCH v2 9/9] gnu: Add nnls-chroma.
Date: Fri,  2 Jun 2023 00:56:46 -0500

* gnu/packages/audio.scm (nnls-chroma): New variable.
---
 gnu/packages/audio.scm | 38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

diff --git a/gnu/packages/audio.scm b/gnu/packages/audio.scm
index c34ccb30a5..d7c11b0a5d 100644
--- a/gnu/packages/audio.scm
+++ b/gnu/packages/audio.scm
@@ -659,6 +659,44 @@ (define-public vamp-aubio-plugins
 description, and beat tracking.")
     (license license:gpl3+)))
 
+(define-public nnls-chroma
+  (package
+    (name "nnls-chroma")
+    (version "1.1")
+    (source (origin
+              (method url-fetch)
+              ;; These urls have an "attachment number" :/ which makes this url
+              ;; not generalizable across versions.
+              (uri (string-append
+                     "https://code.soundsoftware.ac.uk/attachments/download/"
+                     "1691/nnls-chroma-" version ".tar.gz"))
+              (sha256
+               (base32
+                "06n66ff4w4a07rfz1kn0hq2g953dsx8a4cx1bhpvswqds1kb70md"))))
+    (build-system gnu-build-system)
+    (arguments
+      (list #:tests? #f ;; no tests available
+            #:make-flags
+            #~(list "-f" "Makefile.linux"
+                    (string-append "CC=" #$(cc-for-target))
+                    (string-append "VAMP_SDK_DIR=" #$(this-package-input "vamp")
+                                   "/include/vamp-sdk"))
+            #:phases
+            #~(modify-phases %standard-phases
+                (delete 'configure) ; no configure script
+                (replace 'install
+                  (lambda _
+                    (install-file "nnls-chroma.so"
+                                  (string-append #$output "/lib/vamp")))))))
+    (inputs (list boost vamp))
+    (home-page "http://www.isophonics.net/nnls-chroma/")
+    (synopsis "VAMP plugins for audio transcription")
+    (description "This is a set of three VAMP plugins used for audio
+transcription: NNLS Chroma, providing chromatic transcription, Chordino,
+providing chord transcription, and Tuning, which estimates local and global
+tuning.")
+    (license license:gpl2+)))
+
 (define-public dsp
   (package
     (name "dsp")
-- 
2.40.1

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.