Subject: bug#19434: 24.4; cl-subseq bounding issues

From: Leo Liu <[email-masked]>
Date: Wed, 24 Dec 2014 12:14:22 +0800

At the moment (cl-subseq '(1 2 3) 0 5) => (1 2 3 nil nil)

I propose the following fix:

diff --git a/lisp/emacs-lisp/cl-extra.el b/lisp/emacs-lisp/cl-extra.el
index a94dcd33..b50c1e6a 100644
--- a/lisp/emacs-lisp/cl-extra.el
+++ b/lisp/emacs-lisp/cl-extra.el
@@ -524,15 +524,21 @@ (defun cl-subseq (seq start &optional end)
               `(progn (cl-replace ,seq ,new :start1 ,start :end1 ,end)
                       ,new))))
   (if (stringp seq) (substring seq start end)
-    (let (len)
+    (let ((orig-start start) (orig-end end) len)
       (and end (< end 0) (setq end (+ end (setq len (length seq)))))
       (if (< start 0) (setq start (+ start (or len (setq len (length seq))))))
       (cond ((listp seq)
-	     (if (> start 0) (setq seq (nthcdr start seq)))
+	     (when (> start 0)
+	       (setq seq (nthcdr (1- start) seq))
+	       (or seq
+		   (error "Bad bounding indices: %s, %s" orig-start orig-end))
+	       (setq seq (cdr seq)))
 	     (if end
 		 (let ((res nil))
-		   (while (>= (setq end (1- end)) start)
+		   (while (and seq (>= (setq end (1- end)) start))
 		     (push (pop seq) res))
+		   (or (= start end)
+		       (error "Bad bounding indices: %s, %s" orig-start orig-end))
 		   (nreverse res))
 	       (copy-sequence seq)))
 	    (t
diff --git a/test/automated/cl-lib-tests.el b/test/automated/cl-lib-tests.el
index e4c6e914..162f7aeb 100644
--- a/test/automated/cl-lib-tests.el
+++ b/test/automated/cl-lib-tests.el
@@ -245,4 +245,10 @@ (ert-deftest cl-parse-integer ()
 (ert-deftest cl-loop-destructuring-with ()
   (should (equal (cl-loop with (a b c) = '(1 2 3) return (+ a b c)) 6)))
 
+(ert-deftest cl-subseq ()
+  (should-error (cl-subseq '(1 2 3) 4))
+  (should-not   (cl-subseq '(1 2 3) 3))
+  (should       (cl-subseq '(1 2 3) -3))
+  (should-error (cl-subseq '(1 2 3) 1 4)))
+
 ;;; cl-lib.el ends here