Subject: bug#56449: 29.0.50; Revisit target shortcuts in erc-message

From: "J.P." <[email-masked]>
Date: Fri, 08 Jul 2022 06:21:29 -0700

Tags: patch

The purpose of the function `erc-message' is to provide a "target
shortcut" option to a handful of "slash" commands, mostly ones emitting
a PRIVMSG. When a user invoking such a command supplies a period or a
comma instead of a channel or a nick, whatever's stored in the relevant
slot of `erc-server-last-peers' gets substituted in the outgoing
message. IOW, issuing a

  ERC> /MSG , hi

recalls the last nick to speak over a given connection. And

  ERC> /MSG . hi

reuses the target (channel or query) from the last `erc-message'
invocation, which may have been something like

  ERC> /MSG bob hi

with no actual shortcut present. As it happens, these targets are
stashed in the default value shared across all connections, which is
almost certainly undesirable. But attempting to fix it forces us to
confront some basic usability concerns that vary based on whatever we
deem to be the feature's intended "scope":

1. Network (patch)

   The name of the variable in question, `erc-server-last-peers', may
   suggest that this feature should be scoped per IRC connection. But
   what's the point of blindly addressing the last speaker among all of
   a network's buffers without knowing exactly who you're engaging?

2. Buffer-local

   Using a "," for PM'ing the last speaker in a target buffer may lead
   to a surprise if anyone else speaks before you've submitted the
   input. As with (1), only the logs know for sure. Also, the "." form
   is only useful so long as you refrain from speaking.

For now, I propose temporarily adopting (1) by confining shared values
to server buffers. As far as attempting to renovate this feature goes
(rather than, say, tacitly retiring it), I think it's worth considering
that nick completion and abbrevs have long provided capable
alternatives.

In that vein, the last patch below claims to offer a compromise that
somewhat extends the existing pcomplete integration for the affected
slash commands so that dots and commas expand to their relevant targets
in the input area. This reduces potential targeting errors by offering
visual confirmation. IOW, if the last person to speak was Alice, typing

  ERC> /m ,[TAB]

would expand to

  ERC> /m alice _

And while this demo is built atop (1), the idea could easily be adapted
for (2) or another variant. BTW, if anyone has experience with
pcomplete, I'm pretty sure I committed an epic faceplant in trying to
apply the API. If we end up going with this, please help. But, for now,
the door remains wide open, and alternative solutions are more than
welcome.

Thanks,
J.P.

P.S. This bug isn't (yet) claimed by any particular ERC release.

In GNU Emacs 29.0.50 (build 1, x86_64-pc-linux-gnu, GTK+ Version 3.24.34, cairo version 1.17.6)
 of 2022-07-06 built on localhost
Repository revision: e6504c3eda12c72268d2db6598764f043b74c24d
Repository branch: master
Windowing system distributor 'The X.Org Foundation', version 11.0.12014000
System Description: Fedora Linux 36 (Workstation Edition)

Configured using:
 'configure --enable-check-lisp-object-type --enable-checking=yes,glyphs
 'CFLAGS=-O0 -g3'
 PKG_CONFIG_PATH=:/usr/lib64/pkgconfig:/usr/share/pkgconfig'

Configured features:
ACL CAIRO DBUS FREETYPE GIF GLIB GMP GNUTLS GPM GSETTINGS HARFBUZZ JPEG
JSON LCMS2 LIBOTF LIBSELINUX LIBSYSTEMD LIBXML2 M17N_FLT MODULES NOTIFY
INOTIFY PDUMPER PNG RSVG SECCOMP SOUND SQLITE3 THREADS TIFF
TOOLKIT_SCROLL_BARS WEBP X11 XDBE XIM XINPUT2 XPM GTK3 ZLIB

Important settings:
  value of $LANG: en_US.UTF-8
  value of $XMODIFIERS: @im=ibus
  locale-coding-system: utf-8-unix

Major mode: Lisp Interaction

Minor modes in effect:
  tooltip-mode: t
  global-eldoc-mode: t
  eldoc-mode: t
  show-paren-mode: t
  electric-indent-mode: t
  mouse-wheel-mode: t
  tool-bar-mode: t
  menu-bar-mode: t
  file-name-shadow-mode: t
  global-font-lock-mode: t
  font-lock-mode: t
  blink-cursor-mode: t
  line-number-mode: t
  indent-tabs-mode: t
  transient-mark-mode: t
  auto-composition-mode: t
  auto-encryption-mode: t
  auto-compression-mode: t

