Subject: 2015-06-01; add support for ffap via kpsewhich
From: Nicolas Richard <[email-masked]>
To: [email-masked]
Date: Wed, 05 Aug 2015 19:34:56 +0200
List-Id: <debbugs-submit.debbugs.gnu.org>

Hi all,

I'm using the following customizations, which I thought I'd share with
you. As the subject says it, it uses kpsewhich for guessing a filename
at point. It allows to use M-x ffap with point on "geometry" to find
geometry.sty, or with point on "memoir" to find memoir.cls.

It is very quick because it calls kpsewhich only once.

I'm not making this into an actual patch because while it works
fine on my system, it's not ready for inclusion yet. I'm open to
your ideas to make it better and eventually include it.

;; a first step is :
;; don't allow braces as possible characters in a filename (otherwise
;; \input{foo} is seen as a possible filename, instead of just foo)
;; (this is because of a recent change in emacs, see commit
;; ba6c32b6decaa2a72a3d5f854efd513e8e82c118 for detail)

(push '(latex-mode "--:\\\\$+<>@-Z_[:alpha:]~*?" "<@" "@>;.,!:")
      ffap-string-at-point-mode-alist)

;; second step is to extend rules for finding file at point, and use kpsewhich

(defun yf/ffap-latex-mode (name)
  "ffap function in latex buffers"
  (if (file-exists-p name)
      name
    (let ((curbuf (current-buffer)))
      (with-temp-buffer 
        (let ((suffixes '(".sty" ".cls" ".ltx" ".tex" "" ".ldf"))
              (prefixes '("" "beamertheme"
                          "beamercolortheme"
                          "beamerfonttheme"
                          "beamerinnertheme"
                          "beameroutertheme"))
              args)
          (setq args (apply #'append (mapcar
                                      (lambda (suffix)
                                        (mapcar
                                         (lambda (prefix)
                                           (concat prefix name suffix))
                                         prefixes))
                                      suffixes)))
          (let ((process-environment (buffer-local-value 'process-environment curbuf))
                (exec-path (buffer-local-value 'exec-path curbuf)))
            (apply #'call-process "kpsewhich"  nil  t  nil args))
          (when (< (point-min) (point-max))
            (buffer-substring (goto-char (point-min)) (point-at-eol))))))))

;; use the above
(advice-add 'ffap-latex-mode :override 'yf/ffap-latex-mode)

Comments welcome!

Nicolas.