Subject: Re: bug#30444: 26.0.90; browse-url-emacs sets default-directory to "https://"

From: Nicolas Petton <[email-masked]>
Date: Fri, 16 Mar 2018 22:02:49 +0100

Michael Albinus <[email-masked]> writes:

Hi Michael,

> I haven't tested thoroughly, but your tests look OK.
>
>> +    (should (equal (file-name-directory "https://foo.org")
>> +                   "https://foo.org/"))))
>
> This is OK, but I would add also
>
>     (should (equal (file-name-directory "https://foo.org/")
>                    "https://foo.org/"))))
>
> Maybe you could add also negative tests, for example for
> (file-name-directory "not-a-uri://foo.org")

Thanks for your feedback.

Here's a revised version.

From a8bc0f60cfc61b390e089166fcd69f267b77c39e Mon Sep 17 00:00:00 2001
From: Nicolas Petton <[email-masked]>
Date: Tue, 13 Mar 2018 22:07:08 +0100
Subject: [PATCH] Add URL handler for file-name-directory  (Bug#30444)

* lisp/url/url-handlers.el (url-handler-file-name-directory): New
function which handles special cases for `file-name-directory' and
URLs.
* test/lisp/url/url-handlers-test.el: New file.  Add tests for
`url-handler-file-name-directory'.
---
 lisp/url/url-handlers.el           |  9 +++++
 test/lisp/url/url-handlers-test.el | 80 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 89 insertions(+)
 create mode 100644 test/lisp/url/url-handlers-test.el

diff --git a/lisp/url/url-handlers.el b/lisp/url/url-handlers.el
index 7d0320cb5b..17c76cff75 100644
--- a/lisp/url/url-handlers.el
+++ b/lisp/url/url-handlers.el
@@ -186,6 +186,7 @@ url-file-handler-identity
 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
+(put 'file-name-directory 'url-file-handlers 'url-handler-file-name-directory)
 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
@@ -231,6 +232,14 @@ url-handler-unhandled-file-name-directory
       ;; a local process.
       nil)))
 
+(defun url-handler-file-name-directory (dir)
+  (let ((url (url-generic-parse-url dir)))
+    ;; Do not attempt to handle `file' URLs which are local.
+    (if (and (not (equal (url-type url) "file"))
+	     (string-empty-p (url-filename url)))
+	(url-handler-file-name-directory (concat dir "/"))
+      (url-run-real-handler 'file-name-directory (list dir)))))
+
 (defun url-handler-file-remote-p (filename &optional identification _connected)
   (let ((url (url-generic-parse-url filename)))
     (if (and (url-type url) (not (equal (url-type url) "file")))
diff --git a/test/lisp/url/url-handlers-test.el b/test/lisp/url/url-handlers-test.el
new file mode 100644
index 0000000000..814c68bac3
--- /dev/null
+++ b/test/lisp/url/url-handlers-test.el
@@ -0,0 +1,80 @@
+;;; url-handlers-test.el --- Test suite for url-handlers.el  -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2018 Free Software Foundation, Inc.
+
+;; Author: Nicolas Petton <[email-masked]>
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;; Code:
+
+(require 'ert)
+(require 'url-handlers)
+
+(defmacro with-url-handler-mode (&rest body)
+  "Evaluate BODY with `url-handler-mode' turned on."
+  (declare (indent 0) (debug t))
+  (let ((url-handler-mode-active (make-symbol "url-handler-mode-active")))
+    `(let ((,url-handler-mode-active url-handler-mode))
+       (unwind-protect
+           (progn
+             (unless ,url-handler-mode-active
+               (url-handler-mode))
+             ,@body)
+         (unless ,url-handler-mode-active
+           (url-handler-mode -1))))))
+
+(ert-deftest url-handlers-file-name-directory/preserve-url-types ()
+  (with-url-handler-mode
+    (should (equal (file-name-directory "https://gnu.org/index.html")
+                   "https://gnu.org/"))
+    (should (equal (file-name-directory "http://gnu.org/index.html")
+                   "http://gnu.org/"))
+    (should (equal (file-name-directory "ftp://gnu.org/index.html")
+                   "ftp://gnu.org/"))))
+
+(ert-deftest url-handlers-file-name-directory/should-not-handle-non-url-file-names ()
+  (with-url-handler-mode
+    (should-not (equal (file-name-directory "not-uri://gnu.org")
+                   "not-uri://gnu.org/"))))
+
+(ert-deftest url-handlers-file-name-directory/sub-directories ()
+  (with-url-handler-mode
+    (should (equal (file-name-directory "https://foo/bar/baz/index.html")
+                   "https://foo/bar/baz/"))))
+
+(ert-deftest url-handlers-file-name-directory/file-urls ()
+  (with-url-handler-mode
+    (should (equal (file-name-directory "file:///foo/bar/baz.txt")
+                   "file:///foo/bar/"))
+    (should (equal (file-name-directory "file:///")
+                   "file:///"))))
+
+;; Regression test for bug#30444
+(ert-deftest url-handlers-file-name-directory/no-filename ()
+  (with-url-handler-mode
+    (should (equal (file-name-directory "https://foo.org")
+                   "https://foo.org/"))
+    (should (equal (file-name-directory "https://foo.org/")
+                   "https://foo.org/"))))
+
+(ert-deftest url-handlers-file-name-directory/should-not-handle-non-url-file-names ()
+  (with-url-handler-mode
+    (should-not (equal (file-name-directory "not-uri://gnu.org")
+                   "not-uri://gnu.org/"))))
+
+(provide 'url-handlers-test)
+;;; url-handlers-test.el ends here
-- 
2.14.3

Cheers,
Nico