Subject: bug#30962: 26.0.91; Encrypt message when there is a key for each recipient

From: Damien Cassou <[email-masked]>
Date: Wed, 04 Apr 2018 11:35:55 +0200

Nicolas Petton <[email-masked]> writes:
>           Would `message-all-recipients' be a better name?

renamed

> Could you add tests for `message-all-epg-keys-available-p' as well?

done.

Please find attached a new version.

-- 
Damien Cassou
http://damiencassou.seasidehosting.st

"Success is the ability to go from one failure to another without
losing enthusiasm." --Winston Churchill
>From 64bf9c2f6b15e82b5d077b1428408237ad1d1e74 Mon Sep 17 00:00:00 2001
From: Damien Cassou <[email-masked]>
Date: Tue, 27 Mar 2018 16:57:51 +0200
Subject: [PATCH] Detect if a message can be encrypted and add an MML tag

* lisp/gnus/message.el (message-recipients): Return a list of pairs,
one for each recipient in To, Cc, Bcc.
(message-all-epg-keys-available-p): Check that there is a public key
in epg for each recipient of the current message.
(message-sign-encrypt-if-all-keys-available): Add MML tag to sign and
encrypt current message if there is a public key for every recipient
in current message.

* test/lisp/gnus/message-tests.el (message-recipients): Test for
message-recipients.
---
 etc/NEWS                        |  8 +++++++
 lisp/gnus/message.el            | 30 +++++++++++++++++++++++++++
 test/lisp/gnus/message-tests.el | 46 +++++++++++++++++++++++++++++++++++++++++
 3 files changed, 84 insertions(+)

diff --git a/etc/NEWS b/etc/NEWS
index baff9664cf..02b31ecff4 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -337,6 +337,14 @@ or NextCloud hosted files and directories.
 It was obsolete since Emacs 22.1, replaced by customize.
 
 
+** Message
+
++++
+*** Messages can now be systematically encrypted
+when the PGP keyring contains a public key for every recipient.  To
+achieve this, add 'message-add-encrypt-tag-if-can-encrypt' to
+'message-send-hook'.
+
 * New Modes and Packages in Emacs 27.1
 
 +++
diff --git a/lisp/gnus/message.el b/lisp/gnus/message.el
index 37b994de99..fdb296fc24 100644
--- a/lisp/gnus/message.el
+++ b/lisp/gnus/message.el
@@ -2582,6 +2582,36 @@ message-info
 		      (t
 		       'message)))))
 
+(defun message-all-recipients ()
+  "Return a list of all recipients in the message, looking at TO, CC and BCC.
+
+Each recipient is in the format of `mail-extract-address-components'."
+  (mapcan (lambda (header)
+            (let ((header-value (message-fetch-field header)))
+              (and
+               header-value
+               (mail-extract-address-components header-value t))))
+          '("To" "Cc" "Bcc")))
+
+(defun message-all-epg-keys-available-p ()
+  "Return non-nil if the pgp keyring has a public key for each recipient."
+  (require 'epa)
+  (let ((context (epg-make-context epa-protocol)))
+    (catch 'break
+      (dolist (recipient (message-all-recipients))
+        (let ((recipient-email (cadr recipient)))
+          (when (and recipient-email (not (epg-list-keys context recipient-email)))
+            (throw 'break nil))))
+      t)))
+
+(defun message-sign-encrypt-if-all-keys-available ()
+  "Add MML tag to encrypt message when there is a key for each recipient.
+
+Consider adding this function to `message-send-hook' to
+systematically send encrypted emails when possible."
+  (when (message-all-epg-keys-available-p)
+    (mml-secure-message-sign-encrypt)))
+
 
 
 ;;;
diff --git a/test/lisp/gnus/message-tests.el b/test/lisp/gnus/message-tests.el
index ec1f247020..9124dcf77a 100644
--- a/test/lisp/gnus/message-tests.el
+++ b/test/lisp/gnus/message-tests.el
@@ -29,6 +29,8 @@
 (require 'ert)
 (require 'ert-x)
 
+(require 'cl-lib)
+
 (ert-deftest message-mode-propertize ()
   (with-temp-buffer
     (unwind-protect
@@ -97,6 +99,50 @@
         (should (string= stripped-was
                          (message-strip-subject-trailing-was with-was)))))))
 
+(ert-deftest message-all-recipients ()
+  (ert-with-test-buffer (:name "message")
+    (insert "To: Person 1 <[email-masked]>, Person 2 <[email-masked]>\n")
+    (insert "CC: Person 3 <[email-masked]>, Person 4 <[email-masked]>\n")
+    (insert "BCC: Person 5 <[email-masked]>, Person 6 <[email-masked]>\n")
+    (should (equal (message-all-recipients)
+                   '(("Person 1" "[email-masked]")
+                     ("Person 2" "[email-masked]")
+                     ("Person 3" "[email-masked]")
+                     ("Person 4" "[email-masked]")
+                     ("Person 5" "[email-masked]")
+                     ("Person 6" "[email-masked]"))))))
+
+(ert-deftest message-all-epg-keys-available-p ()
+  (let ((person1 '("Person 1" "[email-masked]"))
+        (person2 '("Person 2" "[email-masked]"))
+        (person3 '("Person 3" "[email-masked]"))
+        (recipients nil)
+        (keyring '("[email-masked]" "[email-masked]")))
+    (cl-letf (((symbol-function 'epg-list-keys)
+               (lambda (_ email) (cl-find email keyring :test #'string=)))
+              ((symbol-function 'message-all-recipients)
+               (lambda () recipients)))
+
+      (setq recipients (list))
+      (should (message-all-epg-keys-available-p))
+
+      (setq recipients (list person1))
+      (should (message-all-epg-keys-available-p))
+
+      (setq recipients (list person1 person2))
+      (should (message-all-epg-keys-available-p))
+
+      (setq recipients (list person3))
+      (should-not (message-all-epg-keys-available-p))
+
+      (setq recipients (list person1 person3))
+      (should-not (message-all-epg-keys-available-p))
+
+      (setq recipients (list person3 person1))
+      (should-not (message-all-epg-keys-available-p))
+
+      (setq recipients (list person1 person2 person3))
+      (should-not (message-all-epg-keys-available-p)))))
 
 (provide 'message-mode-tests)
 
-- 
2.14.3