Subject: bug#51263: 29.0.50; [PATCH] Use run-at-time to read a password in comint

From: [email-masked]
Date: Mon, 18 Oct 2021 13:54:59 +0200

Currently, comint-watch-for-password-prompt has some problems. It is
called from the comint process filter and doesn't return until the user
exits the password minibuffer.

If the process produces more output while the minibuffer is still open
(this happens if the "sudo" command times out, for example), the process
filter will be called recursively before the current execution of the
process filter has a chance to finish. This filter function uses some
global/buffer-local, state (the variable comint-last-output-start, for
example), so it isn't made to be called simultaneously like that.

The user may also quit the password minibuffer with C-g, canceling
execution of the filter function.

The result of these two events is usually that the buffer text
containing the password prompt isn't correctly marked as output with the
'field text property. Further problems may arise if
comint-output-filter-functions contain functions after the password
prompt watcher.

I've come up with a solution: using (run-at-time 0 ...), we can prompt
for a password after the filter function finishes execution.  The
attached patch implements this for comint, eshell and term.el.

Best regards.

From d4e8af0f4d90c7d989f21781fc7ca7fd284652bf Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Miha=20Rihtar=C5=A1i=C4=8D?= <[email-masked]>
Date: Mon, 18 Oct 2021 13:13:45 +0200
Subject: [PATCH] *-watch-for-password-prompt: Use run-at-time to read password

* lisp/comint.el (comint-watch-for-password-prompt):
* lisp/eshell/esh-mode.el (eshell-watch-for-password-prompt):
* lisp/term.el (term-watch-for-password-prompt):
Use run-at-time to read a password.
---
 lisp/comint.el          | 18 +++++++++++++-----
 lisp/eshell/esh-mode.el |  9 ++++++++-
 lisp/term.el            |  9 ++++++++-
 3 files changed, 29 insertions(+), 7 deletions(-)

diff --git a/lisp/comint.el b/lisp/comint.el
index a0873c0b6a..e925b3a4b6 100644
--- a/lisp/comint.el
+++ b/lisp/comint.el
@@ -2455,11 +2455,19 @@ comint-watch-for-password-prompt
   (when (let ((case-fold-search t))
 	  (string-match comint-password-prompt-regexp
                         (string-replace "\r" "" string)))
-    (let ((comint--prompt-recursion-depth (1+ comint--prompt-recursion-depth)))
-      (if (> comint--prompt-recursion-depth 10)
-          (message "Password prompt recursion too deep")
-        (comint-send-invisible
-         (string-trim string "[ \n\r\t\v\f\b\a]+" "\n+"))))))
+    ;; Use `run-at-time' in order not to pause execution of the
+    ;; process filter with a minibuffer
+    (run-at-time
+     0 nil
+     (lambda (current-buf)
+       (with-current-buffer current-buf
+         (let ((comint--prompt-recursion-depth
+                (1+ comint--prompt-recursion-depth)))
+           (if (> comint--prompt-recursion-depth 10)
+               (message "Password prompt recursion too deep")
+             (comint-send-invisible
+              (string-trim string "[ \n\r\t\v\f\b\a]+" "\n+"))))))
+     (current-buffer))))
 
 ;; Low-level process communication
 
diff --git a/lisp/eshell/esh-mode.el b/lisp/eshell/esh-mode.el
index 98e89037f3..579b01f4d1 100644
--- a/lisp/eshell/esh-mode.el
+++ b/lisp/eshell/esh-mode.el
@@ -940,7 +940,14 @@ eshell-watch-for-password-prompt
 	(beginning-of-line)
 	(if (re-search-forward eshell-password-prompt-regexp
 			       eshell-last-output-end t)
-	    (eshell-send-invisible))))))
+            ;; Use `run-at-time' in order not to pause execution of
+            ;; the process filter with a minibuffer
+	    (run-at-time
+             0 nil
+             (lambda (current-buf)
+               (with-current-buffer current-buf
+                 (eshell-send-invisible)))
+             (current-buffer)))))))
 
 (custom-add-option 'eshell-output-filter-functions
 		   'eshell-watch-for-password-prompt)
diff --git a/lisp/term.el b/lisp/term.el
index dd5457745b..530b93484e 100644
--- a/lisp/term.el
+++ b/lisp/term.el
@@ -2409,7 +2409,14 @@ term-watch-for-password-prompt
   (when (term-in-line-mode)
     (when (let ((case-fold-search t))
             (string-match comint-password-prompt-regexp string))
-      (term-send-invisible (read-passwd string)))))
+      ;; Use `run-at-time' in order not to pause execution of the
+      ;; process filter with a minibuffer
+      (run-at-time
+       0 nil
+       (lambda (current-buf)
+         (with-current-buffer current-buf
+           (term-send-invisible (read-passwd string))))
+       (current-buffer)))))
 
 
 ;;; Low-level process communication
-- 
2.33.0