Subject: Re: [bug#30390] [PATCH 1/3] gnu: Add rhash.

From: Marius Bakke <[email-masked]>
Date: Tue, 20 Feb 2018 18:44:45 +0100

Arun Isaac <[email-masked]> writes:

> * gnu/packages/crypto.scm (rhash): New variable.

[...]

> +(define-public rhash
> +  (package
> +    (name "rhash")
> +    (version "1.3.5")
> +    (source
> +     (origin
> +       (method url-fetch)
> +       (uri (string-append "https://github.com/rhash/RHash/archive/v"
> +                           version ".tar.gz"))
> +       (file-name (string-append name "-" version ".tar.gz"))
> +       (sha256
> +        (base32
> +         "0bhz3xdl6r06k1bqigdjz42l31iqz2qdpg7zk316i7p2ra56iq4q"))))
> +    (build-system gnu-build-system)
> +    (arguments
> +     `(#:make-flags (list "CC=gcc"
> +                          (string-append "PREFIX=" %output))
> +       #:test-target "test"
> +       #:phases
> +       (modify-phases %standard-phases
> +         (replace 'configure
> +           (lambda* (#:key outputs #:allow-other-keys)
> +             (substitute* "Makefile"
> +               (("\\$\\(DESTDIR\\)/etc")
> +                (string-append (assoc-ref outputs "out") "/etc")))
> +             #t))
> +         (add-after 'build 'build-library
> +           (lambda* (#:key outputs make-flags #:allow-other-keys)
> +             (apply invoke "make" "lib-shared" make-flags)
> +             #t))
> +         (add-after 'install 'install-library
> +           (lambda* (#:key outputs make-flags #:allow-other-keys)
> +             (apply invoke "make" "install-lib-shared" make-flags)
> +             (apply invoke
> +                    "make" "-C" "librhash" "install-headers"
> +                    "install-so-link" make-flags)
> +             #t))
> +         (add-after 'check 'check-library
> +           (lambda* (#:key outputs make-flags #:allow-other-keys)
> +             (apply invoke "make" "test-shared-lib" make-flags)
> +             #t)))))

I think the "outputs" key is unnecessary in all these phases.

Also, (invoke ...) returns #t on successful execution, so no need to add
an extra #t at the end.

> +    (home-page "https://sourceforge.net/projects/rhash/")
> +    (synopsis "Utility for computing hash sums")
> +    (description "RHash is a console utility for calculation and verification
> +of magnet links and a wide range of hash sums like CRC32, MD4, MD5, SHA1,
> +SHA256, SHA512, SHA3, AICH, ED2K, Tiger, DC++ TTH, BitTorrent BTIH, GOST R
> +34.11-94, RIPEMD-160, HAS-160, EDON-R, Whirlpool and Snefru.")
> +    (license (license:fsf-free "file://COPYING"))))

Has this license been approved by the FSF?  If so please add a URL.
Otherwise I'd go with "non-copyleft" here.

Otherwise this LGTM.  I guess this can go to "master" in case it's
needed before the CMake update.