Subject: [PATCH 3/5] guix: Add gerbil-build-system

From: Edouard Klein <[email-masked]>
Date: Fri, 19 Jun 2020 15:36:24 +0200

* guix/build-system/gerbil.scm: New file.
(%gerbil-build-system-modules): New variable.
(gerbil-build): New variable
(gerbil-build-system): New variable

* guix/build/gerbil-build-system.scm: New file.
(%standard-phases): New variable.
(gerbil-build): New variable.
---
 guix/build-system/gerbil.scm       | 119 +++++++++++++++++++++++++++++
 guix/build/gerbil-build-system.scm | 102 +++++++++++++++++++++++++
 2 files changed, 221 insertions(+)
 create mode 100644 guix/build-system/gerbil.scm
 create mode 100644 guix/build/gerbil-build-system.scm

diff --git a/guix/build-system/gerbil.scm b/guix/build-system/gerbil.scm
new file mode 100644
index 0000000000..eea0261b2a
--- /dev/null
+++ b/guix/build-system/gerbil.scm
@@ -0,0 +1,119 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2020 Edouard Klein <[email-masked]>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system gerbil)
+  #:use-module (guix store)
+  #:use-module (guix utils)
+  #:use-module (guix derivations)
+  #:use-module (guix search-paths)
+  #:use-module (guix build-system)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix packages)
+  #:use-module (ice-9 match)
+  #:export (%gerbil-build-system-modules
+            gerbil-build
+            gerbil-build-system))
+
+(define %gerbil-build-system-modules
+  ;; Build-side modules imported by default.
+  `((guix build gerbil-build-system)
+    ,@%gnu-build-system-modules))
+
+(define (default-gerbil)
+  "Return the default Gerbil package."
+  ;; Do not use `@' to avoid introducing circular dependencies.
+  (let ((module (resolve-interface '(gnu packages scheme))))
+    (module-ref module 'gerbil)))
+
+(define* (lower name
+                #:key source inputs native-inputs outputs system target
+                (gerbil (default-gerbil))
+                #:allow-other-keys
+                #:rest arguments)
+  "Return a bag for NAME."
+  (define private-keywords
+    '(#:source #:target #:inputs #:native-inputs))
+  (bag
+    (name name)
+    (system system)
+    (target target)
+    (host-inputs `(,@(if source
+                         `(("source" ,source))
+                         '())
+                   ,@inputs
+                   ;; Keep the standard inputs of 'gnu-build-system'.
+                   ,@(standard-packages)))
+    (build-inputs `(("gerbil" ,gerbil)
+                    ,@native-inputs))
+    (outputs outputs)
+    (build gerbil-build)
+    (arguments (strip-keyword-arguments private-keywords arguments))))
+
+(define* (gerbil-build store name inputs
+                       #:key
+                       (phases '(@ (guix build gerbil-build-system)
+                                   %standard-phases))
+                       (outputs '("out"))
+                       (search-paths '())
+                       (system (%current-system))
+                       (guile #f)
+                       (imported-modules %gerbil-build-system-modules)
+                       (modules '((guix build gerbil-build-system)
+                                  (guix build utils))))
+  "Build SOURCE using GERBIL and with INPUTS."
+  (define builder
+    `(begin
+       (use-modules ,@modules)
+       (gerbil-build #:name ,name
+                     #:source ,(match (assoc-ref inputs "source")
+                                 (((? derivation? source))
+                                  (derivation->output-path source))
+                                 ((source)
+                                  source)
+                                 (source
+                                  source))
+                     #:system ,system
+                     #:phases ,phases
+                     #:outputs %outputs
+                     #:search-paths ',(map search-path-specification->sexp
+                                           search-paths)
+                     #:inputs %build-inputs)))
+
+  (define guile-for-build
+    (match guile
+      ((? package?)
+       (package-derivation store guile system #:graft? #f))
+      (#f                                         ; the default
+       (let* ((distro (resolve-interface '(gnu packages commencement)))
+              (guile  (module-ref distro 'guile-final)))
+         (package-derivation store guile system #:graft? #f)))))
+
+  (build-expression->derivation store name builder
+                                #:inputs inputs
+                                #:system system
+                                #:modules imported-modules
+                                #:outputs outputs
+                                #:guile-for-build guile-for-build))
+
+(define gerbil-build-system
+  (build-system
+    (name 'gerbil)
+    (description "The standard Gerbil build system")
+    (lower lower)))
+
+;;; gerbil.scm ends here
diff --git a/guix/build/gerbil-build-system.scm b/guix/build/gerbil-build-system.scm
new file mode 100644
index 0000000000..e6763b841a
--- /dev/null
+++ b/guix/build/gerbil-build-system.scm
@@ -0,0 +1,102 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2020 Edouard Klein <[email-masked]>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build gerbil-build-system)
+  #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+  #:use-module (guix build utils)
+  #:use-module (ice-9 match)
+  #:use-module (ice-9 ftw)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-26)
+  #:export (%standard-phases
+            gerbil-build))
+
+;; Gerbil's build system and package management is documented at
+;; https://cons.io/guide/package-manager.html
+;; https://cons.io/guide/build.html
+;; https://cons.io/guide/env-vars.html
+;;
+;; The compiler is writing its output in the directory
+;; pointed to by GERBIL_PATH (or ~/.gerbil by default).
+;;
+;; Every package is supposed to have a build.ss script
+;; whose default action (when called with no argument)
+;; is to compile the package.
+;;
+;; The GERBIL_LOADPATH env variable tells gerbil's runtime
+;; where it can find its loadable code.
+;;
+;; GERBIL_HOME tells gerbil where to find its runtime
+;; and standard library
+;;
+;; This build system therefore just
+;; - makes GERBIL_PATH point to the output directory in the store,
+;; - makes GERBIL_LOADPATH point to the lib subdir
+;; of all the gerbil inputs,
+;; - calls ./build.ss,
+;; - wrap any executable with GERBIL_LOADPATH set the the lib
+;; subdir of all the gerbil inputs plus the lib subdir
+;; of the current package's output, and with GERBIL_HOME
+;; set to the lib directory of the 'gerbil' input
+
+(define (loadpath inputs)
+  (string-join (map (match-lambda
+                      ((_ . path)
+                       (string-append path "/lib")))
+                    ;; Restrict to inputs beginning with "gerbil-".
+                    (filter (match-lambda
+                              ((name . _)
+                               (string-prefix? "gerbil-" name)))
+                            inputs))
+               ":"))
+
+(define (gerbil-home inputs)
+  (assoc-ref inputs "gerbil"))
+
+(define* (install #:key inputs outputs #:allow-other-keys)
+  "Install a given Gerbil package."
+  (let ((out (assoc-ref outputs "out"))
+        (in (loadpath inputs)))
+    (setenv "GERBIL_PATH" out)
+    (setenv "GERBIL_LOADPATH" in)
+    (invoke "./build.ss"))
+  #t)
+
+(define* (wrap #:key inputs outputs #:allow-other-keys)
+  "Wrap any executable with a proper GERBIL_LOADPATH and GERBIL_HOME"
+  (let* ((out (assoc-ref outputs "out"))
+         (in (loadpath inputs))
+         (gerbil-loadpath (string-append out "/lib:" in)))
+    (for-each (cut wrap-program <>
+                   `("GERBIL_LOADPATH" = (,gerbil-loadpath))
+                   `("GERBIL_HOME" = (,(gerbil-home inputs))))
+              (find-files (string-append out "/bin")))))
+
+(define %standard-phases
+  (modify-phases gnu:%standard-phases
+    (delete 'bootstrap)
+    (delete 'configure)                 ;not needed
+    (delete 'build)                     ;build.ss does both build and install
+    (delete 'check)                     ;no standard way of testing
+    (replace 'install install)
+    (add-after 'install 'wrap wrap)))
+
+(define* (gerbil-build #:key inputs (phases %standard-phases)
+                       #:allow-other-keys #:rest args)
+  "Build the given Gerbil package, applying all of PHASES in order."
+  (apply gnu:gnu-build #:inputs inputs #:phases phases args))
-- 
2.26.2