Subject: [PATCH] Add python-pylibmc (and dependencies)

From: Maxim Cournoyer <[email-masked]>
Date: Tue, 20 Nov 2018 23:14:33 -0500

Hello Guix!

This adds python-pylibmc, and its direct dependency libmemcached. I also
finally found some use for a Bazaar downloader which I had made a long time ago.

Thank you,

From 4092d51202e0060fa08fe87dbae1274c4b4aeed2 Mon Sep 17 00:00:00 2001
From: Maxim Cournoyer <[email-masked]>
Date: Tue, 20 Nov 2018 23:11:29 -0500
Subject: [PATCH 1/3] Add (guix bzr-download).

* guix/bzr-download.scm, guix/build/bzr.scm,
etc/snippets/scheme-mode/guix-bzr-reference: New files.
* Makefile.am (MODULES): Add them.
* etc/snippets/scheme-mode/guix-origin: Add "bzr-fetch" to the origin choices.
---
 Makefile.am                                 |  2 +
 etc/snippets/scheme-mode/guix-bzr-reference |  7 ++
 etc/snippets/scheme-mode/guix-origin        |  6 +-
 guix/build/bzr.scm                          | 44 +++++++++++
 guix/bzr-download.scm                       | 87 +++++++++++++++++++++
 5 files changed, 144 insertions(+), 2 deletions(-)
 create mode 100644 etc/snippets/scheme-mode/guix-bzr-reference
 create mode 100644 guix/build/bzr.scm
 create mode 100644 guix/bzr-download.scm

diff --git a/Makefile.am b/Makefile.am
index c63b65ba5..2b599217e 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -72,6 +72,7 @@ MODULES =					\
   guix/modules.scm				\
   guix/download.scm				\
   guix/discovery.scm				\
+  guix/bzr-download.scm            		\
   guix/git-download.scm				\
   guix/hg-download.scm				\
   guix/monads.scm				\
@@ -145,6 +146,7 @@ MODULES =					\
   guix/build/font-build-system.scm		\
   guix/build/go-build-system.scm		\
   guix/build/asdf-build-system.scm		\
+  guix/build/bzr.scm				\
   guix/build/git.scm				\
   guix/build/hg.scm				\
   guix/build/glib-or-gtk-build-system.scm	\
diff --git a/etc/snippets/scheme-mode/guix-bzr-reference b/etc/snippets/scheme-mode/guix-bzr-reference
new file mode 100644
index 000000000..a801cc36f
--- /dev/null
+++ b/etc/snippets/scheme-mode/guix-bzr-reference
@@ -0,0 +1,7 @@
+# -*- mode: snippet -*-
+# name: guix-bzr-reference
+# key: bzr-reference...
+# --
+(bzr-reference
+  (url "$1")
+  (revision ${2:ref}))
\ No newline at end of file
diff --git a/etc/snippets/scheme-mode/guix-origin b/etc/snippets/scheme-mode/guix-origin
index 1a068f885..2820a369f 100644
--- a/etc/snippets/scheme-mode/guix-origin
+++ b/etc/snippets/scheme-mode/guix-origin
@@ -9,15 +9,17 @@
                                  "cvs-fetch"
                                  "git-fetch"
                                  "hg-fetch"
