Subject: 26.0.50; Dired: Use relative file names when DIR-OR-LIST is a cons

From: Tino Calancha <[email-masked]>
Date: Mon, 24 Jul 2017 12:29:48 +0900

Severity: wishlist

emacs -Q /tmp

;; Following form shows the full file name in the Dired buffer.
(let* ((dir source-directory)
       (file1 (expand-file-name "lisp/subr.el" dir))
       (file2 (expand-file-name "src/data.c" dir)))
  (dired (list dir file1 file2)))

;; Usually, Dired just shows the relative file name to
;; 'default-directory'.  That is more clear, specially for
;; long file names.

--8<-----------------------------cut here---------------start------------->8---
commit 192c9b0179adbe4ae65d956f064eb9c2197a0a01
Author: Tino Calancha <[email-masked]>
Date:   Mon Jul 24 12:25:24 2017 +0900

    Dired: Use relative file names when DIR-OR-LIST is a cons
    
    * lisp/dired.el (dired-internal-noselect): Use relative file
    names when DIR-OR-LIST is a cons.
    * test/lisp/dired-tests.el (dired-test-bug27801): Add test.

diff --git a/lisp/dired.el b/lisp/dired.el
index 9d500a9f52..718c2b8cf9 100644
--- a/lisp/dired.el
+++ b/lisp/dired.el
@@ -926,6 +926,11 @@ dired-internal-noselect
 	    ;; if it was the name of a directory at all.
 	    (file-name-directory dirname))
       (or switches (setq switches dired-listing-switches))
+      ;; If `dir-or-list' is a cons, use file names relative
+      ;; to default-directory.
+      (when (and (consp dir-or-list) (file-name-absolute-p (cadr dir-or-list)))
+        (setf (cdr dir-or-list)
+              (mapcar #'file-relative-name (cdr dir-or-list))))
       (if mode (funcall mode)
         (dired-mode dir-or-list switches))
       ;; default-directory and dired-actual-switches are set now
diff --git a/test/lisp/dired-tests.el b/test/lisp/dired-tests.el
index 69331457c0..4241609ec6 100644
--- a/test/lisp/dired-tests.el
+++ b/test/lisp/dired-tests.el
@@ -175,5 +175,25 @@
           (should (looking-at "src")))
       (when (buffer-live-p buf) (kill-buffer buf)))))
 
+(ert-deftest dired-test-bug27801 ()
+  "Test for http://debbugs.gnu.org/27801 ."
+  (let* ((dir (make-temp-file "bug27801" 'dir))
+         (foo (expand-file-name "foo" dir))
+         (bar (expand-file-name "bar" dir))
+         (f1 (expand-file-name "file" foo))
+         (f2 (expand-file-name "file" bar))
+         buf)
+    (unwind-protect
+        (progn
+          (make-directory foo)
+          (make-directory bar)
+          (with-temp-file f1 nil)
+          (with-temp-file f2 nil)
+          (setq buf (dired (list dir f1 f2)))
+          (dired-goto-file f1)
+          (should (looking-at "foo/file$")))
+      (when (buffer-live-p buf) (kill-buffer buf))
+      (delete-directory dir t))))
+
 (provide 'dired-tests)
 ;; dired-tests.el ends here
--8<-----------------------------cut here---------------end--------------->8---
In GNU Emacs 26.0.50 (build 1, x86_64-pc-linux-gnu, GTK+ Version 3.22.11)
 of 2017-07-23
Repository revision: 1f450f1d3531cb53ebe50744c85c90141fce7ad0