GNU bug report logs - #54780
[PATCH] gnu: lttng-ust: Fix dependencies.

Previous Next

Full log

Message #47 received at 54780 <at> debbugs.gnu.org (full text, mbox):

From: Maxime Devos <maximedevos <at> telenet.be>
To: Olivier Dion <olivier.dion <at> polymtl.ca>, 54780 <at> debbugs.gnu.org
Subject: Re: [bug#54780] [PATCH] gnu: lttng-ust: Fix dependencies.
Date: Sat, 09 Apr 2022 11:13:04 +0200

[Message part 1 (text/plain, inline)]

Maxime Devos schreef op za 09-04-2022 om 11:11 [+0200]:
> Right, lttng-ust can be used by other packages.
> There were some unaddressed TODOs in absolute-inclusions.scm, the
> attached absolute-icnlusion.scm addresses them.  But aside from that,

Oops I forgot to remove the 'pk'

[absolute-inclusions.scm (text/x-scheme, inline)]

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2022 Maxime Devos <maximedevos <at> telenet.be>
;;; Copyright © 2022 Olivier Dion <olivier.dion <at> polymtl.ca>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix build absolute-inclusions)
  #:use-module (guix build utils)
  #:use-module (ice-9 match)
  #:use-module (rnrs exceptions)
  #:export (absolute-inclusions patch-header-inclusions))

(define (excluded-input? input)
  ;; Exclude glibc to avoid increasing the closure size when a
  ;; static library + binary is build.  Likewise, exclude
  ;; linux-libre-headers.
  (match input
    ((_ . store-item)
     (or (file-exists? (string-append store-item "/include/stdlib.h"))
         (directory-exists? (string-append store-item "/include/linux"))))))

(define (absolute-inclusions files header-locations)
  (substitute* files
    (("^[ \t]*#[ \t]*include[ \t]*<(.*)>[ \t]*" original header-name)
     (guard (c ((search-error? c) original))
       (format #f "#include <~a>"
               (search-input-file header-locations
                (string-append "include/" header-name)))))))

(define header-file?
  ;; See gcc(1) for the list of suffixes.
  (let ((suffixes (list "h" "hh" "H" "hp" "hxx" "hpp" "HPP" "h++" "tcc")))
    (file-name-predicate
     (format #f "\\.(~a)$" (string-join suffixes "|" 'infix)))))

(define* (patch-header-inclusions #:key inputs outputs #:allow-other-keys)
  "Patch inclusions in C headers in OUTPUTS to use absolute file names."
  (define header-locations
    (filter (negate excluded-input?) (append outputs inputs)))
  (for-each (match-lambda
              ((_ . output)
               (absolute-inclusions
                (find-files (string-append output "/include")
                            header-file?)
                header-locations)))
            outputs))

[signature.asc (application/pgp-signature, inline)]

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.