Subject: bug#17954: 24.4.50; [patch] `menu-bar-make-toggle' should allow for keywords

From: Drew Adams <[email-masked]>
Date: Sat, 5 Jul 2014 22:28:37 -0700 (PDT)

`menu-bar-make-toggle' handles no keywords.  It takes the value of
:help as an explicit argument (without keyword), but it does not pass
along :keys, :active, :enable, etc. to `menu-item'.  It should.

It cannot accept keywords in the normal way because it defines BODY as
an &rest parameter.  This mistake should be corrected, making for an
incompatible change unfortunately, in order to allow a KEYWORDS &rest
parameter.

BODY is seldom used.  In the Emacs Lisp sources, there are only these
two occurrences of `menu-bar-make-toggle' that use BODY:
`toggle-save-place-globally' and `toggle-uniquify-buffer-names'.  They
would just need to wrap the current BODY code in an explicit `progn'.

Of course, there may be 3rd-party code that uses parameter BODY.  The
only way I can think of to be sensitive to that breakage is to use a new
macro name and code, and deprecate the old name `menu-bar-make-toggle'.
Perhaps this incompatible change could be tolerated, since BODY is rare
and the adaptation for any existing code is trivial (wrap with `progn').

Here is one possible definition (with a doc string and better parameter
names):

(defmacro bmkp-menu-bar-make-toggle (command variable item-name message help
                                     &optional setting-sexp &rest keywords)
  "Define a menu-bar toggle command.
COMMAND (a symbol) is the toggle command to define.
VARIABLE (a symbol) is the variable to set.
ITEM-NAME (a string) is the menu-item name.
MESSAGE is a format string for the toggle message, with %s for the new
 status.
HELP (a string) is the `:help' tooltip text and the doc string first
 line (minus final period) for the command.
SETTING-SEXP is a Lisp sexp that sets VARIABLE, or it is nil meaning
 set it according to its `defcustom' or using `set-default'.
KEYWORDS is a plist for `menu-item' for keywords other than `:help'."
  `(progn
    (defun ,command (&optional interactively)
      ,(concat "Toggle whether to " (downcase (substring help 0 1))
               (substring help 1) ".
In an interactive call, record this option as a candidate for saving
by \"Save Options\" in Custom buffers.")
      (interactive "p")
      (if ,(if setting-sexp
               `,setting-sexp
               `(progn
		 (custom-load-symbol ',variable)
		 (let ((set (or (get ',variable 'custom-set) 'set-default))
		       (get (or (get ',variable 'custom-get) 'default-value)))
		   (funcall set ',variable (not (funcall get ',variable))))))
          (message ,message "enabled globally")
        (message ,message "disabled globally"))
      ;; `customize-mark-as-set' must only be called when a variable is set
      ;; interactively, because the purpose is to mark the variable as a
      ;; candidate for `Save Options', and we do not want to save options that
      ;; the user has already set explicitly in the init file.
      (when interactively (customize-mark-as-set ',variable)))
    '(menu-item ,item-name ,command :help ,help
      :button (:toggle . (and (default-boundp ',variable)
                          (default-value ',variable)))
      ,@keywords)))

In GNU Emacs 24.4.50.1 (i686-pc-mingw32)
 of 2014-06-28 on ODIEONE
Bzr revision: 117431 [email-masked]
Windowing system distributor `Microsoft Corp.', version 6.1.7601
Configured using:
 `configure --prefix=/c/Devel/emacs/snapshot/trunk
 --enable-checking=yes,glyphs 'CFLAGS=-O0 -g3'
 LDFLAGS=-Lc:/Devel/emacs/lib 'CPPFLAGS=-DGC_MCHECK=1
 -Ic:/Devel/emacs/include''