Subject: bug#54100: 29.0.50; Allow project-buffers to ignore some buffers

From: Manuel Uberti <[email-masked]>
Date: Sat, 26 Feb 2022 07:32:49 +0100

On 26/02/22 02:50, Dmitry Gutov wrote:
> Looking at it more thoroughly, though, shouldn't we simply inline the check 
> added to project-switch-to-buffer to the function project--read-project-buffer?
> 
> It's used by two other related commands (project-display-buffer and 
> project-display-buffer-other-frame), and users would probably expect them to 
> have the same filtering.
> 
> project-ignore-buffer-conditions's docstring can be updated accordingly.

I like the idea. I attached a new version of the patch.

-- 
Manuel Uberti
www.manueluberti.eu

From ea92923b8e907c5f4b884481630a3ab12940ca99 Mon Sep 17 00:00:00 2001
From: Manuel Uberti <[email-masked]>
Date: Wed, 23 Feb 2022 09:25:32 +0100
Subject: [PATCH] Add project-ignore-buffer-conditions

* lisp/progmodes/project.el (project-ignore-buffer-conditions):
New defcustom.
(project--read-project-buffer):
Use it (bug#54100).
---
 lisp/progmodes/project.el | 47 ++++++++++++++++++++++++++++++---------
 1 file changed, 37 insertions(+), 10 deletions(-)

diff --git a/lisp/progmodes/project.el b/lisp/progmodes/project.el
index 880c5b5517..4d6b93ceb5 100644
--- a/lisp/progmodes/project.el
+++ b/lisp/progmodes/project.el
@@ -1112,6 +1112,29 @@ project-compile
              compilation-buffer-name-function)))
     (call-interactively #'compile)))
 
+(defcustom project-ignore-buffer-conditions nil
+  "List of conditions to filter the buffers to be switched to.
+If any of these conditions are satisfied for a buffer in the
+current project, `project-switch-to-buffer',
+`project-display-buffer' and `project-display-buffer-other-frame'
+ignore it.
+See the doc string of `project-kill-buffer-conditions' for the
+general form of conditions."
+  :type '(repeat (choice regexp function symbol
+                         (cons :tag "Major mode"
+                               (const major-mode) symbol)
+                         (cons :tag "Derived mode"
+                               (const derived-mode) symbol)
+                         (cons :tag "Negation"
+                               (const not) sexp)
+                         (cons :tag "Conjunction"
+                               (const and) sexp)
+                         (cons :tag "Disjunction"
+                               (const or) sexp)))
+  :version "29.1"
+  :group 'project
+  :package-version '(project . "0.8.2"))
+
 (defun project--read-project-buffer ()
   (let* ((pr (project-current t))
          (current-buffer (current-buffer))
@@ -1121,7 +1144,10 @@ project--read-project-buffer
          (predicate
           (lambda (buffer)
             ;; BUFFER is an entry (BUF-NAME . BUF-OBJ) of Vbuffer_alist.
-            (memq (cdr buffer) buffers))))
+            (and (memq (cdr buffer) buffers)
+                 (not
+                  (project--buffer-check
+                   (cdr buffer) project-ignore-buffer-conditions))))))
     (read-buffer
      "Switch to buffer: "
      (when (funcall predicate (cons other-name other-buffer))
@@ -1239,11 +1265,12 @@ project--buffer-list
         (push buf bufs)))
     (nreverse bufs)))
 
-(defun project--kill-buffer-check (buf conditions)
+(defun project--buffer-check (buf conditions)
   "Check if buffer BUF matches any element of the list CONDITIONS.
-See `project-kill-buffer-conditions' for more details on the form
-of CONDITIONS."
-  (catch 'kill
+See `project-kill-buffer-conditions' or
+`project-ignore-buffer-conditions' for more details on the
+form of CONDITIONS."
+  (catch 'match
     (dolist (c conditions)
       (when (cond
              ((stringp c)
@@ -1258,15 +1285,15 @@ project--kill-buffer-check
                (buffer-local-value 'major-mode buf)
                (cdr c)))
              ((eq (car-safe c) 'not)
-              (not (project--kill-buffer-check buf (cdr c))))
+              (not (project--buffer-check buf (cdr c))))
              ((eq (car-safe c) 'or)
-              (project--kill-buffer-check buf (cdr c)))
+              (project--buffer-check buf (cdr c)))
              ((eq (car-safe c) 'and)
               (seq-every-p
-               (apply-partially #'project--kill-buffer-check
+               (apply-partially #'project--buffer-check
                                 buf)
                (mapcar #'list (cdr c)))))
-        (throw 'kill t)))))
+        (throw 'match t)))))
 
 (defun project--buffers-to-kill (pr)
   "Return list of buffers in project PR to kill.
@@ -1274,7 +1301,7 @@ project--buffers-to-kill
 in `project-kill-buffer-conditions'."
   (let (bufs)
     (dolist (buf (project-buffers pr))
-      (when (project--kill-buffer-check buf project-kill-buffer-conditions)
+      (when (project--buffer-check buf project-kill-buffer-conditions)
         (push buf bufs)))
     bufs))
 
-- 
2.25.1