GNU bug report logs - #49316
Add apply-partially's right version

Previous Next

Full log

Message #37 received at 49316 <at> debbugs.gnu.org (full text, mbox):

From: Michael Heerdegen <michael_heerdegen <at> web.de>
To: daanturo <daanturo <at> gmail.com>
Cc: 49316 <at> debbugs.gnu.org
Subject: Re: bug#49316: Add apply-partially's right version
Date: Sat, 03 Jul 2021 05:06:18 +0200

daanturo <daanturo <at> gmail.com> writes:

> +(defun apply-mid-partially (fun position &rest args)
> +  "Return a function that is a partial application of FUN to ARGS at POSITION.

I'm not sure if I would prefer that.  Personally I guess I would like
something like this instead: A macro that allows partial application
that really looks like an application.

A placeholder (e.g. the symbol `_' which should normally be unbound)
stands for an argument that is used from the args provided in the actual
call:

#+begin_src emacs-lisp
(defmacro applying-partially (call)
  (let ((args (make-symbol "args")))
    `(lambda (&rest ,args)
       (apply #',(car call)
              ,@(mapcar (lambda (arg)
                          (if (eq arg '_)
                              `(pop ,args)
                            arg))
                        (cdr call))
              ,args))))

(defalias 'minus-10 (applying-partially (- _ 10)))

(minus-10 120) ;;  ==> 110

(defalias 'my-list-with-some-elts
  (applying-partially (list 0 _ 2 _ 4)))

(my-list-with-some-elts 'a 'b 'c 'd) ; => (0 a 2 b 4 c d)

(symbol-function 'my-list-with-some-elts)
;; => (closure (t) (&rest args)
;;      (apply #'list 0 (pop args) 2 (pop args) 4 args))
#+end_src

In my eyes that would be more general and a bit better readable (I like
when eldoc works with such stuff).


Regards,

Michael.

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.