Subject: bug#12537: Acknowledgement (support for git commit --amend/--signoff)

From: Dmitry Gutov <[email-masked]>
Date: Sat, 29 Sep 2012 04:14:16 +0400

Sorry, here's the patch.
=== modified file 'lisp/ChangeLog'
--- lisp/ChangeLog	2012-09-22 15:24:26 +0000
+++ lisp/ChangeLog	2012-09-28 23:47:18 +0000
@@ -1,3 +1,18 @@
+2012-09-28  Dmitry Gutov  <[email-masked]>
+
+	* vc/vc-git.el (vc-git-log-edit-toggle-signoff): New function.
+	(vc-git-log-edit-toggle-amend): New function.
+	(vc-git-log-edit-toggle-signoff): New function.
+	(vc-git-log-edit-mode): New major mode.
+	(vc-git-log-edit-mode-map): Keymap for it.
+	(vc-git-checkin): Handle "Amend" and "Sign-Off" headers.
+
+	* vc/log-edit.el (log-edit-font-lock-keywords): Allow non-letter
+	characters in header names, like hyphens.
+	(log-edit-toggle-header): New function.
+	(log-edit-extract-headers): Accept an alternative form of the
+	first argument's elements, allowing to handle yes/no headers.
+
 2012-09-22  Chong Yidong  <[email-masked]>
 
 	* repeat.el (repeat): Doc fix (Bug#12348).

=== modified file 'lisp/vc/log-edit.el'
--- lisp/vc/log-edit.el	2012-08-28 16:01:59 +0000
+++ lisp/vc/log-edit.el	2012-09-28 23:17:10 +0000
@@ -352,7 +352,8 @@
 (defvar log-edit-font-lock-keywords
   ;; Copied/inspired by message-font-lock-keywords.
   `((log-edit-match-to-eoh
-     (,(concat "^\\(\\([[:alpha:]]+\\):\\)" log-edit-header-contents-regexp)
+     (,(concat "^\\(\\([[:alpha:]][^: \n\t]+\\):\\)"
+               log-edit-header-contents-regexp)
       (progn (goto-char (match-beginning 0)) (match-end 0)) nil
       (1 (if (assoc (match-string 2) log-edit-headers-alist)
              'log-edit-header
@@ -908,12 +909,47 @@
       (insert "\n"))
     log-edit-author))
 
+(defun log-edit-toggle-header (name value)
+  "Toggle a boolean-type header in the current buffer.
+If the value of NAME is VALUE, remove it.  Otherwise, add it if
+it's not present and set it to VALUE.  Afterward, if there are headers,
+make sure there is an empty line after them.  If there are no headers,
+remove all empty lines at the beginning of the buffer.
+Return t if toggled on, otherwise nil."
+  (let ((start (point))
+        (val t)
+        (line (concat name ": " value "\n")))
+    (save-restriction
+      (rfc822-goto-eoh)
+      (narrow-to-region (point-min) (point))
+      (goto-char (point-min))
+      (if (re-search-forward (concat "^" name ":"
+                                     log-edit-header-contents-regexp)
+                             nil t)
+          (if (setq val (not (string= (match-string 1) value)))
+              (replace-match line t t)
+            (replace-match "" t t))
+        (insert line)))
+    (rfc822-goto-eoh)
+    (if (bobp)
+        (when (looking-at "\\([ \t]*\n\\)+")
+          (delete-region (match-beginning 0) (match-end 0)))
+      (delete-horizontal-space)
+      (unless (looking-at "\n")
+        (insert "\n")))
+    (when (> start (point))
+      (goto-char start))
+    val))
+
 (defun log-edit-extract-headers (headers comment)
   "Extract headers from COMMENT to form command line arguments.
 HEADERS should be an alist with elements of the form (HEADER . CMDARG)
-associating header names to the corresponding cmdline option name and the
-result is then a list of the form (MSG CMDARG1 HDRTEXT1 CMDARG2 HDRTEXT2...).
-where MSG is the remaining text from STRING.
+or (HEADER CMDARG VALUE) associating header names to the corresponding
+cmdlineoption name and the result is then a list of the form
+\(MSG CMDARG1 HDRTEXT1 CMDARG2 HDRTEXT2...\) where MSG is the remaining text
+from STRING.  For HEADERS elements of the second type, the header value is not
+added to the list.  And CMDARG is added to the result list only if
+the header value is the same as VALUE.
 If \"Summary\" is not in HEADERS, then the \"Summary\" header is extracted
 anyway and put back as the first line of MSG."
   (with-temp-buffer
@@ -931,8 +967,11 @@
                                   nil t)
           (if (eq t (cdr header))
               (setq summary (match-string 1))
-            (push (match-string 1) res)
-            (push (or (cdr header) (car header)) res))
+            (if (consp (cdr header))
+                (when (string= (match-string 1) (nth 2 header))
+                  (push (nth 1 header) res))
+              (push (match-string 1) res)
+              (push (or (cdr header) (car header)) res)))
           (replace-match "" t t)))
       ;; Remove header separator if the header is empty.
       (widen)

=== modified file 'lisp/vc/vc-git.el'
--- lisp/vc/vc-git.el	2012-09-17 05:41:04 +0000
+++ lisp/vc/vc-git.el	2012-09-28 23:44:39 +0000
@@ -608,14 +608,39 @@
 (defun vc-git-unregister (file)
   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 
-(declare-function log-edit-extract-headers "log-edit" (headers string))
+(defun vc-git-log-edit-toggle-signoff ()
+  (interactive)
+  (log-edit-toggle-header "Sign-Off" "yes"))
+
+(defun vc-git-log-edit-toggle-amend ()
+  (interactive)
+  (when (log-edit-toggle-header "Amend" "yes")
+    (goto-char (point-max))
+    (unless (bolp) (insert "\n"))
+    (insert (with-output-to-string
+              (vc-git-command
+               standard-output 1 nil
+               "log" "--max-count=1" "--pretty=format:%B" "HEAD")))))
+
+(defvar vc-git-log-edit-mode-map
+  (let ((map (make-sparse-keymap "Git-Log-Edit")))
+    (define-key map "\C-c\C-s" 'vc-git-log-edit-toggle-signoff)
+    (define-key map "\C-c\C-e" 'vc-git-log-edit-toggle-amend)
+    map))
+
+(define-derived-mode vc-git-log-edit-mode log-edit-mode "*VC-log*"
+  "Major mode for editing Git log messages.
+It is based on `log-edit-mode', and has Git-specific extensions.
+\\{vc-git-log-edit-mode-map}")
 
 (defun vc-git-checkin (files _rev comment)
   (let ((coding-system-for-write vc-git-commits-coding-system))
     (apply 'vc-git-command nil 0 files
 	   (nconc (list "commit" "-m")
                   (log-edit-extract-headers '(("Author" . "--author")
-					      ("Date" . "--date"))
+                                              ("Date" . "--date")
+                                              ("Amend" "--amend" "yes")
+                                              ("Sign-Off" "--signoff" "yes"))
                                             comment)
                   (list "--only" "--")))))