Subject: 31.0.50; `svg-print' add useless and possibly wrong space in XML representation.
From: David Ponce <[email-masked]>
To: [email-masked]
Date: Fri, 19 Jul 2024 20:24:47 +0200
List-Id: <debbugs-submit.debbugs.gnu.org>

Hello,

While working on generating SVG images from text, I discovered that the
"svg-print" function adds extra space in front of the XML
representation of each child node. This is usually not a problem
because, by default, extra spaces are ignored. But this becomes a
problem, especially for text nodes, when the `xml:space' attribute is
set to "preserve" to indicate that spaces in texts are not
ignored. Because, in this case, the XML representation of the text node
no longer corresponds to the original definition, including unwanted
additional spaces.

Here are two examples which illustrate the problem to be evaluated in
the *scratch* buffer (emacs -Q):

(require 'svg)

;; Simple text with extra spaces between words.
(let* ((text "This buffer is   for text that   is not saved.")
         (w (* (length text) (default-font-width)))
         (h (* 1.5 (default-font-height)))
         (xmlspace "preserve") ;; Rendering preserves spaces.
         (svg (svg-create w h :xml:space xmlspace :stroke-width 0)))
    (svg-rectangle svg 0 0 w h :fill "blue")
    (svg-text svg text :y "1em" :fill "white")
    (insert-image (svg-image svg :scale 1)))

;; Aggregate texts separated by 1 space.
(let* ((texts '("This buffer is "
                  "for text that "
                  "is not saved."))
         (w (* (apply #'+ (mapcar #'length texts))
               (default-font-width)))
         (h (* 1.5 (default-font-height)))
         (xmlspace "preserve") ;; Rendering preserves spaces.
         (svg (svg-create w h :xml:space xmlspace :stroke-width 0)))
    (svg-rectangle svg 0 0 w h :fill "blue")
    (dom-append-child
     svg
     (apply #'dom-node
      'text
      '((y . "1em") (fill . "white"))
      texts))
    (insert-image (svg-image svg :scale 1)))

Since the extra space in front of the XML representation of each child
node is unnecessary according to the SVG 1.1 specification, the attached
V0 patch resolves this issue by removing the offending statement.

The attached V1 patch is a proposal to go a step further by improving
the documentation and using the DOM API to access parts of dom node.

Thanks.

In GNU Emacs 31.0.50 (build 1, x86_64-pc-linux-gnu, GTK+ Version
   3.24.42, cairo version 1.18.0) of 2024-07-17
Repository revision: 3a790abd869ddadc343710deb0c4368227ba6611
Repository branch: master
Windowing system distributor 'The X.Org Foundation', version 11.0.12014000
System Description: Fedora Linux 40 (KDE Plasma)

Configured using:
   'configure --with-x-toolkit=gtk3 --with-cairo-xcb
   --with-native-compilation=no
   PKG_CONFIG_PATH=/usr/local/lib/pkgconfig:/usr/lib/pkgconfig'

Configured features:
ACL CAIRO DBUS FREETYPE GIF GLIB GMP GNUTLS GPM GSETTINGS HARFBUZZ JPEG
LCMS2 LIBOTF LIBSELINUX LIBSYSTEMD LIBXML2 M17N_FLT MODULES NOTIFY
INOTIFY PDUMPER PNG RSVG SECCOMP SOUND SQLITE3 THREADS TIFF
TOOLKIT_SCROLL_BARS TREE_SITTER WEBP X11 XDBE XIM XINPUT2 XPM GTK3 ZLIB

Important settings:
    value of $LC_TIME: fr_FR.utf8
    value of $LANG: fr_FR.UTF-8
    locale-coding-system: utf-8-unix
2024-07-19  David Ponce  <[email-masked]>

	* svg.el (svg-print): Remove useless extra space from the XML
	representation of SVG node.  Use the dom API to access parts of
	dom node. Improve doc string.

diff --git a/lisp/svg.el b/lisp/svg.el
index f2eb2ec66dd..1fed6c6b3b8 100644
--- a/lisp/svg.el
+++ b/lisp/svg.el
@@ -321,19 +321,19 @@ svg-possibly-update-image
 	(put-text-property marker (1+ marker) 'display (svg-image svg))))))
 
 (defun svg-print (dom)
-  "Convert DOM into a string containing the xml representation."
+  "Print the XML representation of DOM at point in current buffer."
   (if (stringp dom)
       (insert dom)
-    (insert (format "<%s" (car dom)))
-    (dolist (attr (nth 1 dom))
-      ;; Ignore attributes that start with a colon.
-      (unless (= (aref (format "%s" (car attr)) 0) ?:)
-        (insert (format " %s=\"%s\"" (car attr) (cdr attr)))))
-    (insert ">")
-    (dolist (elem (nthcdr 2 dom))
-      (insert " ")
-      (svg-print elem))
-    (insert (format "</%s>" (car dom)))))
+    (let ((tag (dom-tag dom)))
+      (insert (format "<%s" tag))
+      (dolist (attr (dom-attributes dom))
+        ;; Ignore attributes that start with a colon.
+        (unless (= (aref (format "%s" (car attr)) 0) ?:)
+          (insert (format " %s=\"%s\"" (car attr) (cdr attr)))))
+      (insert ">")
+      (dolist (elem (dom-children dom))
+        (svg-print elem))
+      (insert (format "</%s>" tag)))))
 
 (defun svg-remove (svg id)
   "Remove the element identified by ID from SVG."
2024-07-19  David Ponce  <[email-masked]>

	* svg.el (svg-print): Remove useless extra space from the XML
	representation of child node.

diff --git a/lisp/svg.el b/lisp/svg.el
index f2eb2ec66dd..f5c76145136 100644
--- a/lisp/svg.el
+++ b/lisp/svg.el
@@ -331,7 +331,6 @@ svg-print
         (insert (format " %s=\"%s\"" (car attr) (cdr attr)))))
     (insert ">")
     (dolist (elem (nthcdr 2 dom))
-      (insert " ")
       (svg-print elem))
     (insert (format "</%s>" (car dom)))))