Load-path shadows:
None found.

Features:
(shadow sort mail-extr emacsbug message mailcap yank-media puny dired
dired-loaddefs rfc822 mml mml-sec password-cache epa derived epg rfc6068
epg-config gnus-util text-property-search time-date subr-x mm-decode
mm-bodies mm-encode mail-parse rfc2231 mailabbrev gmm-utils mailheader
cl-loaddefs cl-lib sendmail rfc2047 rfc2045 ietf-drums mm-util
mail-prsvr mail-utils rmc iso-transl tooltip eldoc paren electric
uniquify ediff-hook vc-hooks lisp-float-type elisp-mode mwheel
term/x-win x-win term/common-win x-dnd tool-bar dnd fontset image
regexp-opt fringe tabulated-list replace newcomment text-mode lisp-mode
prog-mode register page tab-bar menu-bar rfn-eshadow isearch easymenu
timer select scroll-bar mouse jit-lock font-lock syntax font-core
term/tty-colors frame minibuffer nadvice seq simple cl-generic
indonesian philippine cham georgian utf-8-lang misc-lang vietnamese
tibetan thai tai-viet lao korean japanese eucjp-ms cp51932 hebrew greek
romanian slovak czech european ethiopic indian cyrillic chinese
composite emoji-zwj charscript charprop case-table epa-hook
jka-cmpr-hook help abbrev obarray oclosure cl-preloaded button loaddefs
faces cus-face macroexp files window text-properties overlay sha1 md5
base64 format env code-pages mule custom widget keymap
hashtable-print-readable backquote threads dbusbind inotify lcms2
dynamic-setting system-font-setting font-render-setting cairo
move-toolbar gtk x-toolkit xinput2 x multi-tty make-network-process
emacs)

Memory information:
((conses 16 35545 5688)
 (symbols 48 5073 0)
 (strings 32 13303 1546)
 (string-bytes 1 429956)
 (vectors 16 9197)
 (vector-slots 8 145428 11407)
 (floats 8 21 25)
 (intervals 56 214 0)
 (buffers 992 10))
