Subject: 29.0.50; erc-match commands should store regular expressions

From: "J.P." <[email-masked]>
Date: Fri, 08 Jul 2022 06:27:26 -0700

Tags: patch

Currently, pals, fools, keywords, etc. aren't `regexp-quote'd by their
associated commands (such as `erc-add-pal') before being added as match
patterns. Thus, items containing special characters, like "boo[m]" or
"lol.fun.dad", tend to be ineffective. Worse, invalid regexps containing
things like unmatched brackets create errors in the process filter.

Something else not included that perhaps should be is a clearer
indication that items added interactively can match any substring in a
candidate without regard for boundaries. It may also be worth
contrasting this with what's ultimately highlighted. For example, if you
"M-x erc-add-pal RET bo RET", then "<bob>" (minus the brackets) will be
highlighted. Compare this to keywords, where only the matched portion
appears in a designated face.

Documentation aside, it might also be nice to retain a means of
interactively adding a regexp verbatim (IOW, the old behavior minus the
unhelpful completion list). Perhaps this can be done via universal
argument.

BTW, the individual who originally brought this to our attention on
Libera also mused about a command for jumping between keywords, so I've
included something sketchy to that effect. However, it suffers from an
intermittent issue that I can't yet reproduce reliably: basically, when
first invoked, it sometimes makes Emacs unresponsive for a few seconds.
If I can't manage to tame it, I'll just drop it from this patch set.

Lastly, these changes (as presented) uphold the proud ERC tradition of
mutating custom options on behalf of a user. If this is truly
objectionable, then I can switch to network-local analogs instead.
However, such a move may adversely affect third-party code, given that
this module's been around in roughly the same form for some 20 odd
years.

Thanks,
J.P.

P.S. This bug is not (yet) associated with any planned ERC release.

In GNU Emacs 29.0.50 (build 1, x86_64-pc-linux-gnu, GTK+ Version 3.24.34, cairo version 1.17.6)
 of 2022-07-06 built on localhost
Repository revision: e6504c3eda12c72268d2db6598764f043b74c24d
Repository branch: master
Windowing system distributor 'The X.Org Foundation', version 11.0.12014000
System Description: Fedora Linux 36 (Workstation Edition)

Configured using:
 'configure --enable-check-lisp-object-type --enable-checking=yes,glyphs
 'CFLAGS=-O0 -g3'
 PKG_CONFIG_PATH=:/usr/lib64/pkgconfig:/usr/share/pkgconfig'

Configured features:
ACL CAIRO DBUS FREETYPE GIF GLIB GMP GNUTLS GPM GSETTINGS HARFBUZZ JPEG
JSON LCMS2 LIBOTF LIBSELINUX LIBSYSTEMD LIBXML2 M17N_FLT MODULES NOTIFY
INOTIFY PDUMPER PNG RSVG SECCOMP SOUND SQLITE3 THREADS TIFF
TOOLKIT_SCROLL_BARS WEBP X11 XDBE XIM XINPUT2 XPM GTK3 ZLIB

Important settings:
  value of $LANG: en_US.UTF-8
  value of $XMODIFIERS: @im=ibus
  locale-coding-system: utf-8-unix

Major mode: Lisp Interaction

Minor modes in effect:
  tooltip-mode: t
  global-eldoc-mode: t
  eldoc-mode: t
  show-paren-mode: t
  electric-indent-mode: t
  mouse-wheel-mode: t
  tool-bar-mode: t
  menu-bar-mode: t
  file-name-shadow-mode: t
  global-font-lock-mode: t
  font-lock-mode: t
  blink-cursor-mode: t
  line-number-mode: t
  indent-tabs-mode: t
  transient-mark-mode: t
  auto-composition-mode: t
  auto-encryption-mode: t
  auto-compression-mode: t

Load-path shadows:
None found.

Features:
(shadow sort mail-extr emacsbug message mailcap yank-media puny dired
dired-loaddefs rfc822 mml mml-sec password-cache epa derived epg rfc6068
epg-config gnus-util text-property-search time-date subr-x mm-decode
mm-bodies mm-encode mail-parse rfc2231 mailabbrev gmm-utils mailheader
cl-loaddefs cl-lib sendmail rfc2047 rfc2045 ietf-drums mm-util
mail-prsvr mail-utils rmc iso-transl tooltip eldoc paren electric
uniquify ediff-hook vc-hooks lisp-float-type elisp-mode mwheel
term/x-win x-win term/common-win x-dnd tool-bar dnd fontset image
regexp-opt fringe tabulated-list replace newcomment text-mode lisp-mode
prog-mode register page tab-bar menu-bar rfn-eshadow isearch easymenu
timer select scroll-bar mouse jit-lock font-lock syntax font-core
term/tty-colors frame minibuffer nadvice seq simple cl-generic
indonesian philippine cham georgian utf-8-lang misc-lang vietnamese
tibetan thai tai-viet lao korean japanese eucjp-ms cp51932 hebrew greek
romanian slovak czech european ethiopic indian cyrillic chinese
composite emoji-zwj charscript charprop case-table epa-hook
jka-cmpr-hook help abbrev obarray oclosure cl-preloaded button loaddefs
faces cus-face macroexp files window text-properties overlay sha1 md5
base64 format env code-pages mule custom widget keymap
hashtable-print-readable backquote threads dbusbind inotify lcms2
dynamic-setting system-font-setting font-render-setting cairo
move-toolbar gtk x-toolkit xinput2 x multi-tty make-network-process
emacs)

Memory information:
((conses 16 35545 5688)
 (symbols 48 5073 0)
 (strings 32 13303 1546)
 (string-bytes 1 429956)
 (vectors 16 9197)
 (vector-slots 8 145428 11407)
 (floats 8 21 25)
 (intervals 56 214 0)
 (buffers 992 10))

>From a40795bcf278b6c2b5aacde0dc5128afafadfada Mon Sep 17 00:00:00 2001
From: "F. Jason Park" <[email-masked]>
Date: Wed, 6 Jul 2022 19:57:11 -0700
Subject: [PATCH 1/2] Quote new entries as regexps in erc-match commands

* lisp/erc/erc-match.el (erc-add-entry-to-list): Append optional param
`regexpp' indicating whether to `regexp-quote' the input.
(erc-add-pal, erc-add-fool, erc-add-keyword, erc-add-dangerous-host):
Call `erc-add-entry-to-list' with regexpp flag set.
(erc-match-pal-p, erc-match-fool-p, erc-match-keyword-p,
erc-match-dangerous-host-p): Don't bother matching when list is nil.

* lisp/erc/erc.el (erc-list-match (lst str):
Join input list as regexp union instead of looping over items.

* test/lisp/erc/erc-match-tests.el: New file.
---
 lisp/erc/erc-match.el            |  21 +++---
 lisp/erc/erc.el                  |   4 +-
 test/lisp/erc/erc-match-tests.el | 121 +++++++++++++++++++++++++++++++
 3 files changed, 134 insertions(+), 12 deletions(-)
 create mode 100644 test/lisp/erc/erc-match-tests.el

diff --git a/lisp/erc/erc-match.el b/lisp/erc/erc-match.el
index 7c9174ff66..20fe640225 100644
--- a/lisp/erc/erc-match.el
+++ b/lisp/erc/erc-match.el
@@ -290,7 +290,7 @@ erc-keyword-face
 
 ;; Functions:
 
-(defun erc-add-entry-to-list (list prompt &optional completions)
+(defun erc-add-entry-to-list (list prompt &optional completions regexpp)
   "Add an entry interactively to a list.
 LIST must be passed as a symbol
 The query happens using PROMPT.
@@ -300,6 +300,8 @@ erc-add-entry-to-list
 		completions
 		(lambda (x)
 		  (not (erc-member-ignore-case (car x) (symbol-value list)))))))
+    (when regexpp
+      (setq entry (regexp-quote entry)))
     (if (erc-member-ignore-case entry (symbol-value list))
 	(error "\"%s\" is already on the list" entry)
       (set list (cons entry (symbol-value list))))))
@@ -330,7 +332,8 @@ erc-remove-entry-from-list
 (defun erc-add-pal ()
   "Add pal interactively to `erc-pals'."
   (interactive)
-  (erc-add-entry-to-list 'erc-pals "Add pal: " (erc-get-server-nickname-alist)))
+  (erc-add-entry-to-list 'erc-pals "Add pal: "
+                         (erc-get-server-nickname-alist) t))
 
 ;;;###autoload
 (defun erc-delete-pal ()
@@ -343,7 +346,7 @@ erc-add-fool
   "Add fool interactively to `erc-fools'."
   (interactive)
   (erc-add-entry-to-list 'erc-fools "Add fool: "
-			 (erc-get-server-nickname-alist)))
+                         (erc-get-server-nickname-alist) t))
 
 ;;;###autoload
 (defun erc-delete-fool ()
@@ -355,7 +358,7 @@ erc-delete-fool
 (defun erc-add-keyword ()
   "Add keyword interactively to `erc-keywords'."
   (interactive)
-  (erc-add-entry-to-list 'erc-keywords "Add keyword: "))
+  (erc-add-entry-to-list 'erc-keywords "Add keyword: " nil t))
 
 ;;;###autoload
 (defun erc-delete-keyword ()
@@ -367,7 +370,7 @@ erc-delete-keyword
 (defun erc-add-dangerous-host ()
   "Add dangerous-host interactively to `erc-dangerous-hosts'."
   (interactive)
-  (erc-add-entry-to-list 'erc-dangerous-hosts "Add dangerous-host: "))
+  (erc-add-entry-to-list 'erc-dangerous-hosts "Add dangerous-host: " nil t))
 
 ;;;###autoload
 (defun erc-delete-dangerous-host ()
@@ -388,19 +391,19 @@ erc-match-current-nick-p
 (defun erc-match-pal-p (nickuserhost _msg)
   "Check whether NICKUSERHOST is in `erc-pals'.
 MSG will be ignored."
-  (and nickuserhost
+  (and nickuserhost erc-pals
        (erc-list-match erc-pals nickuserhost)))
 
 (defun erc-match-fool-p (nickuserhost msg)
   "Check whether NICKUSERHOST is in `erc-fools' or MSG is directed at a fool."
-  (and msg nickuserhost
+  (and msg nickuserhost erc-fools
        (or (erc-list-match erc-fools nickuserhost)
 	   (erc-match-directed-at-fool-p msg))))
 
 (defun erc-match-keyword-p (_nickuserhost msg)
   "Check whether any keyword of `erc-keywords' matches for MSG.
 NICKUSERHOST will be ignored."
-  (and msg
+  (and msg erc-keywords
        (erc-list-match
 	(mapcar (lambda (x)
 		  (if (listp x)
@@ -412,7 +415,7 @@ erc-match-keyword-p
 (defun erc-match-dangerous-host-p (nickuserhost _msg)
   "Check whether NICKUSERHOST is in `erc-dangerous-hosts'.
 MSG will be ignored."
-  (and nickuserhost
+  (and nickuserhost erc-dangerous-hosts
        (erc-list-match erc-dangerous-hosts nickuserhost)))
 
 (defun erc-match-directed-at-fool-p (msg)
diff --git a/lisp/erc/erc.el b/lisp/erc/erc.el
index 239d8ebdcb..005207d945 100644
--- a/lisp/erc/erc.el
+++ b/lisp/erc/erc.el
@@ -6284,9 +6284,7 @@ erc-user-spec
 
 (defun erc-list-match (lst str)
   "Return non-nil if any regexp in LST matches STR."
-  (memq nil (mapcar (lambda (regexp)
-                      (not (string-match regexp str)))
-                    lst)))
+  (and lst (string-match (string-join lst "\\|") str)))
 
 ;; other "toggles"
 
diff --git a/test/lisp/erc/erc-match-tests.el b/test/lisp/erc/erc-match-tests.el
new file mode 100644
index 0000000000..aed23e665d
--- /dev/null
+++ b/test/lisp/erc/erc-match-tests.el
@@ -0,0 +1,121 @@
+;;; erc-match-tests.el --- Tests for erc-match.  -*- lexical-binding:t -*-
+
+;; Copyright (C) 2022 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+;;; Code:
+
+(require 'ert-x)
+(require 'erc-match)
+
+(ert-deftest erc-pals ()
+  (with-temp-buffer
+    (setq erc-server-process (start-process "true" (current-buffer) "true")
+          erc-server-users (make-hash-table :test #'equal))
+    (set-process-query-on-exit-flag erc-server-process nil)
+    (erc-add-server-user "FOO[m]" (make-erc-server-user :nickname "foo[m]"))
+    (erc-add-server-user "tester" (make-erc-server-user :nickname "tester"))
+
+    (let (erc-pals calls rvs)
+      (cl-letf (((symbol-function 'completing-read)
+                 (lambda (&rest r) (push r calls) (pop rvs))))
+
+        (ert-info ("`erc-add-pal'")
+          (push "foo[m]" rvs)
+          (ert-simulate-command '(erc-add-pal))
+          (should (equal (cadr (pop calls)) '(("tester") ("foo[m]"))))
+          (should (equal erc-pals '("foo\\[m]"))))
+
+        (ert-info ("`erc-match-pal-p'")
+          (should (erc-match-pal-p "FOO[m][email-masked]" nil)))
+
+        (ert-info ("`erc-delete-pal'")
+          (push "foo\\[m]" rvs)
+          (ert-simulate-command '(erc-delete-pal))
+          (should (equal (cadr (pop calls)) '(("foo\\[m]"))))
+          (should-not erc-pals))))))
+
+(ert-deftest erc-fools ()
+  (with-temp-buffer
+    (setq erc-server-process (start-process "true" (current-buffer) "true")
+          erc-server-users (make-hash-table :test #'equal))
+    (set-process-query-on-exit-flag erc-server-process nil)
+    (erc-add-server-user "FOO[m]" (make-erc-server-user :nickname "foo[m]"))
+    (erc-add-server-user "tester" (make-erc-server-user :nickname "tester"))
+
+    (let (erc-fools calls rvs)
+      (cl-letf (((symbol-function 'completing-read)
+                 (lambda (&rest r) (push r calls) (pop rvs))))
+
+        (ert-info ("`erc-add-fool'")
+          (push "foo[m]" rvs)
+          (ert-simulate-command '(erc-add-fool))
+          (should (equal (cadr (pop calls)) '(("tester") ("foo[m]"))))
+          (should (equal erc-fools '("foo\\[m]"))))
+
+        (ert-info ("`erc-match-fool-p'")
+          (should (erc-match-fool-p "FOO[m][email-masked]" ""))
+          (should (erc-match-fool-p "[email-masked]" "FOO[m]: die")))
+
+        (ert-info ("`erc-delete-fool'")
+          (push "foo\\[m]" rvs)
+          (ert-simulate-command '(erc-delete-fool))
+          (should (equal (cadr (pop calls)) '(("foo\\[m]"))))
+          (should-not erc-fools))))))
+
+(ert-deftest erc-keywords ()
+  (let (erc-keywords calls rvs)
+    (cl-letf (((symbol-function 'completing-read)
+               (lambda (&rest r) (push r calls) (pop rvs))))
+
+      (ert-info ("`erc-add-keyword'")
+        (push "[cit. needed]" rvs)
+        (ert-simulate-command '(erc-add-keyword))
+        (should (equal (cadr (pop calls)) nil))
+        (should (equal erc-keywords '("\\[cit\\. needed]"))))
+
+      (ert-info ("`erc-match-keyword-p'")
+        (should (erc-match-keyword-p nil "is pretty [cit. needed]")))
+
+      (ert-info ("`erc-delete-keyword'")
+        (push "\\[cit\\. needed]" rvs)
+        (ert-simulate-command '(erc-delete-keyword))
+        (should (equal (cadr (pop calls)) '(("\\[cit\\. needed]"))))
+        (should-not erc-keywords)))))
+
+(ert-deftest erc-dangerous-hosts ()
+  (let (erc-dangerous-hosts calls rvs)
+    (cl-letf (((symbol-function 'completing-read)
+               (lambda (&rest r) (push r calls) (pop rvs))))
+
+      (ert-info ("`erc-add-dangerous-host'")
+        (push "example.net" rvs)
+        (ert-simulate-command '(erc-add-dangerous-host))
+        (should (equal (cadr (pop calls)) nil))
+        (should (equal erc-dangerous-hosts '("example\\.net"))))
+
+      (ert-info ("`erc-match-dangerous-host-p'")
+        (should (erc-match-dangerous-host-p "FOO[m][email-masked]" nil)))
+
+      (ert-info ("`erc-delete-dangerous-host'")
+        (push "example\\.net" rvs)
+        (ert-simulate-command '(erc-delete-dangerous-host))
+        (should (equal (cadr (pop calls)) '(("example\\.net"))))
+        (should-not erc-dangerous-hosts)))))
+
+;;; erc-match-tests.el ends here
-- 
2.36.1

>From 0e8a8d030117022b6e3beaf7ab76c8bf70ff29a7 Mon Sep 17 00:00:00 2001
From: "F. Jason Park" <[email-masked]>
Date: Wed, 6 Jul 2022 20:53:41 -0700
Subject: [PATCH 2/2] Add command to jump to erc-match keywords

* lisp/erc/erc-match.el (erc-match-next-keyword,
erc-match-previous-keyword): Add new commands.

* tests/lisp/erc/erc-match-tests.el: New file.
---
 lisp/erc/erc-match.el            | 31 +++++++++++++-
 test/lisp/erc/erc-match-tests.el | 72 ++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+), 1 deletion(-)

diff --git a/lisp/erc/erc-match.el b/lisp/erc/erc-match.el
index 20fe640225..76bda8c467 100644
--- a/lisp/erc/erc-match.el
+++ b/lisp/erc/erc-match.el
@@ -520,7 +520,7 @@ erc-match-message
 			     (face match-face))
 			 (when (consp regex)
 			   (setq regex (car elt)
-				 face (cdr elt)))
+                                 face (list (cadr elt) 'erc-keyword-face)))
 			 (goto-char (+ 2 (or nick-end
 					     (point-min))))
 			 (while (re-search-forward regex nil t)
@@ -647,6 +647,35 @@ erc-beep-on-match
   (when (member match-type erc-beep-match-types)
     (beep)))
 
+(declare-function text-property-search-forward "text-property-search"
+                  (property &optional value predicate not-current))
+(declare-function text-property-search-backward "text-property-search"
+                  (property &optional value predicate not-current))
+
+(defun erc-match-next-keyword (arg)
+  "Jump to the ARGth next keyword, if any."
+  (interactive "p")
+  (require 'text-property-search)
+  (let* ((f (if (< arg 0)
+                #'text-property-search-backward
+              #'text-property-search-forward))
+         (i (1+ (abs arg)))
+         (test (lambda (a b) (if (consp b) (memq a b) (eq a b))))
+         (args `(font-lock-face erc-keyword-face ,test t))
+         (opoint (and (> (point) erc-insert-marker) (point)))
+         m)
+    (when opoint
+      (goto-char erc-insert-marker))
+    (while (and (not (zerop (cl-decf i))) (setq m (apply f args)))
+      (goto-char (prop-match-beginning m)))
+    (unless (or m (not opoint))
+      (goto-char opoint))))
+
+(defun erc-match-previous-keyword (arg)
+  "Jump to the ARGth previous keyword, if any"
+  (interactive "p")
+  (erc-match-next-keyword (- arg)))
+
 (provide 'erc-match)
 
 ;;; erc-match.el ends here
diff --git a/test/lisp/erc/erc-match-tests.el b/test/lisp/erc/erc-match-tests.el
index aed23e665d..7f0159544f 100644
--- a/test/lisp/erc/erc-match-tests.el
+++ b/test/lisp/erc/erc-match-tests.el
@@ -118,4 +118,76 @@ erc-dangerous-hosts
         (should (equal (cadr (pop calls)) '(("example\\.net"))))
         (should-not erc-dangerous-hosts)))))
 
+(defun erc-match-tests--populate ()
+  (let ((erc-keywords `("five" ("six" font-lock-string-face) "\\<t.."))
+        (erc-insert-modify-hook '(erc-match-message)))
+
+    (erc-display-message
+     (make-erc-response
+      :sender "[email-masked]"
+      :command "PRIVMSG"
+      :contents "one two three"
+      :command-args '("#chan" "one two three"))
+     nil (current-buffer)
+     (erc-format-privmessage "alice" "one two three" nil t))
+
+    (erc-display-message
+     (make-erc-response
+      :sender "[email-masked]"
+      :command "PRIVMSG"
+      :contents "four five six"
+      :command-args '("#chan" "four five six"))
+     nil (current-buffer)
+     (erc-format-privmessage "bob" "four five six" nil t))))
+
+(ert-deftest erc-match-next-keyword ()
+  (with-current-buffer (get-buffer-create "#chan")
+    (erc-mode)
+    (insert "\n\n")
+    (setq erc-input-marker (make-marker)
+          erc-insert-marker (make-marker)
+          erc-server-current-nick "tester")
+    (set-marker erc-insert-marker (point-max))
+    (erc-display-prompt)
+    (erc-match-tests--populate)
+    (should (= (point) erc-input-marker))
+
+    (ert-info ("Back once")
+      (ert-simulate-command '(erc-match-next-keyword -1))
+      (should (looking-at "six")))
+
+    (ert-info ("Back twice")
+      (ert-simulate-command '(erc-match-next-keyword -2))
+      (should (looking-at "three")))
+
+    (ert-info ("Overshoot")
+      (ert-simulate-command '(erc-match-next-keyword -2))
+      (should (looking-at "two")))
+
+    (ert-info ("About face")
+      (ert-simulate-command '(erc-match-next-keyword 1))
+      (should (looking-at "three")))
+
+    (ert-info ("About face")
+      (ert-simulate-command '(erc-match-next-keyword 1))
+      (should (looking-at "five")))
+
+    (ert-info ("Miss backward")
+      (ert-simulate-command '(erc-match-next-keyword -100))
+      (should (looking-at "two"))
+      (backward-char)
+      (let ((p (point)))
+        (ert-simulate-command '(erc-match-next-keyword -100))
+        (should (= p (point)))))
+
+    (ert-info ("Miss forwards")
+      (ert-simulate-command '(erc-match-next-keyword 100))
+      (should (looking-at "six"))
+      (goto-char (1+ (line-end-position)))
+      (let ((p (point)))
+        (ert-simulate-command '(erc-match-next-keyword 1))
+        (should (= p (point)))))
+
+    (when noninteractive (kill-buffer))))
+
 ;;; erc-match-tests.el ends here
-- 
2.36.1