Subject: [PATCH v2] gnu: Add iPXE.

From: Tobias Geerinckx-Rice <[email-masked]>
Date: Mon, 13 Apr 2020 01:28:31 +0200

From: Vincent Legoll <[email-masked]>

* gnu/packages/bootloaders.scm (ipxe): New variable.

Co-authored-by Tobias Geerinckx-Rice <[email-masked]>
---

Vincent, Danny,

Danny Milosavljevic wrote:
> P.S. The following ROMs are not reproducible:

The ROMS were easily fixed by setting BUILD_ID_CMD to a static string.

The ISO was a pain.  cdrtools' mkisofs seems to predate the concept of
reproducible builds.  Switching to the modern Xorriso exposed another
bug: we weren't setting ISOLINUX_BIN, and cdrtools' mkisofs happily
created an ISO that probably never worked(?).  Luckily, Xorriso
complained loudly.

The image still isn't reproducible, but it has much fewer dates in it
now and it actually boots ;-) [citation needed].

I've silenced some other annoying warnings during the build, and
applied some of my suggestions from my previous mail (not all though —
please do send a V3).

Neither mtools nor XZ were ever used.  Why were they there?

Kind regards,

T G-R

 gnu/packages/bootloaders.scm | 70 +++++++++++++++++++++++++++++++++++-
 1 file changed, 69 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/bootloaders.scm b/gnu/packages/bootloaders.scm
index cadcc937e1..112b079c1b 100644
--- a/gnu/packages/bootloaders.scm
+++ b/gnu/packages/bootloaders.scm
@@ -7,10 +7,11 @@
 ;;; Copyright © 2016, 2017 Danny Milosavljevic <[email-masked]>
 ;;; Copyright © 2016, 2017 David Craven <[email-masked]>
 ;;; Copyright © 2017, 2018 Efraim Flashner <[email-masked]>
-;;; Copyright © 2018, 2019 Tobias Geerinckx-Rice <[email-masked]>
+;;; Copyright © 2018, 2019, 2020 Tobias Geerinckx-Rice <[email-masked]>
 ;;; Copyright © 2019 nee <[email-masked]>
 ;;; Copyright © 2019 Mathieu Othacehe <[email-masked]>
 ;;; Copyright © 2020 Björn Höfling <[email-masked]>
+;;; Copyright © 2020 Vincent Legoll <[email-masked]>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -834,6 +835,73 @@ to Novena upstream, does not load u-boot.img from the first partition.")
        `(("firmware" ,arm-trusted-firmware-rk3399)
          ,@(package-native-inputs base))))))
 
+(define-public ipxe
+  (package
+    (name "ipxe")
+    (version "1.20.1")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/ipxe/ipxe")
+                    (commit (string-append "v" version))))
+              (file-name (string-append name "-" version "-checkout"))
+              (sha256
+               (base32
+                "0w7h7y97gj9nqvbmsg1zp6zj5mpbbpckqbbx7bpp6k3ahy5fk8zp"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:make-flags
+       (list "ECHO_E_BIN_ECHO=echo"
+             "ECHO_E_BIN_ECHO_E=echo -e"
+
+             ;; cdrtools' mkisofs will silently ignore a missing isolinux.bin!
+             ;; Luckily xorriso is more strict.
+             (string-append "ISOLINUX_BIN=" (assoc-ref %build-inputs "syslinux")
+                            "/share/syslinux/isolinux.bin")
+
+             ;; Build reproducibly.
+             "BUILD_ID_CMD=echo -n 0x78697547")
+       #:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'enter-source-directory
+           (lambda _ (chdir "src") #t))
+         (add-before 'configure 'add-make-install-target
+           (lambda* (#:key outputs #:allow-other-keys)
+             (let* ((out (assoc-ref outputs "out"))
+                    (ipxe (string-append out "/share/ipxe")))
+               (substitute* "Makefile"
+                 (("^install :")
+                  (string-append "install :"
+                                 "\n\t@$(MKDIR) -p " ipxe
+                                 "\n\t@$(CP) $(ALL) " ipxe
+                                 "\n\n__old_install :")))
+               #t)))
+         (add-before 'configure 'use-xorriso
+           ;; Use xorriso's mkisofs emulation, which is better maintained and
+           ;; respects SOURCE_DATE_EPOCH to create a reproducible image.
+           (lambda _
+             (substitute* "util/geniso"
+               ((" genisoimage ") " \"xorriso -as mkisofs\" "))
+             #t))
+         (delete 'configure)            ; no configure script
+         (add-after 'install 'leave-source-directory
+           (lambda _ (chdir "..") #t)))
+       #:tests? #f))                    ; no test suite
+    (native-inputs
+     `(("perl" ,perl)
+       ("syslinux" ,syslinux)
+       ("xorriso" ,xorriso)))
+    (home-page "https://ipxe.org")
+    (synopsis "PXE-compliant network boot firmware")
+    (description "iPXE is a network boot firmware.  It provides a full PXE
+implementation enhanced with additional features such as booting from: a web
+server via HTTP, an iSCSI SAN, a Fibre Channel SAN via FCoE, an AoE SAN, a
+wireless network, a wide-area network, an Infiniband network.  It allows to
+control the boot process with a script.  You can use iPXE to replace the
+existing PXE ROM on your network card, or you can chainload into iPXE to obtain
+the features of iPXE without the hassle of reflashing.")
+    (license license:gpl2+)))
+
 (define-public vboot-utils
   (package
     (name "vboot-utils")
-- 
2.25.2