>From 803064a22318abcbcc3fe700884186c51b6fd039 Mon Sep 17 00:00:00 2001
From: "F. Jason Park" <[email-masked]>
Date: Wed, 6 Jul 2022 00:40:42 -0700
Subject: [PATCH 1/3] ; Demo mutating default value of `erc-server-last-peers'

---
 test/lisp/erc/erc-tests.el | 88 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)

diff --git a/test/lisp/erc/erc-tests.el b/test/lisp/erc/erc-tests.el
index 4971d0e194..373f5f16b0 100644
--- a/test/lisp/erc/erc-tests.el
+++ b/test/lisp/erc/erc-tests.el
@@ -893,4 +893,92 @@ erc-process-input-line
 
           (should-not calls))))))
 
+;; Note: if adding an erc-backend-tests.el, please relocate this there.
+
+(ert-deftest erc-message ()
+  (unless (equal erc-server-last-peers '(nil . nil))
+    (setq erc-server-last-peers (cons nil nil)))
+  (let (server-proc
+        calls
+        erc-kill-channel-hook erc-kill-server-hook erc-kill-buffer-hook)
+    (cl-letf (((symbol-function 'erc-display-message)
+               (lambda (_ _ _ line) (push line calls)))
+              ((symbol-function 'erc-server-send)
+               (lambda (line _) (push line calls)))
+              ((symbol-function 'erc-server-buffer)
+               (lambda () (process-buffer server-proc))))
+      (with-current-buffer (get-buffer-create "ExampleNet")
+        (erc-mode)
+        (setq erc-server-current-nick "tester"
+              server-proc (start-process "sleep" (current-buffer) "sleep" "1")
+              erc-server-process server-proc
+              erc-server-last-peers (cons nil nil)
+              erc-server-users (make-hash-table :test 'equal)
+              erc-network 'ExampleNet)
+        (set-process-query-on-exit-flag erc-server-process nil))
+
+      (with-current-buffer (get-buffer-create "#chan")
+        (erc-mode)
+        (setq erc-server-process (buffer-local-value 'erc-server-process
+                                                     (get-buffer "ExampleNet"))
+              erc-default-recipients '("#chan")
+              erc-channel-users (make-hash-table :test 'equal)
+              erc-network 'ExampleNet)
+        (erc-update-current-channel-member "alice" "alice")
+        (erc-update-current-channel-member "tester" "tester"))
+
+      (with-current-buffer "ExampleNet"
+        (erc-server-PRIVMSG erc-server-process
+                            (make-erc-response
+                             :sender "[email-masked]"
+                             :command "PRIVMSG"
+                             :command-args '("#chan" "hi")
+                             :unparsed ":[email-masked] PRIVMSG #chan :hi"))
+        (should (equal erc-server-last-peers '("alice")))
+        (should (string-match "<alice>" (pop calls))))
+
+      (with-current-buffer "#chan"
+        (ert-info ("Shortcuts unusable in target buffers")
+          (should-not (local-variable-p 'erc-server-last-peers))
+          (should (equal erc-server-last-peers '(nil . nil)))
+          (erc-message "PRIVMSG" ". hi")
+          (should (equal erc-server-last-peers '(nil . nil)))
+          (should (eq 'no-target (pop calls)))
+          (erc-message "PRIVMSG" ", hi")
+          (should (equal erc-server-last-peers '(nil . nil)))
+          (should (eq 'no-target (pop calls)))))
+
+      (with-current-buffer "ExampleNet"
+        (ert-info ("Shortcuts local in server bufs")
+          (should (equal erc-server-last-peers '("alice")))
+          (erc-message "PRIVMSG" ", hi")
+          (should (equal erc-server-last-peers '("alice" . "alice")))
+          (should (string-match "PRIVMSG alice :hi" (pop calls)))
+          (setcdr erc-server-last-peers "bob")
+          (erc-message "PRIVMSG" ". hi")
+          (should (equal erc-server-last-peers '("alice" . "bob")))
+          (should (string-match "PRIVMSG bob :hi" (pop calls)))))
+
+      (with-current-buffer "#chan"
+        (ert-info ("Non-shortcuts affect global default")
+          (should-not (local-variable-p 'erc-server-last-peers))
+          (should (equal erc-server-last-peers '(nil . nil)))
+          (erc-message "PRIVMSG" "#chan hola")
+          (should (equal erc-server-last-peers '(nil . "#chan")))
+          (should (equal (default-value 'erc-server-last-peers)
+                         '(nil . "#chan")))
+          (should (string-match "hola" (pop calls))))
+
+        (ert-info ("Dot shortcut now usable in target buffers")
+          (erc-message "PRIVMSG" ". how")
+          (should (equal erc-server-last-peers '(nil . "#chan")))
+          (should (string-match "how" (pop calls))))))
+
+    (should (equal (default-value 'erc-server-last-peers) '(nil . "#chan")))
+    (setq erc-server-last-peers (cons nil nil))
+    (should (equal erc-server-last-peers '(nil . nil)))
+    (should-not calls)
+    (kill-buffer "ExampleNet")
+    (kill-buffer "#chan")))
+
 ;;; erc-tests.el ends here
-- 
2.36.1

>From 93233064285554d24df1a3137194bae4edd1ec06 Mon Sep 17 00:00:00 2001
From: "F. Jason Park" <[email-masked]>
Date: Wed, 29 Jun 2022 04:05:52 -0700
Subject: [PATCH 2/3] [SQUASH] Avoid mutating default value of
 erc-server-last-peers

* lisp/erc/erc-backend.el (erc-server-last-peers): Define as nil
instead of a quoted constant.
(erc-server-connect): Initialize `erc-server-last-peers' to a new
value local to a server buffer.
(erc--message-shortcut): New function to store and recall senders and
receivers for the current connection when processing "."  and ","
shortcuts.
(erc-message): Delegate to `erc--message-shortcut' to handle
shortcuts.
(erc-server-PRIVMSG): Create a new `erc-server-last-peers' for every
message received to make for easier testing.
---
 lisp/erc/erc-backend.el    | 31 +++++++++++++++--------------
 test/lisp/erc/erc-tests.el | 40 ++++++++++++++++----------------------
 2 files changed, 33 insertions(+), 38 deletions(-)

diff --git a/lisp/erc/erc-backend.el b/lisp/erc/erc-backend.el
index bc7a7d14dc..ea1891da0b 100644
--- a/lisp/erc/erc-backend.el
+++ b/lisp/erc/erc-backend.el
@@ -230,7 +230,7 @@ erc-server-error-occurred
 (defvar-local erc-server-lines-sent nil
   "Line counter.")
 
