Subject: Re: bug#56335: 29.0.50; [PATCH] Add more breakpoint chars support to longlines-mode

From: Manuel Giraud <[email-masked]>
Date: Wed, 06 Jul 2022 09:43:37 +0200

Lars Ingebrigtsen <[email-masked]> writes:

> Manuel Giraud <[email-masked]> writes:
>
>> Here is a new patch for longlines-mode. It updates substring filtering
>> to the new interface and do not replace soft newlines with spaces
>> anymore. So now, copy/pasting from a longlines buffer should work as
>> intended.
>
> This leads to
>
> In longlines-encode-string:
> longlines.el:394:18: Warning: assignment to free variable `pos'
> longlines.el:395:24: Warning: reference to free variable `pos'

Sorry, here is a new version of the patch.
>From c5739c078834afe85e96da3867c2c702694619be Mon Sep 17 00:00:00 2001
From: Manuel Giraud <[email-masked]>
Date: Tue, 5 Jul 2022 14:38:43 +0200
Subject: [PATCH] [longlines] substring update

* lisp/longlines.el (longlines-mode, longlines-encode-string): Update
from `buffer-substring-filters' to `filter-buffer-substring-function'.
Remove soft newlines in substring.
---
 lisp/longlines.el | 32 ++++++++++++++++++++------------
 1 file changed, 20 insertions(+), 12 deletions(-)

diff --git a/lisp/longlines.el b/lisp/longlines.el
index a6cf93a039..6dc2f61ed9 100644
--- a/lisp/longlines.el
+++ b/lisp/longlines.el
@@ -118,7 +118,6 @@ longlines-mode
         (add-to-list 'buffer-file-format 'longlines)
         (add-hook 'change-major-mode-hook #'longlines-mode-off nil t)
 	(add-hook 'before-revert-hook #'longlines-before-revert-hook nil t)
-        (make-local-variable 'buffer-substring-filters)
         (make-local-variable 'longlines-auto-wrap)
 	(set (make-local-variable 'isearch-search-fun-function)
 	     #'longlines-search-function)
@@ -126,7 +125,8 @@ longlines-mode
 	     #'longlines-search-forward)
 	(set (make-local-variable 'replace-re-search-function)
 	     #'longlines-re-search-forward)
-        (add-to-list 'buffer-substring-filters 'longlines-encode-string)
+        (add-function :filter-return (local 'filter-buffer-substring-function)
+                      #'longlines-encode-string)
         (when longlines-wrap-follows-window-size
 	  (let ((dw (if (and (integerp longlines-wrap-follows-window-size)
 			     (>= longlines-wrap-follows-window-size 0)
@@ -143,7 +143,7 @@ longlines-mode
 	      (inhibit-modification-hooks t)
               (mod (buffer-modified-p))
 	      buffer-file-name buffer-file-truename)
-          ;; Turning off undo is OK since (spaces + newlines) is
+          ;; Turning off undo is OK since (separators + newlines) is
           ;; conserved, except for a corner case in
           ;; longlines-wrap-lines that we'll never encounter from here
 	  (save-restriction
@@ -202,7 +202,8 @@ longlines-mode
     (kill-local-variable 'replace-search-function)
     (kill-local-variable 'replace-re-search-function)
     (kill-local-variable 'require-final-newline)
-    (kill-local-variable 'buffer-substring-filters)
+    (remove-function (local 'filter-buffer-substring-function)
+                     #'longlines-encode-string)
     (kill-local-variable 'use-hard-newlines)))
 
 (defun longlines-mode-off ()
@@ -385,15 +386,22 @@ longlines-encode-region
       end)))
 
 (defun longlines-encode-string (string)
-  "Return a copy of STRING with each soft newline replaced by a space.
+  "Return a copy of STRING with each soft newline removed.
 Hard newlines are left intact."
-  (let* ((str (copy-sequence string))
-         (pos (string-search "\n" str)))
-    (while pos
-      (if (null (get-text-property pos 'hard str))
-          (aset str pos ? ))
-      (setq pos (string-search "\n" str (1+ pos))))
-    str))
+  (let ((start 0)
+        (result nil)
+        pos)
+    (while (setq pos (string-search "\n" string start))
+      (unless (= start pos)
+        (push (substring string start pos) result))
+      (when (get-text-property pos 'hard string)
+        (push (substring string pos (1+ pos)) result))
+      (setq start (1+ pos)))
+    (if (null result)
+        (copy-sequence string)
+      (unless (= start (length string))
+        (push (substring string start) result))
+      (apply #'concat (nreverse result)))))
 
 ;;; Auto wrap
 
-- 
2.36.1

-- 
Manuel Giraud