Subject: Re: bug#24848: [sh-script] How to save "Local rules set" result from sh-learn-buffer-indent?

From: [email-masked]
Date: Fri, 08 Sep 2017 19:15:32 -0400

<[email-masked]> writes:

> Thanks Noam.  I'm not sure I've got any way to test this patch,
> though...  I don't seem to have an smie.el file anywhere.  I've
> installed the emacs24-el package expecting that to contain it but it
> doesn't -- at least, I've searched my entire hard drive for it (using
> sudo, just in case) and it wasn't found.

What does M-x find-library RET smie RET give you?

I see /usr/share/emacs/24.5/lisp/emacs-lisp/smie.el.gz listed in
https://packages.ubuntu.com/zesty/all/emacs24-el/filelist.  If you have
the gzipped version, you might have to unzip before you can apply the
patch.

Alternatively, I'm fairly sure if you just drop the patched definitions
of smie-config--setter and smie-config into your .emacs it will have the
same effect:

    (defun smie-config--setter (var value)
      (set-default var value)
      (let ((old-modefuns smie-config--modefuns))
        (setq smie-config--modefuns nil)
        (pcase-dolist (`(,mode . ,rules) value)
          (let ((modefunname (intern (format "smie-config--modefun-%s" mode))))
            (fset modefunname (lambda () (smie-config--mode-hook rules)))
            (push modefunname smie-config--modefuns)
            (add-hook (intern (format "%s-hook" mode)) modefunname)))
        ;; Neuter any left-over previously installed hook.
        (dolist (modefun old-modefuns)
          (unless (memq modefun smie-config--modefuns)
            (fset modefun #'ignore)))))

    (defcustom smie-config nil
      ;; FIXME: there should be a file-local equivalent.
      "User configuration of SMIE indentation.
    This is a list of elements (MODE . RULES), where RULES is a list
    of elements describing when and how to change the indentation rules.
    Each RULE element should be of the form (NEW KIND TOKEN NORMAL),
    where KIND and TOKEN are the elements passed to `smie-rules-function',
    NORMAL is the value returned by `smie-rules-function' and NEW is the
    value with which to replace it."
      :version "24.4"
      ;; FIXME improve value-type.
      :type '(choice (const nil)
                     (alist :key-type symbol))
      :initialize 'custom-initialize-set
      :set #'smie-config--setter)