-(defvar-local erc-server-last-peers '(nil . nil)
+(defvar-local erc-server-last-peers nil
   "Last peers used, both sender and receiver.
 Those are used for /MSG destination shortcuts.")
 
@@ -562,7 +562,7 @@ erc-server-connect
         (setq erc-server-last-received-time time))
       (setq erc-server-lines-sent 0)
       ;; last peers (sender and receiver)
-      (setq erc-server-last-peers '(nil . nil)))
+      (setq erc-server-last-peers (cons nil nil)))
     ;; we do our own encoding and decoding
     (when (fboundp 'set-process-coding-system)
       (set-process-coding-system process 'raw-text))
@@ -931,29 +931,30 @@ erc-server-send-queue
                 (run-at-time (+ 0.2 erc-server-flood-penalty)
                              nil #'erc-server-send-queue buffer)))))))
 
+(defun erc--message-shortcut (arg &optional commit)
+  (let* ((buffer (erc-server-buffer))
+         (peers (buffer-local-value 'erc-server-last-peers buffer))
+         (tgt (pcase arg ("," (car peers)) ("." (cdr peers)) (_ arg))))
+    (when tgt
+      (when commit
+        (with-current-buffer buffer
+          (setq erc-server-last-peers (cons (car peers) tgt))))
+      tgt)))
+
 (defun erc-message (message-command line &optional force)
   "Send LINE to the server as a privmsg or a notice.
 MESSAGE-COMMAND should be either \"PRIVMSG\" or \"NOTICE\".
 If the target is \",\", the last person you've got a message from will
 be used.  If the target is \".\", the last person you've sent a message
-to will be used."
+to will be used.  Note that as of ERC 5.6, this syntax is considered
+deprecated.  See the pcomplete module for similar functionality."
   (cond
    ((string-match "^\\s-*\\(\\S-+\\) ?\\(.*\\)" line)
-    (let ((tgt (match-string 1 line))
+    (let ((tgt (erc--message-shortcut (match-string 1 line) 'commit))
           (s (match-string 2 line)))
       (erc-log (format "cmd: MSG(%s): [%s] %s" message-command tgt s))
-      (cond
-       ((string= tgt ",")
-        (if (car erc-server-last-peers)
-            (setq tgt (car erc-server-last-peers))
-          (setq tgt nil)))
-       ((string= tgt ".")
-        (if (cdr erc-server-last-peers)
-            (setq tgt (cdr erc-server-last-peers))
-          (setq tgt nil))))
       (cond
        (tgt
-        (setcdr erc-server-last-peers tgt)
         (erc-server-send (format "%s %s :%s" message-command tgt s)
                          force))
        (t
@@ -1550,7 +1551,7 @@ define-erc-response-handler
                     (erc-process-ctcp-reply proc parsed nick login host
                                             (match-string 1 msg)))))
          (t
-          (setcar erc-server-last-peers nick)
+          (setq erc-server-last-peers (cons nick (cdr erc-server-last-peers)))
           (setq s (erc-format-privmessage
                    (or fnick nick) msg
                    ;; If buffer is a query buffer,
diff --git a/test/lisp/erc/erc-tests.el b/test/lisp/erc/erc-tests.el
index 373f5f16b0..0f222edacf 100644
--- a/test/lisp/erc/erc-tests.el
+++ b/test/lisp/erc/erc-tests.el
@@ -896,8 +896,7 @@ erc-process-input-line
 ;; Note: if adding an erc-backend-tests.el, please relocate this there.
 
 (ert-deftest erc-message ()
-  (unless (equal erc-server-last-peers '(nil . nil))
-    (setq erc-server-last-peers (cons nil nil)))
+  (should-not erc-server-last-peers)
   (let (server-proc
         calls
         erc-kill-channel-hook erc-kill-server-hook erc-kill-buffer-hook)
@@ -938,19 +937,19 @@ erc-message
         (should (string-match "<alice>" (pop calls))))
 
       (with-current-buffer "#chan"
-        (ert-info ("Shortcuts unusable in target buffers")
+        (ert-info ("Shortcuts usable in target buffers")
           (should-not (local-variable-p 'erc-server-last-peers))
-          (should (equal erc-server-last-peers '(nil . nil)))
+          (should-not erc-server-last-peers)
           (erc-message "PRIVMSG" ". hi")
-          (should (equal erc-server-last-peers '(nil . nil)))
+          (should-not erc-server-last-peers)
           (should (eq 'no-target (pop calls)))
           (erc-message "PRIVMSG" ", hi")
-          (should (equal erc-server-last-peers '(nil . nil)))
-          (should (eq 'no-target (pop calls)))))
+          (should-not erc-server-last-peers)
+          (should (string-match "alice :hi" (pop calls)))))
 
       (with-current-buffer "ExampleNet"
         (ert-info ("Shortcuts local in server bufs")
-          (should (equal erc-server-last-peers '("alice")))
+          (should (equal erc-server-last-peers '("alice" . "alice")))
           (erc-message "PRIVMSG" ", hi")
           (should (equal erc-server-last-peers '("alice" . "alice")))
           (should (string-match "PRIVMSG alice :hi" (pop calls)))
@@ -960,23 +959,18 @@ erc-message
           (should (string-match "PRIVMSG bob :hi" (pop calls)))))
 
       (with-current-buffer "#chan"
-        (ert-info ("Non-shortcuts affect global default")
+        (ert-info ("Non-shortcuts are local to server buffer")
           (should-not (local-variable-p 'erc-server-last-peers))
-          (should (equal erc-server-last-peers '(nil . nil)))
+          (should-not erc-server-last-peers)
           (erc-message "PRIVMSG" "#chan hola")
-          (should (equal erc-server-last-peers '(nil . "#chan")))
-          (should (equal (default-value 'erc-server-last-peers)
-                         '(nil . "#chan")))
-          (should (string-match "hola" (pop calls))))
-
-        (ert-info ("Dot shortcut now usable in target buffers")
-          (erc-message "PRIVMSG" ". how")
-          (should (equal erc-server-last-peers '(nil . "#chan")))
-          (should (string-match "how" (pop calls))))))
-
-    (should (equal (default-value 'erc-server-last-peers) '(nil . "#chan")))
-    (setq erc-server-last-peers (cons nil nil))
-    (should (equal erc-server-last-peers '(nil . nil)))
+          (should-not erc-server-last-peers)
+          (should-not (default-value 'erc-server-last-peers))
+          (should (equal (buffer-local-value 'erc-server-last-peers
+                                             (get-buffer "ExampleNet"))
+                         '("alice" . "#chan")))
+          (should (string-match "hola" (pop calls))))))
+
+    (should-not erc-server-last-peers)
     (should-not calls)
     (kill-buffer "ExampleNet")
     (kill-buffer "#chan")))
-- 
2.36.1

>From 87426c1a071c498b1780b1e2ef2a98c6ec90b2eb Mon Sep 17 00:00:00 2001
From: "F. Jason Park" <[email-masked]>
Date: Thu, 7 Jul 2022 02:04:40 -0700
Subject: [PATCH 3/3] [POC/FIXME] Add erc-message shortcuts to erc-pcomplete

* lisp/erc/erc-pcomplete.el (pcomplete/erc-mode/MSG): Intercept a "."
or a "," shortcut and possibly expand it in place, almost like an
abbrev, to a target stored in `erc-server-last-peers'.  This should
probably be done elsewhere, such as during initial command-line
parsing.  Someone familiar with pcomplete please help!
---
 lisp/erc/erc-pcomplete.el | 7 +++++++
 1 file changed, 7 insertions(+)

diff --git a/lisp/erc/erc-pcomplete.el b/lisp/erc/erc-pcomplete.el
index af8528dbc3..be733f17e9 100644
--- a/lisp/erc/erc-pcomplete.el
+++ b/lisp/erc/erc-pcomplete.el
@@ -144,6 +144,12 @@ pcomplete/erc-mode/SAY
   (while (pcomplete-here (pcomplete-erc-nicks))))
 
 (defun pcomplete/erc-mode/MSG ()
+  (when-let* (((= 1 pcomplete-index pcomplete-last))
+              (a (pcomplete-arg 1 1))
+              ((member a '("." ",")))
+              (s (erc--message-shortcut a)))
+    (with-silent-modifications (delete-char -1))
+    (pcomplete-here (list s) ""))
   (pcomplete-here (append (pcomplete-erc-all-nicks)
                           (pcomplete-erc-channels)))
   (while (pcomplete-here (pcomplete-erc-nicks))))
@@ -152,6 +158,7 @@ pcomplete/erc-mode/NAMES
   (while (pcomplete-here (pcomplete-erc-channels))))
 
 (defalias 'pcomplete/erc-mode/NOTICE #'pcomplete/erc-mode/MSG)
+(defalias 'pcomplete/erc-mode/M #'pcomplete/erc-mode/MSG)
 
 (defun pcomplete/erc-mode/OP ()
   (while (pcomplete-here (pcomplete-erc-not-ops))))
-- 
2.36.1