Subject: bug#25157: 26.0.50; whitespace-cleanup does not remove single trailing empty line anymore

From: [email-masked]
Date: Tue, 20 Dec 2016 23:07:56 -0500

Reuben Thomas <[email-masked]> writes:

>
> Given my previous error of reasoning, I'm submitting the above for your consideration before I prepare a patch!

Sorry I didn't get around to looking at this before you wrote a patch,
but I think you're overthinking this.  AFAICT, your first fix (in
https://debbugs.gnu.org/cgi/bugreport.cgi?bug=24745#5) was right.
Here's a patch with some tests, let me know if I missed any cases.

>From e918857882733460a429f6a37344567a5021efa5 Mon Sep 17 00:00:00 2001
From: Noam Postavsky <[email-masked]>
Date: Tue, 20 Dec 2016 23:02:48 -0500
Subject: [PATCH v1] Fix whitespace eob cleanup

* lisp/whitespace.el (whitespace-empty-at-eob-regexp): Match any number
of empty lines at end of buffer.
* test/lisp/whitespace-tests.el (whitespace-cleanup-eob): New test.
(whitespace-tests--cleanup-string): New helper function for tests.
---
 lisp/whitespace.el            |  2 +-
 test/lisp/whitespace-tests.el | 52 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+), 1 deletion(-)
 create mode 100644 test/lisp/whitespace-tests.el

diff --git a/lisp/whitespace.el b/lisp/whitespace.el
index 29d60c9..a15308c 100644
--- a/lisp/whitespace.el
+++ b/lisp/whitespace.el
@@ -729,7 +729,7 @@ whitespace-empty-at-bob-regexp
   :group 'whitespace)

-(defcustom whitespace-empty-at-eob-regexp "^\\([ \t\n]*\\(\n\\{2,\\}\\|[ \t]+\\)\\)\\'"
+(defcustom whitespace-empty-at-eob-regexp "^\\([ \t\n]+\\)\\'"
   "Specify regexp for empty lines at end of buffer.
 
 Used when `whitespace-style' includes `empty'."
diff --git a/test/lisp/whitespace-tests.el b/test/lisp/whitespace-tests.el
new file mode 100644
index 0000000..ffd2e65
--- /dev/null
+++ b/test/lisp/whitespace-tests.el
@@ -0,0 +1,52 @@
+;;; whitespace-tests.el --- Test suite for whitespace -*- lexical-binding: t -*-
+
+;; Copyright (C) 2016 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(require 'whitespace)
+
+(defun whitespace-tests--cleanup-string (string)
+  (with-temp-buffer
+    (insert string)
+    (whitespace-cleanup)
+    (buffer-string)))
+
+(ert-deftest whitespace-cleanup-eob ()
+  (let ((whitespace-style '(empty)))
+    (should (equal (whitespace-tests--cleanup-string "a\n")
+                   "a\n"))
+    (should (equal (whitespace-tests--cleanup-string "a\n\n")
+                   "a\n"))
+    (should (equal (whitespace-tests--cleanup-string "a\n\t\n")
+                   "a\n"))
+    (should (equal (whitespace-tests--cleanup-string "a\n\t \n")
+                   "a\n"))
+    (should (equal (whitespace-tests--cleanup-string "a\n\t \n\n")
+                   "a\n"))
+    (should (equal (whitespace-tests--cleanup-string "\n\t\n")
+                   ""))
+    ;; Whitespace at end of non-empty line is not covered by the
+    ;; `empty' style.
+    (should (equal (whitespace-tests--cleanup-string "a  \n\t \n\n")
+                   "a  \n"))))
+
+(provide 'whitespace-tests)
+
+;;; whitespace-tests.el ends here
-- 
2.9.3