Subject: bug#13160: closed (Re: bug#13160: 24.3.50; [PATCH] man page completion support beyond man-db)

From: [email-masked] (GNU bug Tracking System)
Date: Thu, 10 Jan 2013 15:03:02 +0000

Your bug report

#13160: 24.3.50; [PATCH] man page completion support beyond man-db

which was filed against the emacs package, has been closed.

The explanation is attached below, along with your original report.
If you require more details, please reply to [email-masked].

-- 
13160: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=13160
GNU Bug Tracking System
Contact [email-masked] with problems

Subject: Re: bug#13160: 24.3.50; [PATCH] man page completion support beyond man-db
From: Stefan Monnier <[email-masked]>
To: Wolfgang Jenkner <[email-masked]>
Cc: [email-masked], Kevin Ryde <[email-masked]>
Date: Thu, 10 Jan 2013 10:01:54 -0500
List-Id: <debbugs-submit.debbugs.gnu.org>

> Subject: [PATCH] Support man page completion for more man programs. *
>  lisp/man.el (Man-parse-man-k): New function. (Man-man-k-use-anchor): New
>  variable. (Man-completion-table): Use them to replace man-db specific code
>  for parsing `man -k' output.

Thanks, installed (along with the previous cache-flush patch and with
a few minor changes, mostly not trimming the extraneous entries we get
if the anchor is not used).

        Stefan

Subject: 24.3.50; [PATCH] man page completion support beyond man-db
From: Wolfgang Jenkner <[email-masked]>
To: [email-masked]
Cc: Kevin Ryde <[email-masked]>
Date: Wed, 12 Dec 2012 20:16:45 +0100
List-Id: <debbugs-submit.debbugs.gnu.org>

In lisp/man.el, completion of man pages and sections depends on parsing
the output of `man -k'.  As a bonus, this method provides short
descriptions in the form of tooltips in the *Completions* buffer.

However, the code only handles the `man -k' output format peculiar to
the man-db package, which, even on GNU/Linux, is not the only one used
for this purpose.

For example, Slackware seems to use man-1.6g, whose `man -k' output can
have an additional reference in square brackets between the page name
and the section, so that man topic completion does work in this case,
but neither sections nor descriptions are parsed.

The situation is even worse for FreeBSD, where multiple comma-separated
page names can be shown on the same line (which is arguably against the
spirit of POSIX man(1p), but that's not quite clear and doesn't help
much).

