Subject: bug#48328: switch-buffer-other-window keep-focus [POC INCLUDED]

From: Boruch Baum <[email-masked]>
Date: Mon, 10 May 2021 01:37:17 -0400

I was going through my init file, and realized that something I thought
was part of emacs-core was actually my simple wrapper function. IMO,
it's sensible and I find it very convenient when dealing with buried
buffers being used for reference (eg. occur, grep, help).

All it does is add a prefix-arg control to function
`switch-to-buffer-other-window' (C-x 4 b).

For your consideration:

(defcustom my-switch-to-buffer-other-window-keep-focus nil
  "Controls focus of buffer-switch to other window.
When non-NIL, function `my-switch-to-buffer-other-window' keeps
focus in the current window. This can be over-ridden at run-time
by passing that function a PREFIX-ARG."
  :type 'boolean)

(defun my-switch-to-buffer-other-window (buffer-or-name &optional norecord)
  "Wrapper to allow keeping focus in current window.
Performs action of function `switch-to-buffer-other-window', but
refers to variable `my-switch-to-buffer-other-window-keep-focus'
to determine whether to change focus to the other window. You can
over-ride that setting by calling this function with a
PREFIX-ARG."
  (interactive
   (list (read-buffer-to-switch "Switch to buffer in other window: ")))
  (let ((pop-up-windows t)
        (win (selected-window)))
    (pop-to-buffer buffer-or-name t norecord)
    (when (if current-prefix-arg
            (not my-switch-to-buffer-other-window-keep-focus)
           my-switch-to-buffer-other-window-keep-focus)
      (select-window win 'norecord)))) ; ie. norecord=t

(define-key ctl-x-4-map (kbd "b") 'my-switch-to-buffer-other-window)

--
hkp://keys.gnupg.net
CA45 09B5 5351 7C11 A9D1  7286 0036 9E45 1595 8BC0