Subject: 26.0; Add function(s) for current monitor info

From: Drew Adams <[email-masked]>
Date: Wed, 10 Jan 2018 15:08:27 -0800 (PST)

Please consider adding a function that returns the info describing the
monitor that dominates a frame (default: selected frame).  In
particular, the size of the monitor.  This can be useful, for example,
for positioning a frame when there are multiple monitors.

I've been using this, but you might have a better implementation in
mind:

(defun current-monitor (&optional frame)
  "Attributes of monitor that dominates FRAME (default: `selected-frame')."
  (catch 'current-monitor
    (dolist (atts  (display-monitor-attributes-list frame))
      (when (member (or frame  (selected-frame)) (cdr (assq 'frames atts)))
        (throw 'current-monitor atts)))
    nil))                              ; Should never happen (?)

(defun current-monitor-size (&optional frame workarea-p)
  "Size of the monitor that dominates FRAME (default: `selected-frame').
This is a cons (WIDTH . HEIGHT) where WIDTH and HEIGHT are in pixels.

Uses the full area of the monitor (attribute `geometry' of
`display-monitor-attributes-list') by default.  Non-nil optional arg
WORKAREA-P means use only the available work area (attribute
`workarea') instead."
  (let* ((att  (if workarea-p 'workarea 'geometry))
         (mon  (assq att (current-monitor frame))))
    (cons (nth 3 mon) (nth 4 mon))))

Dunno whether the fallback value of nil is needed.  I haven't come
across a frame that is not listed in attribute `frames' of
`display-monitor-attributes-list'.  Even invisible frames are listed.
Dunno about deleted frames.

Whether it would also be useful to have functions corresponding to
attributes such as `mm-size' and `name' is another question.

In GNU Emacs 26.0.90 (build 3, x86_64-w64-mingw32)
 of 2017-10-13
Repository revision: 906224eba147bdfc0514090064e8e8f53160f1d4
Windowing system distributor `Microsoft Corp.', version 6.1.7601
Configured using:
 `configure --without-dbus --host=x86_64-w64-mingw32
 --without-compress-install 'CFLAGS=-O2 -static -g3''