Subject: 26.1; cl-prin1 doesn't print #' and ignores print-quoted

From: Gemini Lasswell <[email-masked]>
Date: Tue, 29 May 2018 17:34:19 -0700

CL printing doesn't observe the print variable print-quoted and always
prints #'foo as (function foo).

To reproduce, execute the following code (I used emacs -Q and IELM):

(let ((quoted-stuff '('a #'b `(,c ,@d))))
  (let ((print-quoted t))
    (cl-prin1 quoted-stuff) (terpri)
    (prin1 quoted-stuff) (terpri))
  (let ((print-quoted nil))
    (cl-prin1 quoted-stuff) (terpri)
    (prin1 quoted-stuff) (terpri)))

Results:
('a (function b) `(,c ,@d))
('a #'b `(,c ,@d))
('a (function b) `(,c ,@d))
((quote a) (function b) (\` ((\, c) (\,@ d))))

I expect cl-prin1 and prin1 to do the same thing in this example.

Here's a patch to make cl-prin1 behave like prin1:

>From 99b24a7dc7472d04e6de43fb48f45869a272c26c Mon Sep 17 00:00:00 2001
From: Gemini Lasswell <[email-masked]>
Date: Tue, 29 May 2018 11:41:09 -0700
Subject: [PATCH] Make cl-print respect print-quoted

* lisp/emacs-lisp/cl-print.el (cl-print-object) <cons>: Print quote
and its relatives as lists if print-quoted is nil. Add printing of
'function' as #'.
* test/lisp/emacs-lisp/cl-print-tests.el (cl-print-tests-5): New test.
---
 lisp/emacs-lisp/cl-print.el            |  9 +++++++--
 test/lisp/emacs-lisp/cl-print-tests.el | 10 ++++++++++
 2 files changed, 17 insertions(+), 2 deletions(-)

diff --git a/lisp/emacs-lisp/cl-print.el b/lisp/emacs-lisp/cl-print.el
index 55e2bf8bd4..1eae8faf23 100644
--- a/lisp/emacs-lisp/cl-print.el
+++ b/lisp/emacs-lisp/cl-print.el
@@ -61,11 +61,16 @@ cl-print--depth
       (princ "..." stream)
     (let ((car (pop object))
           (count 1))
-      (if (and (memq car '(\, quote \` \,@ \,.))
+      (if (and print-quoted
+               (memq car '(\, quote function \` \,@ \,.))
                (consp object)
                (null (cdr object)))
           (progn
-            (princ (if (eq car 'quote) '\' car) stream)
+            (princ (cond
+                    ((eq car 'quote) '\')
+                    ((eq car 'function) "#'")
+                    (t car))
+                   stream)
             (cl-print-object (car object) stream))
         (princ "(" stream)
         (cl-print-object car stream)
diff --git a/test/lisp/emacs-lisp/cl-print-tests.el b/test/lisp/emacs-lisp/cl-print-tests.el
index bfce4a16ce..404d323d0c 100644
--- a/test/lisp/emacs-lisp/cl-print-tests.el
+++ b/test/lisp/emacs-lisp/cl-print-tests.el
@@ -72,6 +72,16 @@
     (should (equal "#s(cl-print-tests-struct :a (a (b (c ...))) :b nil :c nil :d nil :e nil)"
                    (cl-prin1-to-string deep-struct)))))
 
+(ert-deftest cl-print-tests-5 ()
+  "CL printing observes `print-quoted'."
+  (let ((quoted-stuff '('a #'b `(,c ,@d))))
+    (let ((print-quoted t))
+      (should (equal "('a #'b `(,c ,@d))"
+                     (cl-prin1-to-string quoted-stuff))))
+    (let ((print-quoted nil))
+      (should (equal "((quote a) (function b) (\\` ((\\, c) (\\,@ d))))"
+                     (cl-prin1-to-string quoted-stuff))))))
+
 (ert-deftest cl-print-circle ()
   (let ((x '(#1=(a . #1#) #1#)))
     (let ((print-circle nil))
-- 
2.16.2