-                                 "svn-fetch")})
+                                 "svn-fetch"
+                                 "bzr-fetch")})
  (uri ${1:$(cond ((equal yas-text "git-fetch") "git-reference...")
                  ((equal yas-text "svn-fetch") "svn-reference...")
                  ((equal yas-text "hg-fetch")  "hg-reference...")
                  ((equal yas-text "cvs-fetch") "cvs-reference...")
+                 ((equal yas-text "bzr-fetch") "bzr-reference...")
                  (t "(string-append \\"https://\\" version \\".tar.gz\\")"))}$0)
  ${1:$(cond ((equal yas-text "git-fetch")
              "(file-name (git-file-name name version))")
-            ((member yas-text '("svn-fetch" "hg-fetch" "cvs-fetch"))
+            ((member yas-text '("svn-fetch" "hg-fetch" "cvs-fetch" "bzr-fetch"))
              "(file-name (string-append name \\"-\\" version \\"-checkout\\"))")
             (t ""))}
  (sha256
diff --git a/guix/build/bzr.scm b/guix/build/bzr.scm
new file mode 100644
index 000000000..31639e440
--- /dev/null
+++ b/guix/build/bzr.scm
@@ -0,0 +1,44 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2018 Maxim Cournoyer <[email-masked]>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build bzr)
+  #:use-module (guix build utils)
+  #:export (bzr-fetch))
+
+;;; Commentary:
+;;;
+;;; This is the build-side support code of (guix bzr-download).  It allows a
+;;; Bazaar repository to be branched at a specific revision.
+;;;
+;;; Code:
+
+(define* (bzr-fetch url revision directory
+                       #:key (bzr-command "bzr"))
+  "Fetch REVISION from URL into DIRECTORY.  REVISION must be a valid Bazaar
+revision identifier.  Return #t on success, #f otherwise."
+  ;; Do not attempt to write .bzr.log to $HOME, which doesn't exist.
+  (setenv "BZR_LOG" "/dev/null")
+  ;; Disable SSL certificate verification; we rely on the hash instead.
+  (and (zero? (system* bzr-command "-Ossl.cert_reqs=none" "checkout"
+                       "--lightweight" "-r" revision url directory))
+       (with-directory-excursion directory
+         (begin
+           (delete-file-recursively ".bzr")
+           #t))))
+
+;;; bzr.scm ends here
diff --git a/guix/bzr-download.scm b/guix/bzr-download.scm
new file mode 100644
index 000000000..e990d9de1
--- /dev/null
+++ b/guix/bzr-download.scm
@@ -0,0 +1,87 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2017 Maxim Cournoyer <[email-masked]>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix bzr-download)
+  #:use-module (guix gexp)
+  #:use-module (guix modules)   ;for 'source-module-closure'
+  #:use-module (guix monads)
+  #:use-module (guix packages)
+  #:use-module (guix records)
+  #:use-module (guix store)
+
+  #:export (bzr-reference
+            bzr-reference?
+            bzr-reference-url
+            bzr-reference-revision
+
+            bzr-fetch))
+
+;;; Commentary:
+;;;
+;;; An <origin> method that fetches a specific revision from a Bazaar
+;;; repository.  The repository URL and revision identifier are specified with
+;;; a <bzr-reference> object.
+;;;
+;;; Code:
+
+(define-record-type* <bzr-reference>
+  bzr-reference make-bzr-reference
+  bzr-reference?
+  (url bzr-reference-url)
+  (revision bzr-reference-revision))
+
+(define (bzr-package)
+  "Return the default Bazaar package."
+  (let ((distro (resolve-interface '(gnu packages version-control))))
+    (module-ref distro 'bazaar)))
+
+(define* (bzr-fetch ref hash-algo hash
+                       #:optional name
+                       #:key (system (%current-system)) (guile (default-guile))
+                       (bzr (bzr-package)))
+  "Return a fixed-output derivation that fetches REF, a <bzr-reference>
+object.  The output is expected to have recursive hash HASH of type
+HASH-ALGO (a symbol).  Use NAME as the file name, or a generic name if #f."
+  (define build
+    (with-imported-modules (source-module-closure
+                            '((guix build bzr)))
+      #~(begin
+          (use-modules (guix build bzr))
+          (bzr-fetch
+           (getenv "bzr url") (getenv "bzr reference") #$output
+           #:bzr-command (string-append #+bzr "/bin/bzr")))))
+
+  (mlet %store-monad ((guile (package->derivation guile system)))
+    (gexp->derivation (or name "bzr-branch") build
+
+                      ;; Use environment variables and a fixed script name so
+                      ;; there's only one script in store for all the
+                      ;; downloads.
+                      #:script-name "bzr-download"
+                      #:env-vars
+                      `(("bzr url" . ,(bzr-reference-url ref))
+                        ("bzr reference" . ,(bzr-reference-revision ref)))
+
+                      #:system system
+                      #:local-build? #t  ;don't offload repo branching
+                      #:hash-algo hash-algo
+                      #:hash hash
+                      #:recursive? #t
+                      #:guile-for-build guile)))
+
+;;; bzr-download.scm ends here
-- 
2.19.0

From 2e4d15244cd3c9ef7aaa356665a7e146367b12f0 Mon Sep 17 00:00:00 2001
From: Maxim Cournoyer <[email-masked]>
Date: Tue, 20 Nov 2018 23:12:02 -0500
Subject: [PATCH 2/3] gnu: Add libmemcached.

* gnu/packages/databases.scm (libmemcached): New variable.
---
 gnu/packages/databases.scm | 86 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 86 insertions(+)

diff --git a/gnu/packages/databases.scm b/gnu/packages/databases.scm
index 7258622f4..71c267281 100644
--- a/gnu/packages/databases.scm
+++ b/gnu/packages/databases.scm
@@ -32,6 +32,7 @@
 ;;; Copyright © 2017 Kristofer Buffington <[email-masked]>
 ;;; Copyright © 2018 Amirouche Boubekki <[email-masked]>
 ;;; Copyright © 2018 Joshua Sierles, Nextjournal <[email-masked]>
+;;; Copyright © 2018 Maxim Cournoyer <[email-masked]>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -65,6 +66,7 @@
   #:use-module (gnu packages curl)
   #:use-module (gnu packages cyrus-sasl)
   #:use-module (gnu packages emacs)
+  #:use-module (gnu packages flex)
   #:use-module (gnu packages gettext)
   #:use-module (gnu packages glib)
   #:use-module (gnu packages gnupg)
@@ -100,6 +102,7 @@
   #:use-module ((guix licenses) #:prefix license:)
   #:use-module (guix packages)
   #:use-module (guix download)
+  #:use-module (guix bzr-download)
   #:use-module (guix git-download)
   #:use-module (guix build-system gnu)
   #:use-module (guix build-system go)
@@ -419,6 +422,89 @@ and generic API, and was originally intended for use with dynamic web
 applications.")
     (license license:bsd-3)))
 
+(define-public libmemcached
+  (package
+    (name "libmemcached")
+    (version "1.0.18")
+    ;; We build from the sources since we want to build the extra HTML
+    ;; documentation which is not included with the release.
+    (source (origin
+              (method bzr-fetch)
+              (uri (bzr-reference
+                    (url "lp:libmemcached/1.0")
+                    (revision (string-append "tag:" version))))
+              (file-name (string-append name "-" version "-checkout"))
+              (sha256
+               (base32
+                "1842s4dxdh21gdr46q4dgxigidcs6dkqnbnqjwb9l8r0bqx5nb10"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("memcached" ,memcached)
+       ("libtool" ,libtool)
+       ("autoconf" ,autoconf)
+       ("automake" ,automake)
+       ("bison" ,bison)
+       ("flex" ,flex)
+       ("perl" ,perl)
+       ("python-sphinx" ,python-sphinx))) ;to build the HTML doc.
+    (inputs
+     `(("libevent" ,libevent)
+       ("cyrus-sasl" ,cyrus-sasl)))
+    (outputs '("out" "doc"))
+    (arguments
+     '(#:phases
+       (modify-phases %standard-phases
+         (add-before 'bootstrap 'fix-configure.ac
+           ;; Move the AC_CONFIG_AUX_DIR macro use under AC_INIT, otherwise we
+           ;; get the error ``configure: error: cannot find install-sh,
+           ;; install.sh, or shtool in "." "./.." "./../.."`` (see:
+           ;; https://debbugs.gnu.org/cgi/bugreport.cgi?bug=19539 and
+           ;; https://bugs.launchpad.net/libmemcached/+bug/1803922).
+           (lambda _
+             (delete-file "bootstrap.sh") ;not useful in the context of Guix
+             (substitute* "configure.ac"
+               (("^AC_CONFIG_AUX_DIR\\(\\[build-aux\\]\\).*") "")
+               (("(^AC_INIT.*)" anchor)
+                (string-append anchor "AC_CONFIG_AUX_DIR([build-aux])\n")))
+             #t))
+         (add-before 'bootstrap 'disable-failing-tests
+           ;; See: https://bugs.launchpad.net/libmemcached/+bug/1803926
+           (lambda _
+             ;; Mark some heavily failing test suites as expected to fail.
+             (substitute* "Makefile.am"
+               (("(XFAIL_TESTS =[^\n]*)" xfail_tests)
+                (string-append xfail_tests " tests/testudp"
+                               " tests/libmemcached-1.0/testapp"
+                               " tests/libmemcached-1.0/testsocket")))
+             ;; Disable two tests of the unittest test suite.
+             (substitute* "libtest/unittest.cc"
+               ((".*echo_fubar_BINARY \\},.*") "")
+               ((".*application_doesnotexist_BINARY \\},.*") ""))
+             #t))
+         (add-after 'disable-dns-tests 'build-and-install-html-doc
+           (lambda* (#:key outputs #:allow-other-keys)
+             (let ((html (string-append (assoc-ref outputs "doc")
+                                        "/share/doc/libmemcached/html/")))
+               (invoke "make" "install-html")
+               ;; Cleanup useless files.
+               (for-each delete-file-recursively
+                         (map (lambda (x) (string-append html x))
+                              '("_sources" ".doctrees" ".buildinfo"))))
+             #t)))))
+    (home-page "https://libmemcached.org/")
+    (synopsis "C++ library for memcached")
+    (description "libMemcached is a library to use memcached in C/C++
+applications.  It comes with a complete reference guide and documentation of
+the API, and provides features such as:
+@itemize
+@item Asynchronous and synchronous transport support
+@item Consistent hashing and distribution
+@item Tunable hashing algorithm to match keys
+@item Access to large object support
+@item Local replication
+@end itemize")
+    (license license:bsd-3)))
+
 (define-public mongodb
   (package
     (name "mongodb")
-- 
2.19.0

From a29c83aa95095705a9be7e152601895145a467a8 Mon Sep 17 00:00:00 2001
From: Maxim Cournoyer <[email-masked]>
Date: Tue, 20 Nov 2018 23:12:23 -0500
Subject: [PATCH 3/3] gnu: Add python-pylibmc.

* gnu/packages/databases.scm (python-pylibmc, python2-pylibmc): New variables.
---
 gnu/packages/databases.scm | 39 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

diff --git a/gnu/packages/databases.scm b/gnu/packages/databases.scm
index 71c267281..07eb871de 100644
--- a/gnu/packages/databases.scm
+++ b/gnu/packages/databases.scm
@@ -505,6 +505,45 @@ the API, and provides features such as:
 @end itemize")
     (license license:bsd-3)))
 
+(define-public python-pylibmc
+  (package
+    (name "python-pylibmc")
+    (version "1.6.0")
+    (source
+     (origin
+       (method url-fetch)
+       (uri (pypi-uri "pylibmc" version))
+       (sha256
+        (base32
+         "1n6nvvhl0g52gpzzwdj1my6049xljkfwyxxygnwda9smrbj7pyay"))))
+    (build-system python-build-system)
+    (arguments
+     '(#:phases
+       (modify-phases %standard-phases
+         (add-before 'check 'start-memcached-daemon
+           ;; The test suite requires a memcached server.
+           (lambda _
+             (invoke "memcached" "-d"))))))
+    (native-inputs
+     `(("memcached" ,memcached)
+       ("python-nose" ,python-nose)))
+    (inputs
+     `(("libmemcached" ,libmemcached)
+       ("zlib" ,zlib)
+       ("cyrus-sasl" ,cyrus-sasl)))
+    (home-page
+     "http://sendapatch.se/projects/pylibmc/")
+    (synopsis
+     "Python client for memcached")
+    (description
+     "@code{pylibmc} is a client in Python for memcached.  It is a wrapper
+around TangentOrg’s libmemcached library, and can be used as a drop-in
+replacement for the code@{python-memcached} library.")
+    (license license:bsd-3)))
+
+(define-public python2-pylibmc
+  (package-with-python2 python-pylibmc))
+
 (define-public mongodb
   (package
     (name "mongodb")
-- 
2.19.0