Subject: bug#46573: 28.0.50; Error when edebugging setting unbound place

From: Stefan Monnier <[email-masked]>
Date: Mon, 01 Mar 2021 16:17:40 -0500

>> I checked older Emacs versions -- (setf foo 'bar) works in Emacs 26.1,
>> but not in Emacs 27.1.
> Then we should try fixing it in Emacs 27.2, if that's possible without
> risky changes.

I plan to install the patch below into `master` to fix this problem, but
I believe this change is sufficiently safe for the `emacs-27` branch, so
you agree I'll install it into `emacs-27` instead.

For code like

    (setf (car x) (cdr x))

The instrumented in Emacs-27.1 looked like:

    (let* ((v (edebug-after 0 2 x)))
      (progn
        (edebug-after (edebug-before 1) 3 (car v))
        (setcar v (edebug-after (edebug-before 4) 6
                                (cdr (edebug-after 0 5 x))))))

with the new code it will look like:

    (let* ((v (edebug-after 0 2 x)))
      (edebug-after
       (edebug-before 1) 3
       (setcar v (edebug-after (edebug-before 4) 6
                               (cdr (edebug-after 0 5 x))))))

For reference in Emacs-26, it looked like:

    (let* ((v (edebug-after 0 2 x)))
      (setcar v (edebug-after (edebug-before 4) 6
                              (cdr (edebug-after 0 5 x)))))

IIUC Gemini is too busy with real life to look at this now, but my
understanding of the motivation for his change was that the Emacs-26
code left instrumentation points 1 and 3 above completely unused (they
are generated by Edebug and then thrown away by macro expansion), giving
the mistaken impression (to the code-coverage checker) that these
execution paths are not exercised.  The new form should preserve the
benefit of Gemini's change in this respect while improving the behavior
during Edebug.

        Stefan

* lisp/emacs-lisp/gv.el (edebug-after): Don't run getter in the setter

This fixes bug#46573 which was introduced by commit
d79cf638f278e50c22feb53d6ba556f5ce9d7853.
The new code is a middle ground, which makes sure the instrumentation
point is used (so the coverage checker won't have ghost unreachable
instrumentation points) yet without artificially running the getter
when we only need to run the setter.

diff --git a/lisp/emacs-lisp/gv.el b/lisp/emacs-lisp/gv.el
index 3d8054950c..ce48e578e0 100644
--- a/lisp/emacs-lisp/gv.el
+++ b/lisp/emacs-lisp/gv.el
@@ -324,8 +324,7 @@ 'gv-place
        (gv-letplace (getter setter) place
          (funcall do `(edebug-after ,before ,index ,getter)
                   (lambda (store)
-                    `(progn (edebug-after ,before ,index ,getter)
-                            ,(funcall setter store)))))))
+                    `(edebug-after ,before ,index ,(funcall setter store)))))))
 
 ;;; The common generalized variables.