The last major discussion of man completion issues seems to be bug#3717,
through which I skimmed, but there doesn't seem to be anything related
to this kind of portability.  There is, however, some prior code in the
`man-completion-cache' function in

ftp://download.tuxfamily.org/user42/man-completion.el

to deal with this problem.  In particular, it handles the example

boot-scripts (7) [boot] - General description of boot sequence

where the present patch would miss the section.  However, I don't know
of a man program which actually produces this format (man-1.6g has the
reference in square brackets /preceding/ the section).  Otherwise, the
following patch, which I'd like to install, should handle more formats.

It mainly adds a single separate function for parsing various formats.
There's also an ert test with examples for what I described above and
other formats found on the web.

Wolfgang

=== modified file 'lisp/man.el'
--- lisp/man.el	2012-08-15 16:29:11 +0000
+++ lisp/man.el	2012-12-12 16:00:11 +0000
@@ -780,6 +780,57 @@
   ;; but apparently that's not the case in all cases, so let's add a cache.
   "Cache of completion table of the form (PREFIX . TABLE).")
 
+(defvar Man-keyword-completion-twiddle
+  (cond
+   ;; man-db-* or man-*.
+   ((memq system-type '(gnu gnu/linux gnu/kfreebsd))
+    "^")
+   (t
+    ""))
+  "A string prepended to the keyword passed to `man -k' for completion.
+This should usually be an extended regular expression.
+
+Actually, unwanted page names are weeded out anyway, so with an
+empty string here we will always get correct results, but things
+may take a bit longer.")
+
+(defun Man-parse-apropos (&optional table)
+  "Parse `man -k' output, prepend page names to TABLE and return that.
+
+The current buffer should contain the output of a command of the
+form `man -k keyword', which is traditionally also available with
+apropos(1).
+
+While POSIX man(1p) is a bit vague about what to expect here,
+this function tries to parse some commonly used formats, which
+can be described in the following informal way, with square brackets
+indicating optional parts and whitespace being interpreted
+somewhat loosely.
+
+foo[, bar [, ...]] [other stuff] (sec) - description
+foo(sec)[, bar(sec) [, ...]] [other stuff] - description
+
+For more details and some regression tests, please see
+test/automated/man-tests.el in the emacs bzr repository."
+  (goto-char (point-min))
+  (while (search-forward-regexp "^\\([^ \t,\n]+\\)\\(.*?\\)\
+\\(?:[ \t]\\(([^ \t,\n]+?)\\)\\)?\\(?:[ \t]+- ?\\(.*\\)\\)?$" nil t)
+    (let ((section (match-string 3))
+	  (description (match-string 4))
+	  (bound (match-end 2))
+	  (continue (goto-char (match-end 1))))
+      (while continue
+	;; The first regexp grouping may already match the section
+	;; tacked on to the name, which is ok since for the formats we
+	;; claim to support the third (non-shy) grouping does not
+	;; match in this case, i.e., section is nil.
+	(push (propertize (concat (match-string 1) section)
+			  'help-echo description)
+	      table)
+	(setq continue (search-forward-regexp "\\=, *\\([^ \t,]+\\)"
+					      bound t)))))
+  table)
+
 (defun Man-completion-table (string pred action)
   (cond
    ;; This ends up returning t for pretty much any string, and hence leads to
@@ -813,12 +864,9 @@
             ;; error later.
             (ignore-errors
               (call-process manual-program nil '(t nil) nil
-                            "-k" (concat "^" prefix))))
-          (goto-char (point-min))
-          (while (re-search-forward "^\\([^ \t\n]+\\)\\(?: ?\\((.+?)\\)\\(?:[ \t]+- \\(.*\\)\\)?\\)?" nil t)
-            (push (propertize (concat (match-string 1) (match-string 2))
-                              'help-echo (match-string 3))
-                  table)))
+			    "-k" (concat Man-keyword-completion-twiddle
+					 prefix))))
+	  (setq table (Man-parse-apropos table)))
         ;; Cache the table for later reuse.
         (setq Man-completion-cache (cons prefix table)))
       ;; The table may contain false positives since the match is made

=== added file 'test/automated/man-tests.el'
--- test/automated/man-tests.el	1970-01-01 00:00:00 +0000
+++ test/automated/man-tests.el	2012-12-08 17:10:24 +0000
@@ -0,0 +1,118 @@
+;;; man-tests.el --- Test suite for man.
+
+;; Copyright (C) 2012  Free Software Foundation, Inc.
+
+;; Author: Wolfgang Jenkner <[email-masked]>
+;; Keywords: help, internal, unix
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(require 'man)
+
+(defconst man-tests-parse-apropos-tests
+  '(;; GNU/Linux: man-db-2.6.1
+    ("\
+sin (3)              - sine function
+sinf (3)             - sine function
+sinl (3)             - sine function"
+     . (#("sinl(3)" 0 7 (help-echo "sine function")) #("sinf(3)" 0 7 (help-echo "sine function")) #("sin(3)" 0 6 (help-echo "sine function"))))
+    ;; GNU/Linux: man-1.6g
+    ("\
+sin                  (3)  - sine function
+sinf [sin]           (3)  - sine function
+sinl [sin]           (3)  - sine function"
+     . (#("sinl(3)" 0 7 (help-echo "sine function")) #("sinf(3)" 0 7 (help-echo "sine function")) #("sin(3)" 0 6 (help-echo "sine function"))))
+    ;; FreeBSD 9
+    ("\
+sin(3), sinf(3), sinl(3) - sine functions"
+     . (#("sinl(3)" 0 7 (help-echo "sine functions")) #("sinf(3)" 0 7 (help-echo "sine functions")) #("sin(3)" 0 6 (help-echo "sine functions"))))
+    ;; SunOS, Solaris
+    ;; http://docs.oracle.com/cd/E19455-01/805-6331/usradm-7/index.html
+    ;; SunOS 4
+    ("\
+tset, reset (1)    - establish or restore terminal characteristics"
+     . (#("reset(1)" 0 8 (help-echo "establish or restore terminal characteristics")) #("tset(1)" 0 7 (help-echo "establish or restore terminal characteristics"))))
+    ;; SunOS 5.7, Solaris
+    ("\
+reset  tset (1b)   - establish or restore terminal characteristics
+tset   tset (1b)   - establish or restore terminal characteristics"
+     . (#("tset(1b)" 0 7 (help-echo "establish or restore terminal characteristics")) #("reset(1b)" 0 8 (help-echo "establish or restore terminal characteristics"))))
+    ;; Minix 3
+    ;; http://www.minix3.org/manpages/html5/whatis.html
+    ("\
+cawf, nroff (1) - C version of the nroff-like, Amazingly Workable (text) Formatter
+whatis (5) - database of online manual pages"
+     . (#("whatis(5)" 0 9 (help-echo "database of online manual pages")) #("nroff(1)" 0 8 (help-echo "C version of the nroff-like, Amazingly Workable (text) Formatter")) #("cawf(1)" 0 7 (help-echo "C version of the nroff-like, Amazingly Workable (text) Formatter"))))
+    ;; HP-UX
+    ;; http://docstore.mik.ua/manuals/hp-ux/en/B2355-60130/man.1.html
+    ;; Assuming that the line break in the zgrep description was
+    ;; introduced by the man page formatting.
+    ("\
+grep, egrep, fgrep (1) - search a file for a pattern
+zgrep(1) - search possibly compressed files for a regular expression"
+     . (#("zgrep(1)" 0 8 (help-echo "search possibly compressed files for a regular expression")) #("fgrep(1)" 0 8 (help-echo "search a file for a pattern")) #("egrep(1)" 0 8 (help-echo "search a file for a pattern")) #("grep(1)" 0 7 (help-echo "search a file for a pattern"))))
+    ;; AIX
+    ;; http://pic.dhe.ibm.com/infocenter/aix/v7r1/topic/com.ibm.aix.cmds/doc/aixcmds6/whatis.htm
+    ("\
+ls(1)  -Displays the contents of a directory."
+    . (#("ls(1)" 0 5 (help-echo "Displays the contents of a directory."))))
+    ;; https://www.ibm.com/developerworks/mydeveloperworks/blogs/cgaix/entry/catman_0703_102_usr_lbin_mkwhatis_the_error_number_is_1?lang=en
+    ("\
+loopmount(1)    - Associate an image file to a loopback device."
+     . (#("loopmount(1)" 0 12 (help-echo "Associate an image file to a loopback device."))))
+    )
+  "List of tests for `Man-parse-apropos'.
+Each element is a cons cell whose car is a string containing
+man -k output.  That should result in the table which is stored
+in the cdr of the element.")
+
+(defun man-tests-name-equal-p (name description string)
+  (and (equal name string)
+       (not (next-single-property-change 0 'help-echo string))
+       (equal (get-text-property 0 'help-echo string) description)))
+
+(defun man-tests-parse-apropos-test-case (test)
+  (let ((temp-buffer (get-buffer-create " *test-man*"))
+	(apropos-output (car test)))
+    (unwind-protect
+	(save-window-excursion
+	  (with-current-buffer temp-buffer
+	    (erase-buffer)
+	    (insert apropos-output)
+	    (let ((result (Man-parse-apropos))
+		  (checklist (cdr test)))
+	      (while (and checklist result
+			  (man-tests-name-equal-p
+			   (car checklist)
+			   (get-text-property 0 'help-echo
+					      (car checklist))
+			   (pop result)))
+		(pop checklist))
+	      (and (null checklist) (null result)))))
+      (and (buffer-name temp-buffer)
+	   (kill-buffer temp-buffer)))))
+
+(ert-deftest man-tests ()
+  "Test man."
+  (dolist (test man-tests-parse-apropos-tests)
+    (should (man-tests-parse-apropos-test-case test))))
+
+(provide 'man-tests)
+
+;;; man-tests.el ends here