GNU bug report logs - #32790
27.0.50; point jumps unexpectedly after delete-window

Previous Next

Full log

Message #332 received at 32790 <at> debbugs.gnu.org (full text, mbox):

From: Juri Linkov <juri <at> linkov.net>
To: Eli Zaretskii <eliz <at> gnu.org>
Cc: rudalics <at> gmx.at, 32790 <at> debbugs.gnu.org
Subject: Re: bug#32790: 27.0.50; point jumps unexpectedly after delete-window
Date: Wed, 28 Nov 2018 01:18:13 +0200

>> But wait, maybe still 'switch-to-buffer-pop-to' would be a better name?
>
> I find this name sub-optimal, as it doesn't make sense as an English
> phrase, and doesn't describe well enough what it means.
>
> How about switch-to-buffer-use-pop-to or maybe
> switch-to-buffer-obey-display-actions?

Yes, this is a much better name because it reflects the purpose of the option
instead of the implementation details.  I also updated the docstring:

diff --git a/lisp/window.el b/lisp/window.el
index 2634955a75..4a1637ad0f 100644
--- a/lisp/window.el
+++ b/lisp/window.el
@@ -7779,6 +7779,16 @@ switch-to-buffer-in-dedicated-window
   :group 'windows
   :version "25.1")
 
+(defcustom switch-to-buffer-obey-display-actions nil
+  "If non-nil, have `switch-to-buffer' run `pop-to-buffer-same-window'.
+This means that when switching the buffer it respects display actions
+specified for `display-buffer'.  So `switch-to-buffer' will display the
+buffer in the window specified by the ACTION argument of `display-buffer',
+or by the rules in `display-buffer-alist' and other related variables."
+  :type 'boolean
+  :group 'windows
+  :version "27.1")
+
 (defun switch-to-buffer (buffer-or-name &optional norecord force-same-window)
   "Display buffer BUFFER-OR-NAME in the selected window.
 
@@ -7820,6 +7830,7 @@ switch-to-buffer
 Return the buffer switched to."
   (interactive
    (let ((force-same-window
+          (unless switch-to-buffer-obey-display-actions
             (cond
              ((window-minibuffer-p) nil)
              ((not (eq (window-dedicated-p) t)) 'force-same-window)
@@ -7836,13 +7847,15 @@ switch-to-buffer
                    (user-error
                     "Cannot switch buffers in a dedicated window")))
                 ('pop nil)
-              (_ (set-window-dedicated-p nil nil) 'force-same-window))))))
+                (_ (set-window-dedicated-p nil nil) 'force-same-window)))))))
      (list (read-buffer-to-switch "Switch to buffer: ") nil force-same-window)))
-  (let ((buffer (window-normalize-buffer-to-switch-to buffer-or-name)))
+  (let ((buffer (window-normalize-buffer-to-switch-to buffer-or-name))
+        (set-window-start-and-point (not switch-to-buffer-obey-display-actions)))
     (cond
      ;; Don't call set-window-buffer if it's not needed since it
      ;; might signal an error (e.g. if the window is dedicated).
-     ((eq buffer (window-buffer)))
+     ((and (eq buffer (window-buffer))
+           (not switch-to-buffer-obey-display-actions)))
      ((window-minibuffer-p)
       (if force-same-window
           (user-error "Cannot switch buffers in minibuffer window")
@@ -7852,6 +7865,13 @@ switch-to-buffer
           (user-error "Cannot switch buffers in a dedicated window")
         (pop-to-buffer buffer norecord)))
      (t
+      (when switch-to-buffer-obey-display-actions
+        (let ((selected-window (selected-window)))
+          (pop-to-buffer-same-window buffer norecord)
+          (when (eq (selected-window) selected-window)
+            (setq set-window-start-and-point t))))
+
+      (when set-window-start-and-point
         (let* ((entry (assq buffer (window-prev-buffers)))
 	       (displayed (and (eq switch-to-buffer-preserve-window-point
 				   'already-displayed)
@@ -7863,7 +7883,7 @@ switch-to-buffer
 	    ;; Try to restore start and point of buffer in the selected
 	    ;; window (Bug#4041).
 	    (set-window-start (selected-window) (nth 1 entry) t)
-	  (set-window-point nil (nth 2 entry))))))
+	    (set-window-point nil (nth 2 entry)))))))
 
     (unless norecord
       (select-window (selected-window)))

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.