Subject: bug#25000: 26.0.50; Ibuffer might compare marks case insensitively

From: Tino Calancha <[email-masked]>
Date: Wed, 23 Nov 2016 21:11:21 +0900

In Ibuffer mark comparisons should be case _sensitive_.

emacs -Q:
;; eval following form:
(let ((case-fold-search t))
  (ibuffer)
  (ibuffer-mark-by-name-regexp "scratch")
  (ibuffer-change-marks ibuffer-marked-char ?L)
  (ibuffer-mark-by-name-regexp "Messages")
  (ibuffer-change-marks ibuffer-marked-char ?l)
  (null (cdr (ibuffer-buffer-names-with-mark ?l))))
=> nil
;; It doesn't distinguish between mark "L" and "l".

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
>From a6275e8e966c4f58e30f7aa3787557961385c6dc Mon Sep 17 00:00:00 2001
From: Tino Calancha <[email-masked]>
Date: Wed, 23 Nov 2016 21:04:31 +0900
Subject: [PATCH] ibuffer: compare marks with EQ

* lisp/ibuffer (ibuffer-update-title-and-summary, ibuffer-redisplay-current)
(ibuffer-buffer-name-face, ibuffer-unmark-all)
(ibuffer-count-deletion-lines, ibuffer-buffer-names-with-mark):
Use 'eq' instead of 'char-equal' when comparing mark characters (Bug#25000).
---
 lisp/ibuffer.el | 28 ++++++++++++++--------------
 1 file changed, 14 insertions(+), 14 deletions(-)

diff --git a/lisp/ibuffer.el b/lisp/ibuffer.el
index 51d7cb9..4268be3 100644
--- a/lisp/ibuffer.el
+++ b/lisp/ibuffer.el
@@ -1236,7 +1236,7 @@ ibuffer-buffer-names-with-mark
   (let ((ibuffer-buffer-names-with-mark-result nil))
     (ibuffer-map-lines-nomodify
      (lambda (buf mk)
-       (when (char-equal mark mk)
+       (when (eq mark mk)
 	 (push (buffer-name buf)
 	       ibuffer-buffer-names-with-mark-result))))
     ibuffer-buffer-names-with-mark-result))
@@ -1251,15 +1251,15 @@ ibuffer-count-marked-lines
   (if all
       (ibuffer-map-lines-nomodify
        (lambda (_buf mark)
-	 (not (char-equal mark ?\s))))
+	 (not (eq mark ?\s))))
     (ibuffer-map-lines-nomodify
      (lambda (_buf mark)
-       (char-equal mark ibuffer-marked-char)))))
+       (eq mark ibuffer-marked-char)))))
 
 (defsubst ibuffer-count-deletion-lines ()
   (ibuffer-map-lines-nomodify
    (lambda (_buf mark)
-     (char-equal mark ibuffer-deletion-char))))
+     (eq mark ibuffer-deletion-char))))
 
 (defsubst ibuffer-map-deletion-lines (func)
   (ibuffer-map-on-mark ibuffer-deletion-char func))
@@ -1338,26 +1338,26 @@ ibuffer-unmark-all
   (if (= (ibuffer-count-marked-lines t) 0)
       (message "No buffers marked; use 'm' to mark a buffer")
     (cond
-     ((char-equal mark ibuffer-marked-char)
+     ((eq mark ibuffer-marked-char)
       (ibuffer-map-marked-lines
        (lambda (_buf _mark)
 	 (ibuffer-set-mark-1 ?\s)
 	 t)))
-     ((char-equal mark ibuffer-deletion-char)
+     ((eq mark ibuffer-deletion-char)
       (ibuffer-map-deletion-lines
        (lambda (_buf _mark)
 	 (ibuffer-set-mark-1 ?\s)
 	 t)))
-     ((not (char-equal mark ?\r))
+     ((not (eq mark ?\r))
       (ibuffer-map-lines
        (lambda (_buf cmark)
-	 (when (char-equal cmark mark)
+	 (when (eq cmark mark)
 	   (ibuffer-set-mark-1 ?\s))
 	 t)))
      (t
       (ibuffer-map-lines
        (lambda (_buf mark)
-	 (when (not (char-equal mark ?\s))
+	 (when (not (eq mark ?\s))
 	   (ibuffer-set-mark-1 ?\s))
 	 t)))))
   (ibuffer-redisplay t))
@@ -1908,9 +1908,9 @@ ibuffer-format-column
       (_ (concat str left right)))))
 
 (defun ibuffer-buffer-name-face (buf mark)
-  (cond ((char-equal mark ibuffer-marked-char)
+  (cond ((eq mark ibuffer-marked-char)
 	 ibuffer-marked-face)
-	((char-equal mark ibuffer-deletion-char)
+	((eq mark ibuffer-deletion-char)
 	 ibuffer-deletion-face)
 	(t
 	 (let ((level -1)
@@ -1954,7 +1954,7 @@ ibuffer-redisplay-current
 (defun ibuffer-map-on-mark (mark func)
   (ibuffer-map-lines
    (lambda (buf mk)
-     (if (char-equal mark mk)
+     (if (eq mark mk)
 	 (funcall func buf mark)
        nil))))
 
@@ -2181,8 +2181,8 @@ ibuffer-update-title-and-summary
 		      (buffer-substring (point) (line-end-position)))))
 	   (apply #'insert (mapcar
 			    (lambda (c)
-			      (if (not (or (char-equal c ?\s)
-					   (char-equal c ?\n)))
+			      (if (not (or (eq c ?\s)
+					   (eq c ?\n)))
 				  ?-
 				?\s))
 			    str)))
-- 
2.10.2

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
In GNU Emacs 26.0.50.7 (x86_64-pc-linux-gnu, GTK+ Version 3.22.3)
 of 2016-11-23 built on calancha-pc
Repository revision: c542fab20f53374dd0c71dce949ef370fc76fa48