Subject: bug#26815: [PATCH 3/3] vm: Add UEFI loader to disk images.

From: Marius Bakke <[email-masked]>
Date: Wed, 10 May 2017 21:52:27 +0200

* gnu/system/vm.scm (qemu-image): Add GRUB-EFI to inputs. Append 40MiB EFI
System Partition.
* gnu/build/vm.scm (install-efi): New procedure.
(initialize-hard-disk): Generate grub EFI blob when ESP is present.
---
 gnu/build/vm.scm  | 60 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 gnu/system/vm.scm | 19 +++++++++++++++---
 2 files changed, 76 insertions(+), 3 deletions(-)

diff --git a/gnu/build/vm.scm b/gnu/build/vm.scm
index 935a174fc..258c0b8ae 100644
--- a/gnu/build/vm.scm
+++ b/gnu/build/vm.scm
@@ -27,6 +27,7 @@
   #:use-module (gnu build linux-boot)
   #:use-module (gnu build install)
   #:use-module (guix records)
+  #:use-module (ice-9 format)
   #:use-module (ice-9 match)
   #:use-module (ice-9 regex)
   #:use-module (srfi srfi-1)
@@ -315,6 +316,34 @@ SYSTEM-DIRECTORY is the name of the directory of the 'system' derivation."
     (mkdir-p directory)
     (symlink bootcfg (string-append directory "/bootcfg"))))
 
+(define (install-efi esp grub.cfg)
+  "Write a self-contained Grub UEFI blob to the mounted ESP using GRUB.CFG."
+  (let* ((system %host-type)
+         ;; Hard code the output location to a well-known path recognized by
+         ;; compliant firmware. See "3.5.1.1 Removable Media Boot Behaviour":
+         ;; http://www.uefi.org/sites/default/files/resources/UEFI%20Spec%202_6.pdf
+         (efi-directory (string-append esp "/EFI/BOOT"))
+         ;; Map grub target names to boot file names.
+         (efi-target-map (cond
+                          ((string-prefix? "x86_64" system)
+                           '("x86_64-efi" . "BOOTX64.EFI"))
+                          ((string-prefix? "i686" system)
+                           '("i386-efi" . "BOOTIA32.EFI"))
+                          ((string-prefix? "armhf" system)
+                           '("arm-efi" . "BOOTARM.EFI"))
+                          ((string-prefix? "aarch64" system)
+                           '("arm64-efi" . "BOOTAA64.EFI")))))
+    ;; Grub needs a TMPDIR to prepare the firmware image.
+    (setenv "TMPDIR" esp)
+
+    (mkdir-p efi-directory)
+    (unless (zero? (system* "grub-mkstandalone" "-O" (car efi-target-map)
+                            "-o" (string-append efi-directory "/"
+                                                (cdr efi-target-map))
+                            ;; Graft the configuration file onto the image.
+                            (string-append "boot/grub/grub.cfg=" grub.cfg)))
+      (error "failed to create grub EFI image"))))
+
 (define* (initialize-hard-disk device
                                #:key
                                bootloader
@@ -332,8 +361,13 @@ passing it a directory name where it is mounted."
     "Return the first partition found with the boot flag set."
     (member 'boot (partition-flags partition)))
 
+  (define (partition-esp? partition)
+    "Return the first EFI System Partition."
+    (member 'esp (partition-flags partition)))
+
   (let* ((partitions (initialize-partition-table device partitions))
          (root       (find partition-bootable? partitions))
+         (esp        (find partition-esp? partitions))
          (target     "/fs"))
     (unless root
       (error "no bootable partition specified" partitions))
@@ -345,8 +379,34 @@ passing it a directory name where it is mounted."
     (mount (partition-device root) target (partition-file-system root))
     (install-boot-config bootcfg bootcfg-location target)
     (when bootloader-installer
+      (display "installing bootloader...\n")
       (bootloader-installer bootloader device target))
 
+    (when esp
+      ;; Mount the ESP somewhere and install Grub UEFI image.
+      (let ((mount-point (string-append target "/boot/efi"))
+            (grub.cfg    (string-append target "/tmp/grub-standalone.cfg")))
+        (display "mounting EFI system partition...\n")
+        (mkdir-p mount-point)
+        (mount (partition-device esp) mount-point
+               (partition-file-system esp))
+
+        ;; Create a tiny configuration file telling the embedded grub
+        ;; where to load the real thing.
+        (with-output-to-file grub.cfg
+          (lambda _
+            (format #t
+                    "insmod part_msdos~@
+                    search --set=root --label gnu-disk-image~@
+                    configfile /boot/grub/grub.cfg~%")))
+
+        (display "creating EFI firmware image...")
+        (install-efi mount-point grub.cfg)
+        (display "done.\n")
+
+        (delete-file grub.cfg)
+        (umount mount-point)))
+
     ;; Register BOOTCFG as a GC root.
     (register-bootcfg-root target bootcfg)
 
diff --git a/gnu/system/vm.scm b/gnu/system/vm.scm
index 099e3fac3..fbabcf6c3 100644
--- a/gnu/system/vm.scm
+++ b/gnu/system/vm.scm
@@ -3,6 +3,7 @@
 ;;; Copyright © 2016 Christopher Allan Webber <[email-masked]>
 ;;; Copyright © 2016 Leo Famulari <[email-masked]>
 ;;; Copyright © 2017 Mathieu Othacehe <[email-masked]>
+;;; Copyright © 2017 Marius Bakke <[email-masked]>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -202,7 +203,7 @@ the image."
                       (guix build utils))
 
          (let ((inputs
-                '#$(append (list qemu parted e2fsprogs dosfstools)
+                '#$(append (list qemu parted e2fsprogs dosfstools grub-efi)
                            (map canonical-package
                                 (list sed grep coreutils findutils gawk))
                            (if register-closures? (list guix) '())))
@@ -227,11 +228,23 @@ the image."
                                #:system-directory #$os.drv))
                   (partitions (list (partition
                                      (size #$(- disk-image-size
-                                                (* 10 (expt 2 20))))
+                                                (* 50 (expt 2 20))))
                                      (label #$file-system-label)
                                      (file-system #$file-system-type)
                                      (flags '(boot))
-                                     (initializer initialize)))))
+                                     (initializer initialize))
+                                    ;; Append a small EFI System Partition for
+                                    ;; use with UEFI bootloaders.
+                                    (partition
+                                     ;; The standalone grub image is about 10MiB, but
+                                     ;; leave some room for custom or multiple images.
+                                     (size (* 40 (expt 2 20)))
+                                     (label "GNU-ESP")             ;cosmetic only
+                                     ;; Use "vfat" here since this property is used
+                                     ;; when mounting. The actual FAT-ness is based
+                                     ;; on filesystem size (16 in this case).
+                                     (file-system "vfat")
+                                     (flags '(esp))))))
              (initialize-hard-disk "/dev/vda"
                                    #:partitions partitions
                                    #:bootloader
-- 
2.12.2