Subject: Re: bug#1169: 23.0.60; (substitute-command-keys "\\{...}") adds extra newline

From: Juanma Barranquero <[email-masked]>
Date: Thu, 7 Jul 2011 22:06:35 +0200

On Thu, Jul 7, 2011 at 19:32, Lars Magne Ingebrigtsen <[email-masked]> wrote:

> I know what they do, but is there any point in actually inserting
> something as visually distracting as ^L into the buffer people are
> looking at?
>
> If one, for instance, just made the ^L invisible, it'd look nicer, and
> there would be minimal code change.

(defface page-break
  '((t :strike-through t))
  "Face to make page breaks more visible.")

(define-minor-mode page-break-mode
    "Toggle Page Break mode.

This is a global minor mode: all buffers which don't have an
overriding window or buffer display-table will be affected."
  :init-value nil
  :global t
  (aset (or standard-display-table
            (setq standard-display-table (make-display-table)))
        ?\^L
        (and page-break-mode
             (or (get 'page-break-mode :glyph-vector)
                 (put 'page-break-mode :glyph-vector
                      (make-vector 78 (make-glyph-code ?\s 'page-break)))))))

    Juanma