Subject: Re: bug#32470: rcirc-debug: ignore read-only; do not move point if mid-buffer; use %F

From: Ivan Shmakov <[email-masked]>
Date: Fri, 14 Sep 2018 19:05:26 +0000

>>>>> Noam Postavsky <[email-masked]> writes:
>>>>> Ivan Shmakov <[email-masked]> writes:

 >> I’m somewhat unsure if this change is NEWS-worthy; if so, I suggest
 >> the following entry.

 > The behaviour of debug tracing functions is somewhat in the gray area
 > between user visible and internal details, but I’d say there’s no
 > need to update NEWS for this.

	ACK.

 >> +      (let ((old (set-marker (make-marker) (point))))

 > You could use (point-marker) instead.

	ACK, thanks!

 >> +        (set-marker-insertion-type old t)
 >> +        (goto-char (point-max))
 >> +        (let ((inhibit-read-only t))
 >> +          (terpri (current-buffer) t)

 > This looks like you’re adding an extra newline,

	Only if there’s none already, as the second argument to terpri
	is non-nil.  Which can happen, for example, should user edit the
	buffer manually (for whatever reason.)

 > or was there a lack of newlines before?

	Actually, yes, there seem to be an issue with a “missing”
	trailing newline when rcirc-debug is called from rcirc-filter.

	AIUI, when the remote produces a large amount of data (such as
	just after the handshake), rcirc-filter gets called for each
	bufferful of data, e. g.:

(rcirc-filter #<process> "line-1\nline-2\nli")
(rcirc-filter #<process> "ne-3\nline-4\nline")
(rcirc-filter #<process> "-5\nline-6\nline-7")
; and so on…

	There, rcirc-filter will accumulate data in rcirc-process-output
	and process only when the value ends with a newline.  OTOH,
	rcirc-debug gets called once for each rcirc-debug call,
	currently resulting in the *rcirc debug* state being like:

[2018-09-14T18:35:19 process] line-1
line-2
li[2018-09-14T18:35:19 process] ne-3
line-4
line[2018-09-14T18:35:19 process] -5…

	This patch ensures a newline before every [timestamp] marker.

	Please consider the revised patch MIMEd.

	FTR, a ‘side effect’ of this change is that rcirc-debug no
	longer returns the string appended to buffer.  (Instead, it
	returns the marker coinciding with point.)  AFAICT, the return
	value of this function is never used in the Rcirc code.

-- 
FSF associate member #7257  http://softwarefreedomday.org/  15 September 2018
From: Ivan Shmakov <[email-masked]>
Subject: Improve user convenience of the rcirc debug buffer
Date: Fri, 14 Sep 2018 19:05:12 +0000

* lisp/net/rcirc.el (rcirc-debug): Ignore rcirc-debug-buffer read-only
status.  Restore point after insertion unless it was at the end.
Ensure a newline before each [lead].  Replace %Y-%m-%d with the
equivalent %F in format-time-string; remove useless concat.  (Bug#32470)
---

--- a/lisp/net/rcirc.el
+++ b/lisp/net/rcirc.el
@@ -670,16 +670,24 @@
   "If non-nil, write information to `rcirc-debug-buffer'.")
 (defun rcirc-debug (process text)
   "Add an entry to the debug log including PROCESS and TEXT.
-Debug text is written to `rcirc-debug-buffer' if `rcirc-debug-flag'
-is non-nil."
+Debug text is appended to `rcirc-debug-buffer' if `rcirc-debug-flag'
+is non-nil.
+
+For convenience, the read-only state of the debug buffer is ignored.
+When the point is at the end of the visible portion of the buffer, it
+is moved to after the text inserted.  Otherwise the point is not moved."
   (when rcirc-debug-flag
     (with-current-buffer (get-buffer-create rcirc-debug-buffer)
-      (goto-char (point-max))
-      (insert (concat
-	       "["
-	       (format-time-string "%Y-%m-%dT%T ") (process-name process)
-	       "] "
-	       text)))))
+      (let ((old (point-marker)))
+        (set-marker-insertion-type old t)
+        (goto-char (point-max))
+        (let ((inhibit-read-only t))
+          (terpri (current-buffer) t)
+          (insert "["
+                  (format-time-string "%FT%T ") (process-name process)
+                  "] "
+                  text))
+        (goto-char old)))))
 
 (define-obsolete-variable-alias 'rcirc-sentinel-hooks
   'rcirc-sentinel-functions "24.3")