Subject: [PATCH] git: Remove untracked files from cached checkouts.
From: Ludovic Courtès <[email-masked]>
To: [email-masked]
Cc: Ricardo Wurmus <[email-masked]>,Ludovic Courtès <[email-masked]>
Date: Tue, 2 Jul 2024 15:03:01 +0200
List-Id: <debbugs-submit.debbugs.gnu.org>

Cached checkouts could end up with stale untracked files, for example
because the checkout was interrupted.  As a result, when this happens
for the Guix checkout, users would not get substitutes for ‘guix pull’.

* guix/git.scm (delete-untracked-files): New procedure.
(switch-to-ref): Use it.
* tests/git.scm ("update-cached-checkout, untracked files removed"): New
test.

Co-authored-by: Ricardo Wurmus <[email-masked]>
Change-Id: Iccbe644ade396ad27a037db7e0ef1c2a68ef91ce
---
 guix/git.scm  | 24 ++++++++++++++++++++++++
 tests/git.scm | 22 +++++++++++++++++++++-
 2 files changed, 45 insertions(+), 1 deletion(-)

diff --git a/guix/git.scm b/guix/git.scm
index d75a301f98b..48a962089de 100644
--- a/guix/git.scm
+++ b/guix/git.scm
@@ -298,6 +298,25 @@ (define (resolve-reference repository ref)
       (('tag    . tag)
        (tag->commit repository tag)))))
 
+(define (delete-untracked-files repository)
+  "Delete untracked files from the work directory of REPOSITORY."
+  (let ((workdir (repository-working-directory repository))
+        (status (status-list-new repository
+                                 (make-status-options
+                                  STATUS-SHOW-WORKDIR-ONLY
+                                  (logior
+                                   STATUS-FLAG-INCLUDE-UNTRACKED
+                                   STATUS-FLAG-INCLUDE-IGNORED)))))
+    (for-each (lambda (entry)
+                (let ((status (status-entry-status entry)))
+                  (when (or (memq 'wt-new status)
+                            (memq 'ignored status))
+                    (let* ((diff (status-entry-index-to-workdir entry))
+                           (new  (diff-delta-new-file diff)))
+                      (delete-file-recursively
+                       (in-vicinity workdir (diff-file-path new)))))))
+              (status-list->status-entries status))))
+
 (define (switch-to-ref repository ref)
   "Switch to REPOSITORY's branch, commit or tag specified by REF.  Return the
 OID (roughly the commit hash) corresponding to REF."
@@ -305,6 +324,11 @@ (define (switch-to-ref repository ref)
     (resolve-reference repository ref))
 
   (reset repository obj RESET_HARD)
+
+  ;; There might still be untracked files in REPOSITORY due to an interrupted
+  ;; checkout for example; delete them.
+  (delete-untracked-files repository)
+
   (object-id obj))
 
 (define (call-with-repository directory proc)
diff --git a/tests/git.scm b/tests/git.scm
index ad43435b674..9ccd04f0cdf 100644
--- a/tests/git.scm
+++ b/tests/git.scm
@@ -1,5 +1,5 @@
 ;;; GNU Guix --- Functional package management for GNU
-;;; Copyright © 2019, 2020, 2022 Ludovic Courtès <[email-masked]>
+;;; Copyright © 2019-2020, 2022, 2024 Ludovic Courtès <[email-masked]>
 ;;; Copyright © 2021 Xinglu Chen <[email-masked]
 ;;;
 ;;; This file is part of GNU Guix.
@@ -259,4 +259,24 @@ (define-module (test-git)
          ;; COMMIT should be the ID of the commit object, not that of the tag.
          (string=? commit head))))))
 
+(test-assert "update-cached-checkout, untracked files removed"
+  (call-with-temporary-directory
+   (lambda (cache)
+     (with-temporary-git-repository directory
+         '((add "a.txt" "A")
+           (add ".gitignore" ".~\n")
+           (commit "First commit"))
+       (let ((directory commit relation
+                        (update-cached-checkout directory
+                                                #:ref '()
+                                                #:cache-directory cache)))
+         (close-port
+          (open-output-file (in-vicinity cache "stale-untracked-file")))
+         (let ((directory2 commit2 relation2
+                           (update-cached-checkout directory
+                                                   #:ref '()
+                                                   #:cache-directory cache)))
+           (not (file-exists?
+                 (in-vicinity cache "stale-untracked-file")))))))))
+
 (test-end "git")

base-commit: bd908af0c619cb1b74afeeb07839d7af08de9d91
-- 
2.45.2